WOLFRAM

Wolfram Language & System Documentation Center

Cyclotomic[n,x]

gives the n^(th) cyclotomic polynomial in x.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

Cyclotomic

Cyclotomic[n,x]

gives the n^(th) cyclotomic polynomial in x.

Details

  • The cyclotomic polynomial of order is defined to be , where the product runs over integers less than that are relatively prime to .

Examples

open all close all

Basic Examples  (1)

Give the fifth cyclotomic polynomial:

Wolfram Language code: Cyclotomic[5, x]

The roots are the primitive fifth roots of :

Wolfram Language code: Solve[Cyclotomic[5, x] == 0, x]

Scope  (1)

TraditionalForm formatting:

Wolfram Language code: Cyclotomic[n, x]//TraditionalForm

Applications  (6)

Compare a factored polynomial with Cyclotomic:

Wolfram Language code: Factor[x ^ 11 - 1]
Wolfram Language code: Cyclotomic[11, x]

Values of successive cyclotomic polynomials at 1:

Wolfram Language code: Table[Cyclotomic[n, 1], {n, 2, 20}]

Calculate unique primes for which the decimal expansion of has a unique period:

Wolfram Language code: up[n_] := If[Length[#] === 1, #[[1, 1]]]&[FactorInteger[Cyclotomic[n, 10] / GCD[Cyclotomic[n, 10], n]]]
Wolfram Language code: Select[Table[up[n], {n, 30}], NumberQ]
Wolfram Language code: RealDigits[1 / %]//Column

Plot cyclotomic polynomials:

Wolfram Language code: Plot[Evaluate[Table[Cyclotomic[k, z], {k, 0, 10}]], {z, -1, 1}]

Plot arguments of roots of Cyclotomic:

Wolfram Language code: ListPlot[Table[{Arg[#], n}& /@ (z /. NSolve[Cyclotomic[n, z] == 0, z]), {n, 50}], PlotMarkers -> None]

Plot the degree and number of terms of cyclotomic polynomials:

Wolfram Language code: {ListPlot[Table[Exponent[Cyclotomic[n, x], x], {n, 500}]], ListPlot[Table[Length[Cyclotomic[n, x]], {n, 500}]]}

Properties & Relations  (7)

Integrate a cyclotomic polynomial:

Wolfram Language code: Integrate[1 / Cyclotomic[3, x], x]

Factor a cyclotomic polynomial over an extension field:

Wolfram Language code: Factor[Cyclotomic[5, x]]
Wolfram Language code: Factor[Cyclotomic[5, x], Extension -> {(-1) ^ (1 / 5)}]

Generate cyclotomic polynomials from a definition:

Wolfram Language code: c[n_, z_] := Collect[Product[z - E^(2 π I k/n), {k, Select[Range[n], CoprimeQ[#, n]&]}], z, FullSimplify]
Wolfram Language code: Table[c[n, z], {n, 10}]

Use an alternative definition, valid for :

Wolfram Language code: c[n_, z_] := Cancel[Times@@((1 - z ^ #) ^ MoebiusMu[n / #]& /@ Divisors[n])]
Wolfram Language code: Table[c[n, z], {n, 6}]
Wolfram Language code: Table[Cyclotomic[n, z], {n, 6}]

Form products of cyclotomic polynomials:

Wolfram Language code: f[n_, z_] := Expand[Times@@(Cyclotomic[#, z]& /@ Divisors[n])]
Wolfram Language code: Table[f[n, z], {n, 1, 8}]

Plot the Riemann surface of an inverse of a cyclotomic polynomial over the complex plane:

Wolfram Language code: ParametricPlot3D[Evaluate[{Re[Cyclotomic[10, x + I y]], Im[Cyclotomic[10, x + I y]], x}], {x, -2, 2}, {y, -2, 2}, Mesh -> False, BoxRatios -> 1]

Plot the complex roots of successive derivatives of the 50^(th) cyclotomic polynomial:

Wolfram Language code: Graphics[Point[Flatten[Map[{Re[#], Im[#]}&, Table[z /. NSolve[D[Cyclotomic[50, z], {z, k}] == 0, z], {k, EulerPhi[50] - 2}], {-1}], 1]]]

Neat Examples  (2)

The first cyclotomic polynomial with a coefficient other than 0, ±1:

Wolfram Language code: Cyclotomic[105, x]

Nonzero coefficients of successive cyclotomic polynomials:

Wolfram Language code: ArrayPlot[CoefficientList[Array[Cyclotomic[#, x]&, 40], x], ColorRules -> {0 -> StandardYellow, _ -> StandardBlue}]
Wolfram Research (1988), Cyclotomic, Wolfram Language function, https://reference.wolfram.com/language/ref/Cyclotomic.html.

Text

Wolfram Research (1988), Cyclotomic, Wolfram Language function, https://reference.wolfram.com/language/ref/Cyclotomic.html.

CMS

Wolfram Language. 1988. "Cyclotomic." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Cyclotomic.html.

APA

Wolfram Language. (1988). Cyclotomic. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Cyclotomic.html

BibTeX

@misc{reference.wolfram_2026_cyclotomic, author="Wolfram Research", title="{Cyclotomic}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/Cyclotomic.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_cyclotomic, organization={Wolfram Research}, title={Cyclotomic}, year={1988}, url={https://reference.wolfram.com/language/ref/Cyclotomic.html}, note=[Accessed: 13-June-2026]}