Enable JavaScript to interact with content and submit forms on Wolfram websites. Learn how

Wolfram Language & System Documentation Center

ElementMeshInterpolation

NDSolve`FEM`

NDSolve`FEM`

ElementMeshInterpolation

ElementMeshInterpolation[{emesh},{f₁,f₂,…}]

constructs an InterpolatingFunction object of the function values f_j, corresponding to coordinate j of an ElementMesh object.

ElementMeshInterpolation[{{t₁,t₂,…},emesh},
{{{f₁₁,f₁₂,…}},{{f₂₁,f₂₂,…}},…}]

constructs an interpolation of the function values f_ij, corresponding to discrete t_i and coordinate j of an ElementMesh object.

Details and Options

ElementMeshInterpolation returns an InterpolatingFunction object, which can be used like any other pure function.
The function values f can be real or complex numbers.
The ElementMesh object may contain curved elements.
ElementMeshInterpolation works by fitting polynomial curves between data points belonging to the same element.
The degree of the polynomial curves is specified by the option InterpolationOrder.
The default InterpolationOrder is the order of the ElementMesh.
You can do linear interpolation by using the setting InterpolationOrder1.
ElementMeshInterpolation[data] generates an InterpolatingFunction object that returns values with MachinePrecision.
ElementMeshInterpolation has the same options as Interpolation, with the following additions:
"ExtrapolationHandler" Automatic specify how extrapolation is handled
Setting the option from NDSolve and related functions is explained in NDSolve Finite Element Options.

Examples

open all close all

Basic Examples (2)

Load the package:

Wolfram Language code: Needs["NDSolve`FEM`"]

Set up an ElementMesh:

Wolfram Language code: mesh = ToElementMesh[Disk[]]

Set up function values at the mesh coordinates:

Wolfram Language code: Short[values = Function[{x, y}, x ^ 2 + y ^ 2]@@@mesh["Coordinates"]]

Create an InterpolatingFunction:

Wolfram Language code: if = ElementMeshInterpolation[{mesh}, values]

Apply the function to find interpolated values:

Wolfram Language code: if[0, 0]

Plot the interpolating function:

Wolfram Language code: Plot3D[if[x, y], {x, y}∈Disk[]]

Generate function values for a time-dependent interpolation:

Wolfram Language code:

time = Range[0, 1, 0.1];
data = {values * #}& /@ Sin[time];

Construct a time-dependent interpolating function:

Wolfram Language code: tif = ElementMeshInterpolation[{time, mesh}, data]

Options (6)

"ExtrapolationHandler" (6)

Construct an InterpolatingFunction:

Wolfram Language code: if = ElementMeshInterpolation[{mesh}, values]

Query the InterpolatingFunction outside of its domain:

Wolfram Language code: if[2, 2]

Construct an InterpolatingFunction with an extrapolation handler that returns Indeterminate for queries outside the domain:

Wolfram Language code: if = ElementMeshInterpolation[{mesh}, values, "ExtrapolationHandler" -> {Function[Indeterminate]}]

Query the InterpolatingFunction outside of its domain:

Wolfram Language code: if[2, 2]

Construct an InterpolatingFunction with an extrapolation handler that extrapolates outside its domain and does not give a warning message:

Wolfram Language code: if = ElementMeshInterpolation[{mesh}, values, "ExtrapolationHandler" -> {Automatic, "WarningMessage" -> False}]

Query the InterpolatingFunction outside of its domain:

Wolfram Language code: if[2, 2]

Construct an InterpolatingFunction with an extrapolation handler that returns 0 outside its domain:

Wolfram Language code: if = ElementMeshInterpolation[{mesh}, values, "ExtrapolationHandler" -> {Function[0.]}]

Query the InterpolatingFunction outside of its domain:

Wolfram Language code: if[2, 2]

Construct an InterpolatingFunction with an extrapolation handler that returns Indeterminate outside its domain and does not give a warning message:

Wolfram Language code:

if = ElementMeshInterpolation[{mesh}, values, "ExtrapolationHandler" -> {Function[Indeterminate], "WarningMessage" -> False}]

Query the InterpolatingFunction outside of its domain:

Wolfram Language code: if[2, 2]

The default for NDSolve and the finite element method is to return InterpolatingFunction objects that do not extrapolate outside of the given domain:

Wolfram Language code:

ifun = NDSolveValue[{Laplacian[u[x, y], {x, y}] == 1, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Disk[]];
ifun[2, 0]

Allow InterpolatingFunction objects generated by NDSolve to extrapolate when evaluated outside of the simulation domain and not warn about it:

Wolfram Language code:

ifun = NDSolveValue[{Laplacian[u[x, y], {x, y}] == 1, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Disk[], "ExtrapolationHandler" -> {Automatic, "WarningMessage" -> False}];
ifun[2, 0]

While it is not generally possible to construct periodic interpolating functions for arbitrary meshes, one can mimic periodic interpolating functions based on rectangular regions by specifying an "ExtrapolatiopnHandler".

Generate data and a mesh:

Wolfram Language code:

data = Flatten[Table[{i, j, Sin[i + j]}, {i, 0, 2 π, 2 π / 50}, {j, 0, 2 π, 2 π / 50}], 1];
mesh2 = ToElementMesh["Coordinates" -> data[[All, {1, 2}]]]

Generate a temporary interpolating function from this mesh and data:

Wolfram Language code: temp = ElementMeshInterpolation[{mesh2}, data[[All, 3]]];

Use the extrapolation handler to map the coordinates outside of the meshed domain back into the domain and evaluate over the temporary interpolating function:

Wolfram Language code:

f = ElementMeshInterpolation[{mesh2}, data[[ ;; , -1]], "ExtrapolationHandler" -> {Function[{x, y}, temp[Mod[x, 2 π], Mod[y, 2 π]]]}]

To verify that the interpolation is now periodic, visualize the function f both inside and outside the original domain:

Wolfram Language code: {ContourPlot[f[x, y], {x, 0, 2 π}, {y, 0, 2 π}], ContourPlot[f[x, y], {x, 0, 4 π}, {y, 0, 4 π}]}

Properties & Relations (1)

For time-independent interpolation, ListInterpolation can also be used:

Wolfram Language code: ListInterpolation[values, mesh]

Top