WOLFRAM

Wolfram Language & System Documentation Center

AllMatch[{e1,e2,…},form]

yields True if ei matches the pattern form for all of the ei.

AllMatch[expr,form,level]

tests parts of expr at level level.

AllMatch[form]

represents an operator form of AllMatch that can be applied to an expression.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
Possible Issues  
See Also
History
Cite this Page

AllMatch

AllMatch[{e1,e2,…},form]

yields True if ei matches the pattern form for all of the ei.

AllMatch[expr,form,level]

tests parts of expr at level level.

AllMatch[form]

represents an operator form of AllMatch that can be applied to an expression.

Details

Examples

open all close all

Basic Examples  (4)

Check if all elements of a list match a pattern:

Wolfram Language code: AllMatch[{x ^ 2, x ^ 3, x ^ 5, x ^ 6}, x ^ _]
Wolfram Language code: AllMatch[{x ^ 2, y ^ 3, x ^ 5, x ^ 6}, x ^ _]

Check if all elements of a matrix match a pattern:

Wolfram Language code: AllMatch[{{1, 2, 3}, {4, 5, 6}}, _Integer, 2]
Wolfram Language code: AllMatch[{{a, 2, c}, {4, e, 6}}, _Integer, 2]

Use the operator form of AllMatch:

Wolfram Language code: AllMatch[_Integer][{1, 2, 3, 4, 5}]

Check if all values of an association match a pattern:

Wolfram Language code: AllMatch[<|"a" -> 1, "b" -> 2, "c" -> 3|>, _Integer]

Scope  (4)

AllMatch may be applied to expressions with any head:

Wolfram Language code: AllMatch[f[1, 2, 3], _Integer]

AllMatch can operate on ragged expressions:

Wolfram Language code: AllMatch[{{1, 2, 3}, {4, 5}}, _Integer, 2]
Wolfram Language code: AllMatch[f[{1, 2, 3}, {4, 5}], _Integer, 2]

By default, AllMatch operates at level 1:

Wolfram Language code: AllMatch[4, _String]
Wolfram Language code: AllMatch[{}, _String]
Wolfram Language code: AllMatch[4, _String, 0]

Use Verbatim to test for a literal blank:

Wolfram Language code: AllMatch[f[_, _, _], Verbatim[_]]

Properties & Relations  (6)

AllMatch[list,form] is equivalent to NoneMatch[list,Except[form]]:

Wolfram Language code: {AllMatch[{1, 2, 3, 4, 5}, _Integer], NoneMatch[{1, 2, 3, 4, 5}, Except[_Integer]]}

AllMatch[list,form] works efficiently on sparse vectors:

Wolfram Language code: AllMatch[SparseArray[{1000 -> 2}, {1000000000000}], _Integer]

AllMatch[list,form] checks the parts of list in order, stopping as soon as form does not match:

Wolfram Language code: AllMatch[{1, 2, 3, 4, 5}, _ ? (OddQ @* Echo)]

AllMatch[list,form] is equivalent to AllTrue[list,MatchQ[form]]:

Wolfram Language code: {AllMatch[{1, 2, 3, 4, 5}, _Integer], AllTrue[{1, 2, 3, 4, 5}, MatchQ[_Integer]]}

AllMatch[{e1,e2,…},form] is equivalent to And[MatchQ[e1,form],MatchQ[e2,form],…]:

Wolfram Language code: {AllMatch[{1, 2, 3}, _Integer], MatchQ[1, _Integer] && MatchQ[2, _Integer] && MatchQ[3, _Integer]}

AllMatch[list,e1|e2|…] is equivalent to ContainsOnly[list,{e1,e2,…}]:

Wolfram Language code: {AllMatch[{a, a, b, a, b}, a | b], ContainsOnly[{a, a, b, a, b}, {a, b}]}

Possible Issues  (1)

For associations, AllMatch tests only values:

Wolfram Language code: AllMatch[<|a -> 1|>, 1]
Wolfram Language code: AllMatch[<|a -> 1|>, a]
Wolfram Research (2024), AllMatch, Wolfram Language function, https://reference.wolfram.com/language/ref/AllMatch.html.

Text

Wolfram Research (2024), AllMatch, Wolfram Language function, https://reference.wolfram.com/language/ref/AllMatch.html.

CMS

Wolfram Language. 2024. "AllMatch." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AllMatch.html.

APA

Wolfram Language. (2024). AllMatch. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AllMatch.html

BibTeX

@misc{reference.wolfram_2026_allmatch, author="Wolfram Research", title="{AllMatch}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/AllMatch.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_allmatch, organization={Wolfram Research}, title={AllMatch}, year={2024}, url={https://reference.wolfram.com/language/ref/AllMatch.html}, note=[Accessed: 13-June-2026]}