WOLFRAM

Wolfram Language & System Documentation Center
Structure Matrices and Convolution Kernels

Structure Matrices and Convolution Kernels

DiskMatrix[r]
a radius r disk of 1s inside a (2r+1)×(2r+1) matrix of 0s
DiskMatrix[{r1,…}]
an ellipsoid of 1s with radii r1, … inside an array of dimension (2r1+1)× …
DiskMatrix[{r1, …},{n1, …}]
an ellipsoid with radii r1, … inside an array of dimension n1× …
DiamondMatrix[{r1,…},{n1,…}]
a diamond of 1s with radii r1, … inside an array of dimension n1× …
BoxMatrix[{r1,…},{n1,…}]
a box of 1s with radii r1, … inside an array of dimension n1× …
CrossMatrix[{r1,…},{n1,…}]
a cross of 1s with radii r1, … inside an array of dimension n1× …
Constructing matrices with special shapes.
This creates a matrix of 0s containing a radius 4 diamond of 1s. The result is a 9×9 matrix:
Wolfram Language code: DiamondMatrix[4]//MatrixForm
The size of the matrix can be explicitly specified:
Wolfram Language code: BoxMatrix[2, 10]//MatrixForm
Wolfram Language code: DiamondMatrix[7, {10, 20}]//MatrixForm
This creates a matrix containing an ellipse and displays it graphically:
Wolfram Language code: ArrayPlot[DiskMatrix[{100, 200}, {251, 501}]]
Here is the same matrix, converted to an Image. Note that 1 is White and 0 is Black:
Wolfram Language code: Image[DiskMatrix[{100, 200}, {251, 501}]]
The shape matrix family of functions can make arrays with any rank:
Wolfram Language code: Image /@ CrossMatrix[{3, 5, 10}]
Wolfram Language code: Graphics3D[Cuboid /@ Position[DiskMatrix[{12, 10, 8}], 1], BoxRatios -> Automatic]
GaussianMatrix[r]
a (2r+1)×(2r+1) matrix that samples a Gaussian
GaussianMatrix[{r,σ}]
a (2r+1)×(2r+1) matrix that samples a Gaussian with standard deviation σ
GaussianMatrix[{{r1,…},{σ1,…}}]
a (2r1+1)× … array that samples a Gaussian with standard deviation σi in the i th direction
GaussianMatrix[{{r1,…},{σ1,…}},{n1,…}]
a (2r1+1)× … array that samples the ni th discrete derivative in the i th direction of a Gaussian with standard deviation σi in the i th direction
Gaussian matrices.
This creates a radius 2 Gaussian kernel:
Wolfram Language code: GaussianMatrix[2]//MatrixForm
GaussianMatrix can construct arrays with any rank:
Wolfram Language code: GaussianMatrix[{{2}}]
By default, the matrix elements are numerical and constructed to behave optimally under discrete convolution. Using WorkingPrecision->Infinity will produce an exact representation:
Wolfram Language code: GaussianMatrix[1, WorkingPrecision -> Infinity]//MatrixForm
Use Method->"Gaussian" to sample a true Gaussian:
Wolfram Language code: GaussianMatrix[2, Method -> "Gaussian", WorkingPrecision -> Infinity]//MatrixForm
This shows a comparison of the two types of Gaussians:
Wolfram Language code: ListLinePlot[{GaussianMatrix[{{10}}, Method -> "Bessel"], GaussianMatrix[{{10}}, Method -> "Gaussian"]}, DataRange -> {-10, 10}, PlotStyle -> {Blue, Red}]
This specifies a standard deviation of 1 in both directions of a rectangular Gaussian matrix:
Wolfram Language code: GaussianMatrix[{{3, 2}, 1}]//MatrixForm
Plot the second derivative of the Gaussian in the row direction:
Wolfram Language code: ListPlot3D[GaussianMatrix[10, {2, 0}], DataRange -> {{-10, 10}, {-10, 10}}]
Sum derivatives by using nested List objects in the second argument. For example, this plots the Laplacian:
Wolfram Language code: ListDensityPlot[GaussianMatrix[10, {{2, 0}, {0, 2}}], DataRange -> {{-10, 10}, {-10, 10}}]
This finds the length of the vector which has a minimum of 95% of the integrated fraction of the Gaussian with standard deviation 1:
Wolfram Language code: Dimensions[GaussianMatrix[{{Automatic}, {1}, {.95}}]]
This finds the dimensions of the matrix which, in each direction, has a minimum of 95% of the integrated fraction of the Gaussian with standard deviation 1:
Wolfram Language code: Dimensions[GaussianMatrix[{Automatic, 1, .95}]]
Wolfram Language code: Dimensions[GaussianMatrix[{Automatic, 1, {.85, .95, .99}}]]