WOLFRAM

Wolfram Language & System Documentation Center

CirclePoints[n]

gives the positions of n points equally spaced around the unit circle.

CirclePoints[r,n]

gives the positions of n points equally spaced around a circle of radius r.

CirclePoints[{r,θ1},n]

starts at angle θ1 with respect to the axis.

CirclePoints[{x,y},rspec,n]

centers the circle at {x,y}.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
Interactive Examples  
Neat Examples  
See Also
Related Guides
History
Cite this Page

CirclePoints

CirclePoints[n]

gives the positions of n points equally spaced around the unit circle.

CirclePoints[r,n]

gives the positions of n points equally spaced around a circle of radius r.

CirclePoints[{r,θ1},n]

starts at angle θ1 with respect to the axis.

CirclePoints[{x,y},rspec,n]

centers the circle at {x,y}.

Details

  • For positive integer n, CirclePoints[n] generates a list of vertices for a regular n-sided polygon, oriented so its base is horizontal.
  • In CirclePoints[n], n does not have to be an exact integer. The angles between successive vectors are always .
  • Unless explicitly given as a Quantity object, the angle θ1 is assumed to be in radians, counterclockwise starting from the axis. (Multiply by Degree to convert from degrees.)
  • If the angle θ1 is not given, it is assumed to be π/n-π/2, so that for integer n the vectors correspond to a regular polygon with its base horizontal.
  • All arguments of CirclePoints except n can be symbolic. They can also be Quantity objects.

Examples

open all close all

Basic Examples  (3)

Corners of an equilateral triangle:

Wolfram Language code: CirclePoints[3]

Draw a pentagon:

Wolfram Language code: Graphics[Polygon[CirclePoints[5]]]

Draw unit vectors to the corners of a regular heptagon:

Wolfram Language code: Graphics[Arrow[{{0, 0}, #}]& /@ CirclePoints[7]]

Scope  (6)

Corners of a centered square with horizontal and vertical sides:

Wolfram Language code: CirclePoints[4]

Corners of a square of size :

Wolfram Language code: CirclePoints[s / Sqrt[2], 4]

Four unitary vectors aligned with the axes:

Wolfram Language code: CirclePoints[{1, 0}, 4]

Displace them to a different point:

Wolfram Language code: CirclePoints[{x, y}, {1, 0}, 4]

The four corners of an arbitrary square, at any point and any size or orientation:

Wolfram Language code: CirclePoints[{x, y}, {s, θ}, 4]

Use a Quantity radius:

Wolfram Language code: CirclePoints[Quantity[2, "Meters"], 4]

Specify the initial angle as a Quantity object:

Wolfram Language code: CirclePoints[{2, Quantity[90, "AngularDegrees"]}, 4]

Draw polygons, with their lowest side oriented horizontally by default:

Wolfram Language code: Graphics /@ Polygon /@ CirclePoints /@ Range[3, 10]

Draw them all together, with opacity:

Wolfram Language code: Graphics[{Opacity[0.15], Table[Polygon[CirclePoints[n, n]], {n, 3, 10}]}]

Properties & Relations  (2)

CirclePoints returns pairs that can be reinterpreted as real and imaginary parts of the roots of unity:

Wolfram Language code: With[{n = 7}, Exp[2Pi I Range[0, n - 1] / n]]
Wolfram Language code: ComplexExpand[ReIm /@ %]
Wolfram Language code: % == CirclePoints[{1, 0}, 7]

CirclePoints is equivalent to a collection of AngleVector calls:

Wolfram Language code: CirclePoints[{1, 0}, 6]
Wolfram Language code: % === AngleVector /@ Most@Range[0, 2Pi, Pi / 3]

Interactive Examples  (1)

Construct polygons of different sizes and number of sides:

Wolfram Language code: Manipulate[Graphics[{Arrow[{{0, 0}, #}]& /@ CirclePoints[n], Opacity[0.7], Polygon[CirclePoints[r, n]]}, Axes -> True, PlotRange -> {{-1, 1}, {-1, 1}}], {{r, 0.5}, 0, 1}, {{n, 5}, 2, 10}]

Neat Examples  (2)

Combine Fold and CirclePoints:

Wolfram Language code: Manipulate[Graphics[Point[Fold[f[n], {{0, 0}}, {6k, 3k, k, 1}]]], {{k, 0.5}, 0, 1}, {{n, 4}, Range[3, 6]}, Initialization :> {f[n_][points_, d_] := Flatten[CirclePoints[#, d, n]& /@ points, 1]}]

Combine CirclePoints with BezierCurve:

Wolfram Language code: Graphics[Table[Rotate[ BezierCurve[{{0, 0}, #, {1, 0}}]& /@ CirclePoints[8], i Pi / 8], {i, 0, 16}]]
Wolfram Language code: Graphics[Table[Rotate[ BezierCurve[{{0, 0}, ##, {2, 0}}]& /@ CirclePoints[24], i Pi / 2, {0, 0}], {i, 0, 3}]]
Wolfram Research (2015), CirclePoints, Wolfram Language function, https://reference.wolfram.com/language/ref/CirclePoints.html.

Text

Wolfram Research (2015), CirclePoints, Wolfram Language function, https://reference.wolfram.com/language/ref/CirclePoints.html.

CMS

Wolfram Language. 2015. "CirclePoints." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CirclePoints.html.

APA

Wolfram Language. (2015). CirclePoints. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CirclePoints.html

BibTeX

@misc{reference.wolfram_2026_circlepoints, author="Wolfram Research", title="{CirclePoints}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/CirclePoints.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_circlepoints, organization={Wolfram Research}, title={CirclePoints}, year={2015}, url={https://reference.wolfram.com/language/ref/CirclePoints.html}, note=[Accessed: 12-June-2026]}