WOLFRAM

Wolfram Language & System Documentation Center

ChemicalInstance[chemical,<|qual1val1,qual2val2,|>]

represents a chemical whose qualifiers quali have values of vali.

ChemicalInstance[chemical,quantity]

represents a chemical quantified by quantity.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Chemical Objects  
Properties  
Generalizations & Extensions  
Applications  
Possible Issues  
See Also
Related Guides
History
Cite this Page

ChemicalInstance

ChemicalInstance[chemical,<|qual1val1,qual2val2,|>]

represents a chemical whose qualifiers quali have values of vali.

ChemicalInstance[chemical,quantity]

represents a chemical quantified by quantity.

Details

  • Possible forms for chemical include:
  • Atom[…]an atom
    BioSequence[…]a biomolecular sequence
    ChemicalFormula[…]a molecular entity with the given formula
    Entity[…]a chemical entity
    ExternalIdentifier[…]an external identifier
    Molecule[…]a molecule
    "identifier"a systematic chemical name, SMILES or InChI string
  • Chemical entities include "Chemical", "Element", "Isotope", "Mineral" and "Protein".
  • Typical quali qualifiers include:
  • "Amount"amount of substance
    "AtomCount"number of atoms
    "Mass"mass
    "MassDensity"density
    "MoleculeCount"number of molecules
    "Phase"phase of matter
    "Pressure"pressure
    "Temperature"temperature
    "Volume"volume
  • The quali can be physical quantity names, a QuantityVariable expression or a "PhysicalQuantity" Entity.
  • Properties "prop" of a ChemicalInstance obtained by ChemicalInstance[…]["prop"] include:
  • "Amount"amount of substance
    "AtomCount"number of atoms
    "Chemical"chemical object
    "Mass"mass
    "MoleculeCount"number of molecules
    "Quantity"quantity object
    "Volume"volume
  • ChemicalInstance[chemical,assoc]["prop"] will return the value for the specified property in assoc.

Examples

open all close all

Basic Examples  (2)

Represent a solid silver nanoparticle containing 40 atoms:

Wolfram Language code: ChemicalInstance[Entity["Element", "Silver"], <|"Atoms" -> Quantity[40, "Atoms"], "Phase" -> "Solid"|>]

Represent a measured amount of tin(IV) oxide using a milligram balance:

Wolfram Language code: ChemicalInstance[Entity["Chemical", "TinIVOxide"], <|"Mass" -> Quantity[Around[14.583, 0.0009], "Grams"]|>]

An equivalent specification:

Wolfram Language code: ChemicalInstance[Entity["Chemical", "TinIVOxide"], Quantity[Around[14.583, 0.0009], "Grams"]]

Scope  (10)

Chemical Objects  (6)

Represent a gold nanoparticle containing 30 atoms:

Wolfram Language code: ChemicalInstance[Atom["Au"], Quantity[30, "Atoms"]]

Represent 3 milligrams of a DNA sequence:

Wolfram Language code: ChemicalInstance[BioSequence["DNA", "ATAAACGTACGTTTTTAGGCT"], Quantity[3, "Milligrams"]]

Represent 3 mL of a new chemical with an empirical formula of :

Wolfram Language code: ChemicalInstance[ChemicalFormula["PaC8H8"], Quantity[Around[3., 0.1], "Milliliters"]]

Represent 50 micrograms of plutonium-239:

Wolfram Language code: ChemicalInstance[Entity["Isotope", "Plutonium239"], Quantity[50, "Micrograms"]]

Represent solid uranium(VI) oxide using an ExternalIdentifier:

Wolfram Language code: ChemicalInstance[Molecule[ExternalIdentifier["PubChemCompoundID", 74013]], <|"Phase" -> "Solid"|>]

Represent 6 millimoles of tungsten hexamethyl:

Wolfram Language code: ChemicalInstance[Molecule["C[W](C)(C)(C)(C)C"], Quantity[6, "Millimoles"]]

Properties  (4)

Extract the chemical:

Wolfram Language code: ChemicalInstance[Molecule["1,3-butadiene"], <|"Volume" -> Quantity[3, "Milliliters"], "MassDensity" -> Quantity[Around[0.64, 0.01], "Grams"/"Milliliters"], "Temperature" -> Quantity[-6, "DegreesCelsiusDifference"]|>]["Chemical"]
Wolfram Language code: ChemicalInstance[Entity["Chemical", "Water"], Quantity[Around[5.1, 0.05], "Milliliters"]]["Chemical"]

Extract the quantity:

Wolfram Language code: ChemicalInstance[Molecule["1,3-butadiene"], <|"Volume" -> Quantity[3, "Milliliters"], "MassDensity" -> Quantity[Around[0.64, 0.01], "Grams"/"Milliliters"], "Temperature" -> Quantity[-6, "DegreesCelsiusDifference"]|>]["Quantity"]
Wolfram Language code: ChemicalInstance[Entity["Chemical", "Water"], Quantity[Around[5.1, 0.05], "Milliliters"]]["Quantity"]

Compute the quantity corresponding to an extensive physical property:

Wolfram Language code: ChemicalInstance[Entity["Chemical", "ManganeseIVOxide"], Quantity[30, "Grams"]]["Amount"]
Wolfram Language code: ChemicalInstance[Entity["Chemical", "ManganeseIVOxide"], Quantity[30, "Grams"]]["MoleculeCount"]
Wolfram Language code: ChemicalInstance[Entity["Chemical", "ManganeseIVOxide"], Quantity[30, "Grams"]]["Volume"]

Get a chemical property using any qualifying data that is present:

Wolfram Language code: ChemicalInstance[Entity["Chemical", "PenicillinV"], <|"MassDensity" -> Quantity[Around[1.441, 0.005], "Grams" / "Centimeters"^3], "Volume" -> Quantity[Around[5.1, 0.05], "Milliliters"]|>]["MassDensity"]
Wolfram Language code: ChemicalInstance[Entity["Chemical", "PenicillinV"], Quantity[Around[5.1, 0.05], "Milliliters"]]["MassDensity"]

Generalizations & Extensions  (2)

Compute the volume symbolically when the density is unknown:

Wolfram Language code: ChemicalInstance[ChemicalFormula[{"U" -> 1, "O" -> 2, {"H" -> 2, "O" -> 1} -> 5}, Association["NetCharge" -> 2]], <|"Mass" -> Quantity[2, "Milligrams"], "MassDensity" -> Quantity[, "Grams" / "Milliliters"]|>]["Volume"]

Compute the amount of substance symbolically:

Wolfram Language code: ChemicalInstance[BioSequence["DNA", "ATAAACGTACGTTTTTAGGCT", {}], <|"Mass" -> Quantity[25, "Micrograms"], "MolarMass" -> Quantity[, "Grams" / "Moles"]|>]["Amount"]

Applications  (1)

Compare the number of atoms in 2 mg of each stable isotope of tin:

Wolfram Language code: BarChart[Map[ChemicalInstance[#, Quantity[2, "Milligrams"]]["AtomCount"]&, {Entity["Isotope", "Tin120"], Entity["Isotope", "Tin118"], Entity["Isotope", "Tin116"], Entity["Isotope", "Tin119"], Entity["Isotope", "Tin117"], Entity["Isotope", "Tin124"], Entity["Isotope", "Tin122"], Entity["Isotope", "Tin112"], Entity["Isotope", "Tin114"], Entity["Isotope", "Tin115"]}]]

Possible Issues  (2)

Computed properties require a quantity stored under a key corresponding to a physical quantity:

Wolfram Language code: ChemicalInstance[Entity["Chemical", "Methane"], <|"Phase" -> "Gas"|>]["Amount"]

Properties of a chemical at a nonstandard temperature and pressure may be unavailable:

Wolfram Language code: ChemicalInstance[Entity["Chemical", "1Butanol"], <|"Volume" -> Quantity[1, "Liters"], "Temperature" -> Quantity[400, "Kelvins"]|>]["Amount"]
Wolfram Research (2022), ChemicalInstance, Wolfram Language function, https://reference.wolfram.com/language/ref/ChemicalInstance.html.

Text

Wolfram Research (2022), ChemicalInstance, Wolfram Language function, https://reference.wolfram.com/language/ref/ChemicalInstance.html.

CMS

Wolfram Language. 2022. "ChemicalInstance." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ChemicalInstance.html.

APA

Wolfram Language. (2022). ChemicalInstance. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ChemicalInstance.html

BibTeX

@misc{reference.wolfram_2026_chemicalinstance, author="Wolfram Research", title="{ChemicalInstance}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/ChemicalInstance.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_chemicalinstance, organization={Wolfram Research}, title={ChemicalInstance}, year={2022}, url={https://reference.wolfram.com/language/ref/ChemicalInstance.html}, note=[Accessed: 12-June-2026]}