WOLFRAM

Wolfram Language & System Documentation Center

DayCount[date1,date2]

gives the number of days from date1 to date2.

DayCount[date1,date2,daytype]

gives the number of days of the specified daytype from date1 to date2.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
CalendarType  
HolidayCalendar  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

DayCount

DayCount[date1,date2]

gives the number of days from date1 to date2.

DayCount[date1,date2,daytype]

gives the number of days of the specified daytype from date1 to date2.

Details and Options

  • Dates can be specified in the following forms:
  • DateObject[…]date object
    {y,m,d}year, month, day
    {y,m}the first day of the specified month
    {y}the first day of the first month of the year y
    "string"date as a string ("Jan. 1, 2000")
  • Possible day types are:
  • Allany calendar date (default)
    "Weekday"date considered a weekday
    "Weekend"date considered a weekend
    "Holiday" holiday according the HolidayCalendar
    "NonHoliday"date that is not a holiday
    "BusinessDay"non-holiday weekday
    "NonBusinessDay"holiday or weekend
    "WeekdayHoliday"holiday on a weekday
    "WeekendHoliday"holiday on a weekend
    "WeekendNonHoliday"non-holiday weekend
    Monday, Tuesday, …a specific day of the week
    "EndOfMonth"final day of a given month
    "BeginningOfMonth"first day of a given month
  • DayCount excludes the beginning date of the date range.
  • DayCount takes the following options:
  • CalendarTypeAutomaticcalendar in which the dates have been specified
    HolidayCalendar{"UnitedStates","Default"}holiday schedule and subspecification for the business day and holiday computations
  • In the Jewish calendar, the weekdays are Sunday through Thursday.

Examples

open all close all

Basic Examples  (4)

Print the number of days in a date range:

Wolfram Language code: With[{first = Today}, DayCount[first, DatePlus[first, {{1, "Month"}, {-1, "Day"}}]]]

Print the number of days that fall on a given day of the week:

Wolfram Language code: With[{first = Yesterday}, DayCount[first, DatePlus[first, {{1, "Month"}, {-1, "Day"}}], Sunday]]

Print the number of business days in a date range:

Wolfram Language code: With[{first = Tomorrow}, DayCount[first, DatePlus[first, {{1, "Month"}, {-1, "Day"}}], "BusinessDay"]]

Print all holidays in the current year, subject to the default holiday schedule:

Wolfram Language code: With[{first = Now}, DayCount[first, DatePlus[first, {{1, "Year"}, {-1, "Day"}}], "Holiday"]]

Scope  (2)

Compute the average number of weekend days this century:

Wolfram Language code: Mean[Table[DayCount[{i}, {i + 1}, "Weekend"], {i, 2001, 2100}]]//N

Compute the average number of non-weekend Swedish holidays this century:

Wolfram Language code: Mean[Table[DayCount[{i}, {i + 1}, "Holiday", HolidayCalendar -> "Sweden"], {i, 2001, 2100}]]//N

Options  (3)

CalendarType  (1)

Count all US holidays that will occur in the current Islamic calendar year:

Wolfram Language code: With[{first = CalendarConvert[Today, "Islamic"]}, DayCount[first, DatePlus[first, {{1, "Year"}, {-1, "Day"}}], "Holiday"]]

HolidayCalendar  (2)

Count holidays in India:

Wolfram Language code: With[{first = Take[DateList[], 1]}, DayCount[first, DatePlus[first, {{1, "Year"}, {-1, "Day"}}], "Holiday", HolidayCalendar -> "India"]]

Different markets within a country may have different holiday schedules:

Wolfram Language code: CalendarData["UnitedStates"]
Wolfram Language code: With[{first = DateObject[{2022, 4}]}, DayCount[first, DatePlus[first, {{1, "Month"}}], "Holiday", HolidayCalendar -> {"UnitedStates", "NYSE"}]]
Wolfram Language code: With[{first = DateObject[{2022, 4}]}, DayCount[first, DatePlus[first, {{1, "Month"}}], "Holiday"]]

Applications  (1)

Compute the number of days until the next US presidential election (first Tuesday after the first Monday in November of leap years):

Wolfram Language code: nextelection[date_] := Module[{year = 4Ceiling[date[[1]] / 4], nearest}, nearest = DatePlus[DayRange[{year, 11, 1}, {year, 11, 30}, Monday][[1]], 1]; If[QuantityMagnitude[DateDifference[date, nearest]] > 0, DayCount[date, nearest], DayCount[date, DatePlus[DayRange[{year + 4, 11, 1}, {year + 4, 11, 30}, Monday][[1]], 1]]]//Floor]; nextelection[DateList[]]

Properties & Relations  (2)

DayCount is equivalent to the length of the list output by DayRange for the same set of inputs:

Wolfram Language code: With[{first = Today}, Length[DayRange[first, DatePlus[first, {{1, "Month"}, {-1, "Day"}}], "IncludeEndPoints" -> {False, True}]] == DayCount[first, DatePlus[first, {{1, "Month"}, {-1, "Day"}}]]]

Holidays, weekends, and business days always add up to the total number of days in the range:

Wolfram Language code: DayCount[{2022}, {2023}, "Holiday"] + DayCount[{2022}, {2023}, "Weekend"] + DayCount[{2022}, {2023}, "BusinessDay"] - DayCount[{2022}, {2023}]
Wolfram Research (2012), DayCount, Wolfram Language function, https://reference.wolfram.com/language/ref/DayCount.html (updated 2025).

Text

Wolfram Research (2012), DayCount, Wolfram Language function, https://reference.wolfram.com/language/ref/DayCount.html (updated 2025).

CMS

Wolfram Language. 2012. "DayCount." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/DayCount.html.

APA

Wolfram Language. (2012). DayCount. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DayCount.html

BibTeX

@misc{reference.wolfram_2026_daycount, author="Wolfram Research", title="{DayCount}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/DayCount.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_daycount, organization={Wolfram Research}, title={DayCount}, year={2025}, url={https://reference.wolfram.com/language/ref/DayCount.html}, note=[Accessed: 13-June-2026]}