WOLFRAM

Wolfram Language & System Documentation Center

ElementMeshProjection[mesh,p]

applies the projection p to the coordinates of an ElementMesh mesh.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
1D to 1D  
2D to 2D  
2D to 3D  
3D to 3D  
3D to 2D  
Applications  
Possible Issues  
See Also
Tech Notes
Cite this Page
NDSolve`FEM`
NDSolve`FEM`

ElementMeshProjection

ElementMeshProjection[mesh,p]

applies the projection p to the coordinates of an ElementMesh mesh.

Details and Options

  • ElementMeshProjection returns a new ElementMesh with coordinates computed by mapping p/@mesh["Coordinates"].
  • ElementMeshProjection can be used to project a 3D boundary mesh to a 2D mesh.
  • ElementMeshProjection can be used to create parts of a 3D boundary mesh from a 2D mesh.
  • ElementMeshProjection can be used to scale or rotate a mesh.
  • ElementMeshProjection accepts the same options as ElementMesh.

Examples

open all close all

Basic Examples  (2)

Load the package:

Wolfram Language code: Needs["NDSolve`FEM`"]

Create an ElementMesh:

Wolfram Language code: mesh2D = ToElementMesh[Rectangle[]]

Visualize the ElementMesh:

Wolfram Language code: mesh2D["Wireframe"]
Wolfram Language code: projectedMesh = ElementMeshProjection[mesh2D, RotationTransform[π / 3]]

Visualize the projected ElementMesh:

Wolfram Language code: projectedMesh["Wireframe"]

Create and visualize a 2D ElementMesh:

Wolfram Language code: mesh2D = ToElementMesh[Rectangle[]]; mesh2D["Wireframe"]

Project the 2D mesh to 3D:

Wolfram Language code: projectedMesh = ElementMeshProjection[mesh2D, {#[[1]], #[[2]], 0.}&]

Visualize the projected ElementMesh:

Wolfram Language code: projectedMesh["Wireframe"]

Scope  (7)

1D to 1D  (1)

Create and visualize a 1D ElementMesh:

Wolfram Language code: mesh1D = ToElementMesh[Line[{{0}, {2π}}]]; mesh1D["Wireframe"]

Scale the 1D mesh:

Wolfram Language code: ElementMeshProjection[mesh1D, {2 * #[[1]]}&]

2D to 2D  (2)

Create and visualize a 2D ElementMesh:

Wolfram Language code: mesh2D = ToElementMesh[Rectangle[]]; mesh2D["Wireframe"]

Scale the mesh:

Wolfram Language code: projectedMesh = ElementMeshProjection[mesh2D, {#[[1]], 2 * #[[2]]}&]

Visualize the projected ElementMesh:

Wolfram Language code: projectedMesh["Wireframe"]

Create and visualize a 2D boundary ElementMesh:

Wolfram Language code: boundaryMesh2D = ToBoundaryMesh[Rectangle[]]; boundaryMesh2D["Wireframe"]

Scale the mesh:

Wolfram Language code: projectedMesh = ElementMeshProjection[boundaryMesh2D, {#[[1]], 2 * #[[2]]}&]

Visualize the projected boundary ElementMesh:

Wolfram Language code: projectedMesh["Wireframe"]

2D to 3D  (2)

Create and visualize a 2D ElementMesh:

Wolfram Language code: mesh2D = ToElementMesh[Rectangle[]]; mesh2D["Wireframe"]

Project and scale the mesh:

Wolfram Language code: projectedMesh = ElementMeshProjection[mesh2D, {#[[1]], 2 * #[[2]], 0.}&]

Visualize the projected boundary ElementMesh:

Wolfram Language code: projectedMesh["Wireframe"]

Create and visualize a 2D ElementMesh:

Wolfram Language code: mesh2D = ToElementMesh[Rectangle[]]; mesh2D["Wireframe"]

Project the mesh to 3D:

Wolfram Language code: projectedMesh = ElementMeshProjection[mesh2D, {#[[1]], #[[2]], #[[1]] + #[[2]]}&]

Visualize the projected boundary ElementMesh:

Wolfram Language code: projectedMesh["Wireframe"]

3D to 3D  (1)

Create and visualize a 3D ElementMesh:

Wolfram Language code: mesh3D = ToElementMesh[Ball[]]; mesh3D["Wireframe"]

Scale the mesh to 3D:

Wolfram Language code: projectedMesh = ElementMeshProjection[mesh3D, {#[[1]], #[[2]], 2 * #[[3]]}&]

Visualize the projected ElementMesh:

Wolfram Language code: projectedMesh["Wireframe"]

3D to 2D  (1)

Create and visualize a 3D boundary ElementMesh:

Wolfram Language code: boundaryMesh3D = ToBoundaryMesh[Polygon[{{0, 0, 0}, {3, 0, 0}, {3, 3, 0}, {0, 3, 0}, {1, 1, 0}, {1, 2, 0}, {2, 2, 0}, {2, 1, 0}}, {1, 2, 3, 4} -> {{5, 6, 7, 8}}]];boundaryMesh3D["Wireframe"]

Project the boundary mesh to 2D:

Wolfram Language code: projectedMesh = ElementMeshProjection[boundaryMesh3D, {#[[1]], #[[2]]}&]

Visualize the projected ElementMesh:

Wolfram Language code: projectedMesh["Wireframe"]

Applications  (1)

Make a rotational transform on a full element mesh:

Wolfram Language code: mesh3D = ToElementMesh[Cuboid[{0, 0, 0}, {1, 2, 3}]]; result1 = ElementMeshProjection[mesh3D, RotationTransform[{{0, 0, 1}, {1, 1, 1}}]]

Visualize the original wireframe mesh in black and the transformed wireframe in blue:

Wolfram Language code: Show[result1["Wireframe"["MeshElementStyle" -> Directive[EdgeForm[Blue]]]], mesh3D["Wireframe"]]

Possible Issues  (3)

Projections from 3D to 1D and vice versa are not implemented:

Wolfram Language code: ElementMeshProjection[ToElementMesh[Ball[]], {#[[1]]}&]

Projections from 2D to 1D and vice versa are not implemented:

Wolfram Language code: ElementMeshProjection[ToElementMesh[Rectangle[]], {#[[1]]}&]

Projections can lead to a distorted ElementMesh:

Wolfram Language code: ElementMeshProjection[ToElementMesh[Cuboid[{0, 0, 0}, {1, 2, 3}]], {#[[1]], #[[3]] / 10, 5 * #[[2]]}&]

In some cases, this can be circumvented by using a different element type:

Wolfram Language code: ElementMeshProjection[ToElementMesh[Cuboid[{0, 0, 0}, {1, 2, 3}], "MeshElementType" -> TetrahedronElement], {#[[1]], #[[3]] / 10, 5 * #[[2]]}&]
Wolfram Research (2024), ElementMeshProjection, Wolfram Language function, https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshProjection.html.

Text

Wolfram Research (2024), ElementMeshProjection, Wolfram Language function, https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshProjection.html.

CMS

Wolfram Language. 2024. "ElementMeshProjection." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshProjection.html.

APA

Wolfram Language. (2024). ElementMeshProjection. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshProjection.html

BibTeX

@misc{reference.wolfram_2026_elementmeshprojection, author="Wolfram Research", title="{ElementMeshProjection}", year="2024", howpublished="\url{https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshProjection.html}", note=[Accessed: 15-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_elementmeshprojection, organization={Wolfram Research}, title={ElementMeshProjection}, year={2024}, url={https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshProjection.html}, note=[Accessed: 15-June-2026]}