WOLFRAM

Wolfram Language & System Documentation Center

DistributionParameterAssumptions[dist]

gives a logical expression for assumptions on parameters in the symbolic distribution dist.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

DistributionParameterAssumptions

DistributionParameterAssumptions[dist]

gives a logical expression for assumptions on parameters in the symbolic distribution dist.

Details

Examples

open all close all

Basic Examples  (1)

Obtain parameter assumptions for a normal distribution:

Wolfram Language code: DistributionParameterAssumptions[NormalDistribution[μ, σ]]

Parameter assumptions for a multinomial distribution:

Wolfram Language code: DistributionParameterAssumptions[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]}]]

Scope  (4)

Obtain assumptions for distributions with combinations of numeric and symbolic parameters:

Wolfram Language code: dists = Table[GammaDistribution[a, b], {a, {α, 1}}, {b, {β, 2}}]//Flatten
Wolfram Language code: Table[{d, DistributionParameterAssumptions[d]}, {d, dists}]//TableForm

Get assumptions for univariate and multivariate discrete and continuous distributions:

Wolfram Language code: validDistributions = {GeometricDistribution[p], ParetoDistribution[k, a], BinormalDistribution[ρ], MultivariatePoissonDistribution[μ, {Subscript[μ, 1], Subscript[μ, 2]}]};
Wolfram Language code: Table[{dist, DistributionParameterAssumptions[dist]}, {dist, validDistributions}]//TableForm

Get assumptions for a derived distribution:

Wolfram Language code: tdist = TransformedDistribution[x ^ 3, xPoissonDistribution[μ]];
Wolfram Language code: DistributionParameterAssumptions[tdist]

Data distributions have no parameters, so the assumptions are vacuously true:

Wolfram Language code: ddist = EmpiricalDistribution[Range[10]];
Wolfram Language code: DistributionParameterAssumptions[ddist]

Applications  (4)

Get the PDF for an extreme value distribution:

Wolfram Language code: pdf = PDF[ExtremeValueDistribution[α, β], x]

Compute the integral for its mean without including parameter assumptions:

Wolfram Language code: Integrate[x * pdf, {x, -∞, ∞}]

Use parameter assumptions to simplify the result:

Wolfram Language code: Assuming[DistributionParameterAssumptions[ExtremeValueDistribution[α, β]], Simplify[%]]

Compute the result by giving the assumptions directly to Integrate:

Wolfram Language code: Integrate[x * pdf, {x, -∞, ∞}, Assumptions -> DistributionParameterAssumptions[ExtremeValueDistribution[α, β]]]

Compare with the mean of the distribution:

Wolfram Language code: Mean[ExtremeValueDistribution[α, β]]

Define two χ2 distributions and their parameter assumptions:

Wolfram Language code: dist1 = ChiSquareDistribution[n]; dist2 = ChiSquareDistribution[m]; assumpts = DistributionParameterAssumptions[dist1] && DistributionParameterAssumptions[dist2];

Compute the pdf of the sum of the χ2 distributed variables via convolution with assumptions:

Wolfram Language code: Convolve[PDF[dist1, t], PDF[dist2, t], t, x, Assumptions -> assumpts]

Verify the additive property of χ2 variables:

Wolfram Language code: % == PDF[ChiSquareDistribution[m + n], x]//Simplify

Define a Haight distribution with probability parameter :

Wolfram Language code: dist = ProbabilityDistribution[(4 ^ (-1 + k)p((1 - p) * p) ^ (-1 + k)(-(3 / 2) + k)!) / (Sqrt[Pi]k!), {k, 1, Infinity, 1}, Assumptions -> 1 / 2 < p < 1];

Sum the PDF expression to check normalization:

Wolfram Language code: Sum[PDF[dist, k], {k, 1, Infinity}]

The result is not always unity if the distribution assumptions are not met:

Wolfram Language code: FullSimplify[%, Not[DistributionParameterAssumptions[dist]]]

Give assumptions to Sum to verify the total probability is 1 for assumed values of :

Wolfram Language code: Sum[PDF[dist, k], {k, 1, Infinity}, Assumptions -> DistributionParameterAssumptions[dist]]

Get the assumptions for a type 1 Pearson with unknown b1 and b0 parameters:

Wolfram Language code: assumpts = DistributionParameterAssumptions[PearsonDistribution[1, 3, -2, 3, Subscript[b, 1], Subscript[b, 0]]]

Find the maximum possible value of b1 as a function of b0:

Wolfram Language code: max = ArgMax[{Subscript[b, 1], assumpts}, Subscript[b, 1]]
Wolfram Language code: Plot[max, {Subscript[b, 0], -10, 10}, Filling -> -20, AxesLabel -> {Subscript[b, 0], Subscript[b, 1]}]

Properties & Relations  (1)

DistributionParameterAssumptions returns conditions on parameters:

Wolfram Language code: DistributionParameterAssumptions[BinomialDistribution[n, p]]

DistributionParameterQ assumes symbolic parameters are valid:

Wolfram Language code: DistributionParameterQ[BinomialDistribution[n, p]]

With numeric parameters, the outputs are equivalent:

Wolfram Language code: DistributionParameterAssumptions[BinomialDistribution[20, 1 / 3]]
Wolfram Language code: DistributionParameterQ[BinomialDistribution[20, 1 / 3]]
Wolfram Research (2010), DistributionParameterAssumptions, Wolfram Language function, https://reference.wolfram.com/language/ref/DistributionParameterAssumptions.html.

Text

Wolfram Research (2010), DistributionParameterAssumptions, Wolfram Language function, https://reference.wolfram.com/language/ref/DistributionParameterAssumptions.html.

CMS

Wolfram Language. 2010. "DistributionParameterAssumptions." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DistributionParameterAssumptions.html.

APA

Wolfram Language. (2010). DistributionParameterAssumptions. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DistributionParameterAssumptions.html

BibTeX

@misc{reference.wolfram_2026_distributionparameterassumptions, author="Wolfram Research", title="{DistributionParameterAssumptions}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/DistributionParameterAssumptions.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_distributionparameterassumptions, organization={Wolfram Research}, title={DistributionParameterAssumptions}, year={2010}, url={https://reference.wolfram.com/language/ref/DistributionParameterAssumptions.html}, note=[Accessed: 12-June-2026]}