WOLFRAM

Wolfram Language & System Documentation Center

"CArray" (Compiled Type)

"CArray"::[type]

represents an array type compatible with C, containing elements of the specified type.

Details

  • "CArray" can be used in Typed and related constructs to specify a type.
  • Objects with type "CArray" are not automatically memory managed and must be manually freed.
  • "CArray"::[t] is equivalent to t* in C.
  • "CArray" can be used when interfacing with external libraries that are compatible with C.
  • Internally, objects with type "CArray" are represented with pointers.

Constructors

Properties

  • Information[carr,"ElementType"] for carr of type "CArray"::[type] gives type .
  • FromRawPointer[carr,offset] indexes the C array carr. Indexes start with 0.

Conversions

Runtime Errors

  • Indexing is an unsafe operation, and indexing past the end of a C array can lead to crashes.

Examples

open all close all

Basic Examples  (3)

Create a memory-managed C array, and then access one of its elements:

Wolfram Language code: cf = FunctionCompile[Function[{}, Module[{carr}, carr = CreateTypeInstance["Managed"::["CArray"::["MachineInteger"]], {3, 1, 4}]; FromRawPointer[carr, 2] ]]]
Wolfram Language code: cf[]

Represent a function from an external library that takes a C array as an argument:

Wolfram Language code: dec = LibraryFunctionDeclaration["sumArray", "compilerDemoBase", {"CArray"::["CLong"], "CLong"} -> "CInt"];

Compile a program that creates a C array and calls the function:

Wolfram Language code: cf = FunctionCompile[dec, Function[Typed[arg, "ListVector"::["CLong"]], Module[{carr}, carr = CreateTypeInstance["Managed"::["CArray"::["CLong"]], arg]; LibraryFunction["sumArray"][carr, Length[arg]] ] ]]
Wolfram Language code: cf[Range[100]]

Compile a program that creates a C array and then frees it:

Wolfram Language code: cf = FunctionCompile[ Function[Typed[arg, "MachineInteger"], Module[{carr}, carr = CreateTypeInstance[ "CArray"::["Real64"], arg]; DeleteObject[carr] ] ]]
Wolfram Language code: cf[10]

Possible Issues  (1)

C arrays created outside of a "Managed" object are not automatically memory managed, and must be freed manually. Compile a function that creates unmanaged C arrays:

Wolfram Language code: cf1 = FunctionCompile[Function[{}, With[{carr = CreateTypeInstance["CArray"::["Integer8"], 100]}, Null ]]]

The function leaks memory:

Wolfram Language code: With[{before = MemoryInUse[]}, Do[cf1[], 10];MemoryInUse[] - before]

Use DeleteObject to manually free the C arrays:

Wolfram Language code: cf2 = FunctionCompile[Function[{}, With[{carr = CreateTypeInstance["CArray"::["Integer8"], 100]}, DeleteObject[carr] ]]]

The resulting function does not leak memory:

Wolfram Language code: With[{before = MemoryInUse[]}, Do[cf2[], 10];MemoryInUse[] - before]