WOLFRAM

Wolfram Language & System Documentation Center

"ByteArray" (Compiled Type)

"ByteArray"

represents a one-dimensional array of bytes.

Details

  • "ByteArray" can be used in Typed and related constructs to specify a type.
  • "ByteArray" objects are automatically memory managed.

Constructors

  • ByteArray["string"] constructs a "ByteArray" object by extracting byte values from a Base64-encoded string.
  • ByteArray[na] constructs a copy of the array na, where na has the type "NumericArray"::["UnsignedInteger8", 1].
  • CreateTypeInstance["ByteArray",len] constructs a byte array of length len.
  • CreateTypeInstance["ByteArray",byte,len] constructs a byte array of length len filled with byte values.

Conversions

    Expressions

  • "ByteArray" objects can be converted to and from ByteArray expressions.

    • "NumericArray"

  • "ByteArray" objects can be converted to and from "NumericArray"::["UnsignedInteger8",1] objects.

Runtime Errors

    ArrayPartError

  • Operations that require extracting elements from a "ByteArray" can give a runtime error if those elements do not exist.

    • Cast

  • Casting from or to a "ByteArray" object can give a runtime error if the object cannot be converted to the target type.

Examples

open all close all

Basic Examples  (2)

"ByteArray" can be used as input or output for a CompiledCodeFunction:

Wolfram Language code: cf = FunctionCompile[Function[Typed[ba, "ByteArray"], ba]]
Wolfram Language code: cf[ByteArray[{1, 2, 3}]]

Create a "ByteArray" in compiled code:

Wolfram Language code: func = FunctionCompile@Function[Typed[str, "String"], ByteArray[str] ]
Wolfram Language code: func["AQIDBAUGBwg="]

Scope  (8)

Construction  (4)

Construct a "ByteArray" from a string:

Wolfram Language code: func = FunctionCompile@Function[Typed[str, "String"], ByteArray[str] ]
Wolfram Language code: func["AQIDBAUGBwg="]

Construct a "ByteArray" from a numeric array:

Wolfram Language code: func = FunctionCompile@Function[Typed[na, "NumericArray"::["UnsignedInteger8", 1]], ByteArray[na] ]
Wolfram Language code: func[NumericArray[{1, 2, 3}, "UnsignedInteger8"]]

Create a "ByteArray" instance of a given length:

Wolfram Language code: func = FunctionCompile@Function[Typed[len, "MachineInteger"], CreateTypeInstance["ByteArray", len] ]
Wolfram Language code: Length[func[10]]

Note that the created byte array is filled with random values:

Wolfram Language code: Normal[func[10]]

Create a "ByteArray" instance of a given length filled with an initial value:

Wolfram Language code: func = FunctionCompile@Function[{Typed[byte, "UnsignedInteger8"], Typed[len, "MachineInteger"]}, CreateTypeInstance["ByteArray", byte, len] ]
Wolfram Language code: Normal[func[42, 10]]

Conversion  (4)

Convert a "ByteArray" to a "NumericArray":

Wolfram Language code: func = FunctionCompile@Function[{Typed[ba, "ByteArray"]}, Cast[ba, "NumericArray"::["UnsignedInteger8", 1]] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

Convert a "ByteArray" from a "NumericArray":

Wolfram Language code: func = FunctionCompile@Function[{Typed[na, "NumericArray"::["UnsignedInteger8", 1]]}, Cast[na, "ByteArray"] ]
Wolfram Language code: func[NumericArray[{1, 2, 3}, "UnsignedInteger8"]]

Convert a "ByteArray" to an "InertExpression":

Wolfram Language code: func = FunctionCompile@Function[{Typed[ba, "ByteArray"]}, Cast[ba, "InertExpression"] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

Convert a "ByteArray" from an "InertExpression":

Wolfram Language code: func = FunctionCompile@Function[{Typed[expr, "InertExpression"]}, Cast[expr, "ByteArray"] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

Properties & Relations  (5)

Get the length:

Wolfram Language code: func = FunctionCompile@Function[Typed[ba, "ByteArray"], Length[ba] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

Get the head:

Wolfram Language code: func = FunctionCompile@Function[Typed[ba, "ByteArray"], Head[ba] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

Get an element:

Wolfram Language code: func = FunctionCompile@Function[{Typed[ba, "ByteArray"], Typed[x, "MachineInteger"]}, ba[[x]] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}], 2]

Convert a "ByteArray" to a normal expression:

Wolfram Language code: func = FunctionCompile@Function[{Typed[ba, "ByteArray"]}, Normal[ba] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

Convert a "ByteArray" to a string:

Wolfram Language code: func = FunctionCompile@Function[{Typed[ba, "ByteArray"]}, ToString[ba] ]
Wolfram Language code: func[ByteArray[{1, 2, 3}]]

Possible Issues  (2)

Part access can cause a runtime error if the element does not exist:

Wolfram Language code: func = FunctionCompile[Function[Typed[ba, "ByteArray"], ba[[4]]]]; func[ByteArray[{1, 2, 3}]]

Casting can cause a runtime error if the object cannot be converted to the target type:

Wolfram Language code: func = FunctionCompile[Function[Typed[expr, "InertExpression"], Cast[expr, "ByteArray"]]]; func[4]