WOLFRAM

Wolfram Language & System Documentation Center

How to | Plot Data

The Wolfram Language offers extensive support for plotting all kinds of data in many different ways.

Consider the following data to be plotted (stored as sdata):

Wolfram Language code: sdata = Table[1. Sin[2 i], {i, 0, 2 Pi, Pi / 12}]

Use ListPlot to plot sdata:

Wolfram Language code: ListPlot[sdata]

Plot sdata by filling to the axis:

Wolfram Language code: ListPlot[sdata, Filling -> Axis]

Specify a color and increase the size of the data points:

Wolfram Language code: ListPlot[sdata, PlotStyle -> {PointSize[Medium], Red}]

Use ListLinePlot to plot sdata with a connecting line:

Wolfram Language code: ListLinePlot[sdata]

Create another set of data to plot (stored as cdata):

Wolfram Language code: cdata = Table[1. Cos[i / 2], {i, 0, 2 Pi, Pi / 12}];

Plot sdata and cdata together:

Wolfram Language code: ListLinePlot[{sdata, cdata}]

Use ListPolarPlot to plot cdata as points at polar coordinates:

Wolfram Language code: ListPolarPlot[cdata]

Define another dataset to plot (stored as data):

Wolfram Language code: data = Table[Sin[j ^ 2 + i ^ 2], {i, 0, Pi, Pi / 30}, {j, 0, Pi, Pi / 30}];

The dataset has 31 sublists:

Wolfram Language code: Length[data]

Plot only specific parts of data:

Wolfram Language code: ListPlot[{data[[1]], data[[19]]}]

Connect these points with lines:

Wolfram Language code: ListLinePlot[{data[[1]], data[[19]]}]

Generate a 3D scatter plot of points with an array of height values for data using ListPointPlot3D:

Wolfram Language code: ListPointPlot3D[data]

Use ListPlot3D to plot data as a surface:

Wolfram Language code: ListPlot3D[data]

Use ListDensityPlot to generate a density plot from the height values of data:

Wolfram Language code: ListDensityPlot[data]

Use ListContourPlot to generate a contour plot instead:

Wolfram Language code: ListContourPlot[data]
    

This constructs a Demonstration of data plotting:

Wolfram Language code: Manipulate[ListPolarPlot[Table[Cos[i / n] ^ m, {i, -k Pi, t Pi, Pi / d}], PlotStyle -> {PointSize[s], Red}, ImageSize -> {400, 400}, Axes -> None, PlotRange -> {{-1.1, 1.1}, {-1.1, 1.1}}], {{n, 0.32}, 0.1, 5, 0.01}, {m, 1, 4, 1}, {{t, 4.14}, 2, 6}, {{d, 100}, 10, 200, 10}, {{k, 4}, -1.5, 8}, {{s, 0.006}, 0.003, 0.01, 0.001}]