WOLFRAM

Wolfram Language & System Documentation Center

TetGenTetrahedralize[expr,settings]

tetrahedralizes a TetGen expression using settings and returns the result in a new TetGen expression.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Options  
"TetrahedronRefinement"  
Possible Issues  
Tech Notes
Related Guides
Cite this Page
TetGenLink`
TetGenLink`

TetGenTetrahedralize

TetGenTetrahedralize[expr,settings]

tetrahedralizes a TetGen expression using settings and returns the result in a new TetGen expression.

Details and Options

  • To use TetGenTetrahedralize, you first need to load it using Needs["TetGenLink`"].
  • The settings given to TetGenTetrahedralize are a string of different commands:
  • "p"tetrahedralize a piecewise linear complex (PLC)
    "q"quality mesh generation; a minimum radius-edge ratio may be specified (default 2.0)
    "a"apply a maximum tetrahedron volume constraint
    "A"assign attributes to identify tetrahedra in certain regions
    "r"reconstruct/refine a previously generated mesh
    "Y"suppress splitting of boundary facets/segments
    "YY"suppress splitting of exterior and interior boundary facets/segments
    "i"insert a list of additional points into mesh
    "M"do not merge coplanar facets
    "T"set a tolerance for coplanar test (default )
    "d"detect intersections of PLC facets
    "o2"generate second-order subparametric elements
    "C"check the consistency of the final mesh
    "Q"quiet: no terminal output except error
  • An empty string " " given to TetGenTetrahedralize creates a Delaunay tetrahedralization.
  • TetGenTetrahedralize has the following options:
  • "TetrahedronRefinement" Nonefunction to refine a tetrahedron

Examples

open all close all

Basic Examples  (1)

First, load the package:

Wolfram Language code: Needs["TetGenLink`"]

This creates an instance of a TetGen expression:

Wolfram Language code: inst = TetGenCreate[]

This sets up points and facets to use:

Wolfram Language code: pts = {{0., 0., 0.}, {2., 0., 0.}, {2., 0., 2.}, {0., 0., 2.}, {0., 12., 0.}, {2., 12., 0.}, {2., 12., 2.}, {0., 12., 2.}}; facets = {{{1, 2, 3, 4}}, {{5, 6, 7, 8}}, {{1, 5, 6, 2}}, {{2, 6, 7, 3}}, {{3, 7, 8, 4}}, {{4, 8, 5, 1}}};

This sets the points and facets in the TetGen instance:

Wolfram Language code: TetGenSetPoints[inst, pts]; TetGenSetFacets[inst, facets];

This carries out the tetrahedralization, returning a new TetGen instance:

Wolfram Language code: inst1 = TetGenTetrahedralize[ inst, "pq1.414a0.1"]

This extracts the points and faces from the tetrahedralization:

Wolfram Language code: elemPts = TetGenGetPoints[inst1]; elemFaces = TetGenGetFaces[inst1];

This plots the faces:

Wolfram Language code: Graphics3D[GraphicsComplex[elemPts, Polygon[elemFaces]]]

Set the "r" string in place of "p" to refine an existing TetGen instance:

Wolfram Language code: inst2 = TetGenTetrahedralize[ inst1, "rq1.414a0.01"]

This extracts the points and faces from the tetrahedralization:

Wolfram Language code: elemPts = TetGenGetPoints[inst2]; elemFaces = TetGenGetFaces[inst2];

This plots the faces:

Wolfram Language code: Graphics3D[GraphicsComplex[elemPts, Polygon[elemFaces]]]

Options  (1)

"TetrahedronRefinement"  (1)

First, load the package:

Wolfram Language code: Needs["TetGenLink`"]

This creates an instance of a TetGen expression:

Wolfram Language code: inst = TetGenCreate[]

This sets up points and facets to use:

Wolfram Language code: pts = {{0., 0., 0.}, {2., 0., 0.}, {2., 0., 2.}, {0., 0., 2.}, {0., 12., 0.}, {2., 12., 0.}, {2., 12., 2.}, {0., 12., 2.}}; facets = {{{1, 2, 3, 4}}, {{5, 6, 7, 8}}, {{1, 5, 6, 2}}, {{2, 6, 7, 3}}, {{3, 7, 8, 4}}, {{4, 8, 5, 1}}};

This sets the points and facets in the TetGen instance:

Wolfram Language code: TetGenSetPoints[inst, pts]; TetGenSetFacets[inst, facets];

This carries out the tetrahedralization, returning a new TetGen instance:

Wolfram Language code: inst1 = TetGenTetrahedralize[ inst, "pq1.414"]

This extracts the points and faces from the tetrahedralization:

Wolfram Language code: elemPts = TetGenGetPoints[inst1]; elemFaces = TetGenGetFaces[inst1];

This plots the faces:

Wolfram Language code: Graphics3D[GraphicsComplex[elemPts, Polygon[elemFaces]]]

This sets up a compiled function that returns True if a tetrahedron should be refined and False otherwise:

Wolfram Language code: cf = Compile[{{coordinates, _Real, 2}, {volume, _Real, 0}}, If[volume > 0.1, True, False] ];

This carries out the tetrahedralization with the refinement function, returning a new TetGen instance:

Wolfram Language code: inst2 = TetGenTetrahedralize[inst, "pq1.414", "TetrahedronRefinement" -> cf]

In this case the "p" string is used as the refinement operates on the initial TetGen instance.

This extracts the points and faces from the tetrahedralization:

Wolfram Language code: elemPts = TetGenGetPoints[inst2]; elemFaces = TetGenGetFaces[inst2];

This plots the faces:

Wolfram Language code: Graphics3D[GraphicsComplex[elemPts, Polygon[elemFaces]]]

Refine the already tetrahedralized TetGen instance:

Wolfram Language code: inst2 = TetGenTetrahedralize[inst1, "rq1.414", "TetrahedronRefinement" -> cf]

In this case the "r" string is used as the refinement operates on an already tetrahedralized TetGen instance.

This extracts the points and faces from the tetrahedralization:

Wolfram Language code: elemPts = TetGenGetPoints[inst2]; elemFaces = TetGenGetFaces[inst2];

This plots the faces:

Wolfram Language code: Graphics3D[GraphicsComplex[elemPts, Polygon[elemFaces]]]

Possible Issues  (1)

Refinement of an already tetrahedralized TetGen instance needs to be done with the "r" string.

First, load the package:

Wolfram Language code: Needs["TetGenLink`"]

Set up and tetrahedralize an initial TetGen instance:

Wolfram Language code: coordinates = {{0., 0., 0.}, {2., 0., 0.}, {2., 0., 2.}, {0., 0., 2.}, {0., 12., 0.}, {2., 12., 0.}, {2., 12., 2.}, {0., 12., 2.}}; facets = {{{1, 2, 3, 4}}, {{5, 6, 7, 8}}, {{1, 5, 6, 2}}, {{2, 6, 7, 3}}, {{3, 7, 8, 4}}, {{4, 8, 5, 1}}};
Wolfram Language code: geometry = TetGenCreate[]; TetGenSetPoints[geometry, coordinates]; TetGenSetFacets[geometry, facets]; discretization = TetGenTetrahedralize[geometry, "pq"];

Inspect the number of tetrahedra in the tetrahedralized instance:

Wolfram Language code: TetGenGetElements[discretization]//Length

Tetrahedralization of an already tetrahedralized TetGen instance as a piecewise linear complex (PLC) does not work. No new elements are generated:

Wolfram Language code: refinement = TetGenTetrahedralize[discretization, "pqa.01"]; TetGenGetElements[refinement]//Length

Refinement of an already tetrahedralized TetGen instance needs to be done with the "r" string:

Wolfram Language code: discretization = TetGenTetrahedralize[geometry, "pq"]; refinement = TetGenTetrahedralize[discretization, "rqa.01"];
Wolfram Language code: TetGenGetElements[refinement]//Length
Wolfram Research (2010), TetGenTetrahedralize, Wolfram Language function, https://reference.wolfram.com/language/TetGenLink/ref/TetGenTetrahedralize.html (updated 2014).

Text

Wolfram Research (2010), TetGenTetrahedralize, Wolfram Language function, https://reference.wolfram.com/language/TetGenLink/ref/TetGenTetrahedralize.html (updated 2014).

CMS

Wolfram Language. 2010. "TetGenTetrahedralize." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/TetGenLink/ref/TetGenTetrahedralize.html.

APA

Wolfram Language. (2010). TetGenTetrahedralize. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/TetGenLink/ref/TetGenTetrahedralize.html

BibTeX

@misc{reference.wolfram_2026_tetgentetrahedralize, author="Wolfram Research", title="{TetGenTetrahedralize}", year="2014", howpublished="\url{https://reference.wolfram.com/language/TetGenLink/ref/TetGenTetrahedralize.html}", note=[Accessed: 15-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_tetgentetrahedralize, organization={Wolfram Research}, title={TetGenTetrahedralize}, year={2014}, url={https://reference.wolfram.com/language/TetGenLink/ref/TetGenTetrahedralize.html}, note=[Accessed: 15-June-2026]}