WOLFRAM

Wolfram Language & System Documentation Center

$ContextAliases

is a global variable that gives an association with mappings from aliases to contexts.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Creating Context Aliases  
Using Context Aliases  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
History
Cite this Page

$ContextAliases

$ContextAliases

is a global variable that gives an association with mappings from aliases to contexts.

Details

  • $ContextAliases takes the form <|"alias1`""context1`","alias2`""context2`",…|>, where aliasi can be any string of characters that could be used to create a legal symbol name. contexti must be a fully qualified context name.
  • An alias can be used in place of a fully qualified context when referring to symbols. For a given symbol context`symbol, the name alias`symbol may be used in its place.
  • $ContextAliases can be modified directly. It is also updated automatically by calls to Needs, EndPackage and End. »

Examples

open all close all

Basic Examples  (1)

Define a symbol in a specific context:

Wolfram Language code: Context1`Context2`Square[x_] := x ^ 2

Create an alias for Context1`Context2`:

Wolfram Language code: $ContextAliases["cc`"] = "Context1`Context2`";

Use the alias to reference the symbol:

Wolfram Language code: cc`Square[5]

Delete the alias:

Wolfram Language code: $ContextAliases["cc`"]=.

Scope  (8)

Creating Context Aliases  (4)

$ContextAliases must be an association with entries of the form "alias""context`":

Wolfram Language code: $ContextAliases = "NewContext`"

Aliases cannot represent relative contexts:

Wolfram Language code: $ContextAliases["relative`"] = "`NewContext`"

Aliases must form legal symbol names:

Wolfram Language code: $ContextAliases["1701`"] = "NewContext`"
Wolfram Language code: $ContextAliases["ncc1701`"] = "NewContext`"

Needs can create a context alias:

Wolfram Language code: Needs["Developer`" -> "d`"] $ContextAliases["d`"]

Use PackedArrayQ from the Developer Utilities Package:

Wolfram Language code: d`PackedArrayQ[Range[10]]

Since "Developer`" is not on $ContextPath, the unqualified symbol name is not resolved:

Wolfram Language code: PackedArrayQ[Range[10]]

Using Context Aliases  (4)

Aliases are resolved before creating new symbols:

Wolfram Language code: $ContextAliases["abc`"] = "ExampleContext`"; abc`newsymbol

An alias may represent multiple levels of contexts:

Wolfram Language code: $ContextAliases["es`"] = "ExampleContext1`SubContext2`"; es`newsymbol

All ways of typing in a symbol respect context aliases:

Wolfram Language code: $ContextAliases["abc`"] = "ExampleContext`"; DeleteDuplicates[{abc`x, Symbol["abc`x"], ToExpression["abc`x"]}]

Clear a single alias:

Wolfram Language code: $ContextAliases = <|"alias1`" -> "Context1`", "alias2`" -> "Context2`"|>; $ContextAliases["alias1`"]=. $ContextAliases

Clear all context aliases:

Wolfram Language code: $ContextAliases = <|"alias1`" -> "Context1`", "alias2`" -> "Context2`"|>; $ContextAliases=. $ContextAliases

Properties & Relations  (9)

Context aliases work in ToExpression:

Wolfram Language code: NewContext`fun[x_] := x ^ 2; $ContextAliases["abc`"] = "NewContext`"; ToExpression["abc`fun[x]"]

A context alias is resolved in held evaluations:

Wolfram Language code: $ContextAliases["abc`"] = "NewContext`"; Hold[abc`newSymbol]

Symbol resolves context aliases:

Wolfram Language code: $ContextAliases["abc`"] = "NewContext`"; abc`newSymbol Symbol["abc`newSymbol"]

Changes made to aliases after BeginPackage will be restored after the matching EndPackage:

Wolfram Language code: BeginPackage["MyPackage`"]; Needs["Experimental`" -> "ep`"]; $ContextAliases["ep2`"] = "ExamplePackage2`"; EndPackage[]; {$ContextAliases["ep`"], $ContextAliases["ep2`"]}

End restores $ContextAliases to the value it had before the matching Begin:

Wolfram Language code: Begin["`Private`"]; $ContextAliases["ep`"] = "ExamplePackage`"; End[]; $ContextAliases

Names resolves context aliases by default:

Wolfram Language code: $ContextAliases["abc`"] = "NewContext`"; abc`newSymbol; Names["abc`newSymbol"]

Use the ResolveContextAliases option to prevent alias resolution:

Wolfram Language code: Names["abc`newSymbol", ResolveContextAliases -> False]

NameQ behaves identically:

Wolfram Language code: {NameQ["abc`newSymbol"], NameQ["abc`newSymbol", ResolveContextAliases -> False]}

Contexts resolves aliases by default:

Wolfram Language code: $ContextAliases["abc`"] = "NewContext`"; abc`newSymbol; Contexts["abc`"]

Use the ResolveContextAliases option to prevent alias resolution:

Wolfram Language code: Contexts["abc`", ResolveContextAliases -> False]

Information resolves aliases by default:

Wolfram Language code: $ContextAliases["abc`"] = "NewContext`"; abc`newSymbol; Information["abc`newSymbol"]

Information also uses aliases when resolving string patterns:

Wolfram Language code: Information["a*c`newSymbol"]

Use the ResolveContextAliases option to prevent alias resolution:

Wolfram Language code: Information["abc`newSymbol", ResolveContextAliases -> False]

An active alias cannot be added to $ContextPath:

Wolfram Language code: $ContextAliases["abc`"] = "NewContext`"; AppendTo[$ContextPath, "abc`"]; $ContextPath

Possible Issues  (1)

Aliases can mask existing contexts:

Wolfram Language code: cont`x = 7;
Wolfram Language code: $ContextAliases["cont`"] = "othercont`"

Because of the aliases, the symbol cont`x is not accessible:

Wolfram Language code: cont`x

Removing the clashing alias will restore access to the masked context:

Wolfram Language code: $ContextAliases["cont`"]=.
Wolfram Language code: cont`x
Wolfram Research (2021), $ContextAliases, Wolfram Language function, https://reference.wolfram.com/language/ref/$ContextAliases.html.

Text

Wolfram Research (2021), $ContextAliases, Wolfram Language function, https://reference.wolfram.com/language/ref/$ContextAliases.html.

CMS

Wolfram Language. 2021. "$ContextAliases." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/$ContextAliases.html.

APA

Wolfram Language. (2021). $ContextAliases. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/$ContextAliases.html

BibTeX

@misc{reference.wolfram_2026_$contextaliases, author="Wolfram Research", title="{$ContextAliases}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/$ContextAliases.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_$contextaliases, organization={Wolfram Research}, title={$ContextAliases}, year={2021}, url={https://reference.wolfram.com/language/ref/$ContextAliases.html}, note=[Accessed: 13-June-2026]}