WOLFRAM

Wolfram Language & System Documentation Center

ElementMeshRegionProduct[mesh1,mesh2]

represents the Cartesian product of the ElementMesh mesh1 and mesh2.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
"RegionMarkerFunction"  
Applications  
See Also
Tech Notes
Related Guides
Cite this Page
NDSolve`FEM`
NDSolve`FEM`

ElementMeshRegionProduct

ElementMeshRegionProduct[mesh1,mesh2]

represents the Cartesian product of the ElementMesh mesh1 and mesh2.

Details and Options

  • ElementMeshRegionProduct is also known as outer product region or region extrusion.
  • ElementMeshRegionProduct[mesh1,mesh2] represents the region .
  • The embedding dimension of the product region is the sum of embedding dimensions, and the geometric dimension is the sum of geometric dimensions.
  • The highest product dimension supported is 3.
  • ElementMeshRegionProduct has the same options as ToElementMesh, with the following additions and changes:
  • "RegionMarkerFunction" Nonespecify region markers

Examples

open all close all

Basic Examples  (2)

Load the package:

Wolfram Language code: Needs["NDSolve`FEM`"]

Create an ElementMesh:

Wolfram Language code: mesh = ToElementMesh[Line[{{0}, {1}}]]

Compute the ElementMesh region product:

Wolfram Language code: productMesh = ElementMeshRegionProduct[mesh, mesh]

Visualize the region product mesh:

Wolfram Language code: productMesh["Wireframe"]

Create three ElementMesh instances:

Wolfram Language code: meshX = ToElementMesh[Line[{{0}, {2}}]]; meshY = ToElementMesh[Line[{{0}, {1}}]]; meshZ = ToElementMesh[Line[{{0}, {3}}]];

Compute the ElementMesh region product:

Wolfram Language code: productMesh = ElementMeshRegionProduct[meshX, meshY, meshZ]

Visualize the region product mesh:

Wolfram Language code: productMesh["Wireframe"]

Scope  (1)

Create two ElementMesh instances:

Wolfram Language code: meshXY = ToElementMesh[Disk[], MaxCellMeasure -> 0.1]; meshZ = ToElementMesh[Line[{{0}, {3}}]];

Extrude the first ElementMesh with the second by forming a region product:

Wolfram Language code: productMesh = ElementMeshRegionProduct[meshXY, meshZ]

Visualize the region product mesh:

Wolfram Language code: productMesh["Wireframe"]

Options  (2)

"RegionMarkerFunction"  (2)

Create a marker association and a region member function:

Wolfram Language code: regs = <|"solid" -> 10, "fluid" -> 20|>; rmf = RegionMember[Rectangle[{1.2, 0}, {1.8, 3}]];

Define a region marker function:

Wolfram Language code: myRegionMarkerFunction = With[{rmf = rmf, rs = regs["solid"], rf = regs["fluid"]}, If[rmf[#], rs, rf]&];

Create ElementMesh that is used in each direction:

Wolfram Language code: mesh = ToElementMesh[Line[{{0.}, {3.}}]];

Compute the ElementMesh region product:

Wolfram Language code: mesh = ElementMeshRegionProduct[mesh, mesh, "RegionMarkerFunction" -> myRegionMarkerFunction]

Inspect the "MeshElementMarkerUnion" of the generated mesh:

Wolfram Language code: mesh["MeshElementMarkerUnion"]

Visualize the region product mesh with the region markers:

Wolfram Language code: Show[mesh["Wireframe"["MeshElementStyle" -> {Directive[FaceForm[Red]], Directive[FaceForm[Green]]}]], AspectRatio -> 1]

Create a marker association and a region member function:

Wolfram Language code: regs = <|"left" -> 1, "central" -> 3, "right" -> 2|>; rLeft = RegionMember[Cuboid[{0, 0, 0}, {0.8, 2, 2}]]; rCentral = RegionMember[Cuboid[{0.8, 0, 0}, {1.2, 2, 2}]]; rRight = RegionMember[Cuboid[{1.2, 0, 0}, {2, 2, 2}]];

Define a region marker function:

Wolfram Language code: myRegionMarkerFunction = With[{rmf = rmf, rl = regs["left"], rc = regs["central"], rr = regs["right"]}, If[rLeft[#], rl, If[rCentral[#], rc, rr]]&];

Create ElementMesh that is used in each direction:

Wolfram Language code: mesh = ToElementMesh[Line[{{0.}, {2.}}]];

Compute the ElementMesh region product:

Wolfram Language code: mesh = ElementMeshRegionProduct[mesh, mesh, mesh, "RegionMarkerFunction" -> myRegionMarkerFunction]

Inspect the "MeshElementMarkerUnion" of the generated mesh:

Wolfram Language code: mesh["MeshElementMarkerUnion"]

Visualize the region product mesh with the region markers:

Wolfram Language code: Show[Map[mesh["Wireframe"[ElementMarker == #[[1]], "MeshElement" -> "MeshElements", "ElementMeshDirective" -> Directive[EdgeForm[], FaceForm[#[[2]]]]]]&, {{1, Green}, {2, Orange}, {3, Red}}] , PlotRange -> {All, {1, 2}, All}]

Applications  (2)

Create a 2D graded mesh from a product of two 1D graded meshes:

Wolfram Language code: mesh = ToGradedMesh[Line[{{0}, {2}}], <| "Alignment" -> "Left"|>]; productMesh = ElementMeshRegionProduct[mesh, mesh]; productMesh["Wireframe"]

Create a 1D graded mesh with a "Central" point distribution:

Wolfram Language code: meshX = ToGradedMesh[Line[{{0}, {2}}], <|"Alignment" -> "Central"|>];

Create a second 1D graded mesh with a "Central" point distribution and 50 elements:

Wolfram Language code: meshY = ToGradedMesh[Line[{{0}, {1}}], <|"Alignment" -> "Central", "ElementCount" -> 50|>];

Construct a region product:

Wolfram Language code: productMesh = ElementMeshRegionProduct[meshX, meshY]

Visualize the region product of the anisotropic mesh:

Wolfram Language code: productMesh["Wireframe"]

Create a third 1D graded mesh with a "BothEnds" point distribution, 50 elements and an endpoint distance of 1/200:

Wolfram Language code: meshZ = ToGradedMesh[Line[{{0}, {1}}], <| "Alignment" -> "BothEnds", "ElementCount" -> 50, "MinimalDistance" -> 1 / 200|>]

Create the region product:

Wolfram Language code: productMesh = ElementMeshRegionProduct[productMesh, meshZ]

Visualize the 3D graded mesh:

Wolfram Language code: productMesh["Wireframe"]
Wolfram Research (2021), ElementMeshRegionProduct, Wolfram Language function, https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshRegionProduct.html (updated 2023).

Text

Wolfram Research (2021), ElementMeshRegionProduct, Wolfram Language function, https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshRegionProduct.html (updated 2023).

CMS

Wolfram Language. 2021. "ElementMeshRegionProduct." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshRegionProduct.html.

APA

Wolfram Language. (2021). ElementMeshRegionProduct. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshRegionProduct.html

BibTeX

@misc{reference.wolfram_2026_elementmeshregionproduct, author="Wolfram Research", title="{ElementMeshRegionProduct}", year="2023", howpublished="\url{https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshRegionProduct.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_elementmeshregionproduct, organization={Wolfram Research}, title={ElementMeshRegionProduct}, year={2023}, url={https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshRegionProduct.html}, note=[Accessed: 13-June-2026]}