WOLFRAM

Wolfram Language & System Documentation Center

DEigenvalues[ℒ[u[x,y,…]],u,{x,y,…}∈Ω,n]

gives the n smallest magnitude eigenvalues for the linear differential operator ℒ over the region Ω.

DEigenvalues[eqns,u,t,{x,y,…}∈Ω,n]

gives the eigenvalues for solutions u of the time-dependent differential equations eqns.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
1D  
2D  
3D  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
History
Cite this Page

DEigenvalues

DEigenvalues[ℒ[u[x,y,…]],u,{x,y,…}∈Ω,n]

gives the n smallest magnitude eigenvalues for the linear differential operator ℒ over the region Ω.

DEigenvalues[eqns,u,t,{x,y,…}∈Ω,n]

gives the eigenvalues for solutions u of the time-dependent differential equations eqns.

Details and Options

  • DEigenvalues can compute eigenvalues for ordinary and partial differential operators with given boundary conditions.
  • DEigenvalues gives a list {λ1,…,λn} of the n smallest magnitude eigenvalues λi.
  • An eigenvalue and eigenfunction pair {λi,ui} for the differential operator ℒ satisfy ℒ[ui[x,y,…]]==λi ui[x,y,…].
  • Homogeneous DirichletCondition or NeumannValue boundary conditions may be included. Inhomogeneous boundary conditions will be replaced with corresponding homogeneous boundary conditions.
  • When no boundary condition is specified on the boundary ∂Ω, then this is equivalent to specifying a Neumann 0 condition.
  • The equations eqns are specified as in DSolve.
  • N[DEigenvalues[…]] calls NDEigenvalues for eigenvalues that cannot be computed symbolically.
  • The Assumptions option can be used to specify assumptions on parameters.

Examples

open all close all

Basic Examples  (2)

Find the 4 smallest eigenvalues of the Laplacian operator on [0,π]:

Wolfram Language code: DEigenvalues[{-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]}, u[x], {x, 0, π}, 4]

Compute the first 6 eigenvalues for a circular membrane with the edges clamped:

Wolfram Language code: DEigenvalues[{-Laplacian[u[x, y], {x, y}], DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Disk[], 6]//TraditionalForm
Wolfram Language code: N[%]

Scope  (17)

1D  (8)

Specify a Laplacian operator:

Wolfram Language code: ℒ = -Laplacian[u[x], {x}];

Specify homogeneous Dirichlet boundary conditions:

Wolfram Language code: ℬ = DirichletCondition[u[x] == 0, True];

Find the 5 smallest eigenvalues in an interval:

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x], {x, 0, π}, 5]

Specify a Laplacian operator:

Wolfram Language code: ℒ = -Laplacian[u[x], {x}];

Specify homogeneous Neumann boundary conditions:

Wolfram Language code: ℬ = NeumannValue[0, True];

Find the 5 smallest eigenvalues in an interval:

Wolfram Language code: DEigenvalues[ℒ + ℬ, u[x], {x, 0, π}, 5]

This is equivalent:

Wolfram Language code: DEigenvalues[ℒ, u[x], {x, 0, π}, 5]

Specify a Laplacian operator:

Wolfram Language code: ℒ = -Laplacian[u[x], {x}];

Specify a homogeneous Dirichlet boundary condition:

Wolfram Language code: ℬ1 = DirichletCondition[u[x] == 0, x == 0];

Specify a homogeneous Neumann boundary condition:

Wolfram Language code: ℬ2 = NeumannValue[0, x == π];

Find the 5 smallest eigenvalues in an interval:

Wolfram Language code: DEigenvalues[{ℒ + ℬ2, ℬ1}, u[x], {x, 0, π}, 5]

Find the ^(th) eigenvalue:

Wolfram Language code: FindSequenceFunction[%, n]//Factor

Find symbolic expressions for the eigenvalues of a Laplace operator:

Wolfram Language code: DEigenvalues[{-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]}, u[x], {x, a, b}, 3]

Specify a Laplacian operator:

Wolfram Language code: ℒ = -Laplacian[u[x], {x}];

Specify a homogeneous Dirichlet boundary condition:

Wolfram Language code: ℬ1 = DirichletCondition[u[x] == 0, x == π];

Specify a homogeneous nonzero Neumann boundary condition:

Wolfram Language code: ℬ2 = NeumannValue[-u[x] / 3, x == 0];

Find the 5 smallest eigenvalues in an interval:

Wolfram Language code: vals = DEigenvalues[{ℒ + ℬ2, ℬ1}, u[x], {x, 0, π}, 5];
Wolfram Language code: vals[[1]]//TraditionalForm

Specify an Airy operator:

Wolfram Language code: ℒ = -Laplacian[u[x], {x}] + x u[x];

Specify a homogeneous Dirichlet boundary condition:

Wolfram Language code: ℬ = DirichletCondition[u[x] == 0, True];

Find the 3 smallest eigenvalues in an interval:

Wolfram Language code: vals = DEigenvalues[{ℒ, ℬ}, u[x], {x, 0, 1}, 3];

The eigenvalues are roots of a transcendental equation:

Wolfram Language code: vals//TraditionalForm

Numerical approximations for the eigenvalues:

Wolfram Language code: N[vals, 20]

Specify an Airy operator:

Wolfram Language code: ℒ = -Laplacian[u[x], {x}] + x u[x];

Specify a homogeneous Neumann boundary condition:

Wolfram Language code: ℬ = NeumannValue[0, True];

Find the 5 smallest eigenvalues and eigenfunctions in an interval:

Wolfram Language code: vals = DEigenvalues[{ℒ + ℬ}, u[x], {x, 0, 1}, 5];

The eigenvalues are roots of a transcendental equation:

Wolfram Language code: vals[[1]]//TraditionalForm

Specify a heat equation with homogeneous Dirichlet boundary conditions:

Wolfram Language code: {ℒ, ℬ} = {D[u[t, x], t] == Laplacian[u[t, x], {x}], DirichletCondition[u[t, x] == 0, True]};

Find the 4 smallest eigenvalues:

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[t, x], t, {x, 0, π}, 4]

2D  (5)

Specify a Laplacian operator with homogeneous Dirichlet boundary conditions:

Wolfram Language code: {ℒ, ℬ} = {-Laplacian[u[x, y], {x, y}], DirichletCondition[u[x, y] == 0, True]};

Find the 9 smallest eigenvalues in a rectangle:

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y], {x, 0, π}, {y, 0, π}, 9]

Specify a Laplacian operator with homogeneous Neumann boundary conditions:

Wolfram Language code: ℒ = -Laplacian[u[x, y], {x, y}] + NeumannValue[0, True];

Find the 4 smallest eigenvalues in a rectangle:

Wolfram Language code: DEigenvalues[ℒ, u[x, y], {x, 0, π}, {y, 0, π}, 4]

Specify a Laplacian operator:

Wolfram Language code: ℒ = -Laplacian[u[x, y], {x, y}];

Specify homogeneous Dirichlet boundary conditions:

Wolfram Language code: ℬ = DirichletCondition[u[x, y] == 0, True];

Find the 4 smallest eigenvalues of the operator in a unit disk:

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y], {x, y}∈Disk[], 4]//TraditionalForm

Specify a Laplacian operator:

Wolfram Language code: ℒ = -Laplacian[u[x, y], {x, y}];

Specify homogeneous Dirichlet boundary conditions:

Wolfram Language code: ℬ = DirichletCondition[u[x, y] == 0, True];

Find the 6 smallest eigenvalues of the operator in a triangle:

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y], {x, y}∈Triangle[], 6]

Specify a Laplacian operator:

Wolfram Language code: ℒ = -Laplacian[u[x, y], {x, y}];

Specify homogeneous Dirichlet boundary conditions:

Wolfram Language code: ℬ = DirichletCondition[u[x, y] == 0, True];

Find the 4 smallest eigenvalues in a sector of a disk:

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y], {x, y}∈Disk[{0, 0}, 1, {0, Pi / 5}], 4]//TraditionalForm

3D  (4)

Specify a Laplacian operator:

Wolfram Language code: ℒ = -Laplacian[u[x, y, z], {x, y, z}];

Specify homogeneous Dirichlet boundary conditions:

Wolfram Language code: ℬ = DirichletCondition[u[x, y, z] == 0, True];

Find the 7 smallest eigenvalues in a cuboid:

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y, z], {x, y, z}∈Cuboid[{2, 1, 1}, {4, 2, 3}], 7]

Specify a Laplacian operator:

Wolfram Language code: ℒ = -Laplacian[u[x, y, z], {x, y, z}];

Specify homogeneous Dirichlet boundary conditions:

Wolfram Language code: ℬ = DirichletCondition[u[x, y, z] == 0, True];

Find the 5 smallest eigenvalues in a cylinder:

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y, z], {x, y, z}∈Cylinder[{{0, 0, 0}, {0, 0, 5}}, 2], 5]//TraditionalForm

Specify a Laplacian operator:

Wolfram Language code: ℒ = -Laplacian[u[x, y, z], {x, y, z}];

Specify homogeneous Dirichlet boundary conditions:

Wolfram Language code: ℬ = DirichletCondition[u[x, y, z] == 0, True];

Find the 7 smallest eigenvalues in a ball:

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y, z], {x, y, z}∈Ball[{0, 0, 0}, 2], 7]//TraditionalForm

Specify a Laplacian operator:

Wolfram Language code: ℒ = -Laplacian[u[x, y, z], {x, y, z}];

Specify homogeneous Dirichlet boundary conditions:

Wolfram Language code: ℬ = DirichletCondition[u[x, y, z] == 0, True];

Find the 7 smallest eigenvalues in a prism:

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y, z], {x, y, z}∈Prism[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 2}, {1, 0, 2}, {0, 1, 2}}], 7]

Properties & Relations  (3)

Use NDEigenvalues to find numerical eigenvalues and eigenvectors:

Wolfram Language code: {ℒ, ℬ} = {-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]};

Exact eigenvalues:

Wolfram Language code: exacteigvals = DEigenvalues[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3]

Numerical eigenvalues:

Wolfram Language code: numeigvals = NDEigenvalues[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3]

Use DEigensystem to find the eigensystem for a differential operator:

Wolfram Language code: {ℒ, ℬ} = {-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]};

Find the eigenvalues:

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3]

Find the eigensystem:

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3]
Wolfram Language code: vals

Apply N[DEigenvalues[…]] to invoke NDEigenvalues if symbolic evaluation fails:

Wolfram Language code: DEigenvalues[{-Laplacian[u[x, y], {x, y}] + E ^ (-x ^ 3 + x) u[x, y], DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Rectangle[], 4]
Wolfram Language code: N[%]

Possible Issues  (2)

Inhomogeneous Dirichlet conditions are replaced with homogeneous ones:

Wolfram Language code: DEigenvalues[{-Laplacian[u[x], {x}], DirichletCondition[u[x] == 1, True]}, u[x], {x, 0, 1}, 2]

The same result:

Wolfram Language code: DEigenvalues[{-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]}, u[x], {x, 0, 1}, 2]

Inhomogeneous Neumann values are replaced with homogeneous ones:

Wolfram Language code: DEigenvalues[{-Laplacian[u[x], {x}] + NeumannValue[1, True]}, u[x], {x, 0, 1}, 2]

The same result:

Wolfram Language code: DEigenvalues[-Laplacian[u[x], {x}], u[x], {x, 0, 1}, 2]
Wolfram Research (2015), DEigenvalues, Wolfram Language function, https://reference.wolfram.com/language/ref/DEigenvalues.html.

Text

Wolfram Research (2015), DEigenvalues, Wolfram Language function, https://reference.wolfram.com/language/ref/DEigenvalues.html.

CMS

Wolfram Language. 2015. "DEigenvalues." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DEigenvalues.html.

APA

Wolfram Language. (2015). DEigenvalues. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DEigenvalues.html

BibTeX

@misc{reference.wolfram_2026_deigenvalues, author="Wolfram Research", title="{DEigenvalues}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/DEigenvalues.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_deigenvalues, organization={Wolfram Research}, title={DEigenvalues}, year={2015}, url={https://reference.wolfram.com/language/ref/DEigenvalues.html}, note=[Accessed: 13-June-2026]}