WOLFRAM

Wolfram Language & System Documentation Center
Using TriangleLink

Using TriangleLink

This section shows some of the ways that TriangleLink can be applied.

Convex Hull

To use TriangleLink, it must first be loaded.

Wolfram Language code: Needs["TriangleLink`"]

Next, some random points are generated and displayed.

Wolfram Language code: data = RandomReal[{0, 1}, {100, 2}]; Graphics[Point[data]]

Now you can compute the convex hull of the 3D points. TriangleConvexHull will return a list of points and segments.

Wolfram Language code: {pts, segments} = TriangleConvexHull[data];

Each segment is a list of two integers. These integers refer to the coordinates. You can plot them by using GraphicsComplex.

Wolfram Language code: Graphics[GraphicsComplex[pts, Line[segments]]]

Delaunay Triangulation

To use TriangleLink, it must first be loaded.

Wolfram Language code: Needs["TriangleLink`"]

This creates some 2D data.

Wolfram Language code: data = RandomReal[{0, 1}, {100, 2}];

You can compute the Delaunay triangulation of the data with TriangleDelaunay.

Wolfram Language code: {pts, triangles} = TriangleDelaunay[data];

The result is a list of points and triangles. The list of triangles is a list of three integers that refer to the coordinate positions. To visualize the triangle as a wireframe, you can use Polygon.

Wolfram Language code: Graphics[GraphicsComplex[pts, {EdgeForm[LightDarkSwitched[Black, White]], FaceForm[], Polygon[triangles]}]]

Meshing a Rectangle (Basic)

This loads the package.

Wolfram Language code: Needs["TriangleLink`"]

First, an instance of a triangle expression is created.

Wolfram Language code: inInst = TriangleCreate[]

Next, coordinates and line segments are specified.

Wolfram Language code: coords = {{0., 0.}, {1., 0.}, {1., 1.}, {0., 1.}}; segments = {{1, 2}, {2, 3}, {3, 4}, {4, 1}}; Graphics[GraphicsComplex[coords, Line[segments]]]

These are then set into the triangle instance.

Wolfram Language code: TriangleSetPoints[inInst, coords]
Wolfram Language code: TriangleSetSegments[inInst, segments]

The actual triangulation is then done with TriangleTriangulate and a set of string parameters (Triangle string codes).

Wolfram Language code: outInst = TriangleTriangulate[inInst, "pq30a0.01"]

The data can be extracted from the triangle instance.

Wolfram Language code: rawCoords = TriangleGetPoints[outInst]; Length[rawCoords] incidents = TriangleGetElements[outInst]; Length[incidents]

A visualization of the triangle mesh.

Wolfram Language code: Graphics[ {EdgeForm[LightDarkSwitched[Black, White]], FaceForm[], GraphicsComplex[rawCoords, Polygon[incidents]]}]