WOLFRAM

Wolfram Language & System Documentation Center

DivisorSigma[k,n]

gives the divisor function .

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Symbolic Manipulation  
Options  
GaussianIntegers  
Applications  
Basic Applications  
Special Sequences  
Number Theory  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

DivisorSigma

DivisorSigma[k,n]

gives the divisor function .

Details and Options

  • DivisorSigma is also known as the divisor function or sum‐of‐divisors function.
  • Integer mathematical function, suitable for both symbolic and numerical manipulation.
  • DivisorSigma[k,n] is the sum of the k ^(th) powers of the divisors of n.
  • For a number with a unit and primes, DivisorSigma[k,n] returns .
  • With the setting GaussianIntegers->True, DivisorSigma includes divisors that are Gaussian integers.
  • DivisorSigma[k,m+In] automatically works over Gaussian integers.

Examples

open all close all

Basic Examples  (2)

Find the divisors of :

Wolfram Language code: Divisors[20]

The sum of divisors:

Wolfram Language code: DivisorSigma[1, 20]

The sum of squares of divisors:

Wolfram Language code: DivisorSigma[2, 20]

Plot DivisorSigma with log-scaled values:

Wolfram Language code: DiscretePlot[{DivisorSigma[0, n], DivisorSigma[1, n], DivisorSigma[2, n]}, {n, 50}, ...]

Scope  (12)

Numerical Evaluation  (4)

DivisorSigma works over integers:

Wolfram Language code: DivisorSigma[2, 6]

Negative powers:

Wolfram Language code: DivisorSigma[-2, 10]

Rational powers:

Wolfram Language code: DivisorSigma[1 / 2, 12]

Gaussian integers:

Wolfram Language code: DivisorSigma[1, 3 + I]
Wolfram Language code: DivisorSigma[2, 6, GaussianIntegers -> True]

Compute for large integers:

Wolfram Language code: DivisorSigma[2, 10 ^ 30]

DivisorSigma threads elementwise over lists:

Wolfram Language code: DivisorSigma[2, {1, 2, 3, 4, 5}]

Symbolic Manipulation  (8)

TraditionalForm formatting:

Wolfram Language code: DivisorSigma[k, n]//TraditionalForm

Reduce expressions:

Wolfram Language code: Reduce[DivisorSigma[1, n] == 3n && 0 < n < 4000, n, Integers]

Solve equations:

Wolfram Language code: Solve[DivisorSigma[2, n] == n ^ 2 + 1 && 0 < n < 10, n, Integers]

Simplify expressions:

Wolfram Language code: FullSimplify[DivisorSigma[1, 2 ^ (p - 1)(2 ^ p - 1)], Element[2 ^ p - 1, Primes]]
Wolfram Language code: FullSimplify[DivisorSigma[0, n] < EulerPhi[n], n∈Integers && n > 30]

Use DivisorSigma in a sum:

Wolfram Language code: Sum[DivisorSigma[0, n] / n ^ s, {n, Infinity}]

DirichletTransform:

Wolfram Language code: DirichletTransform[DivisorSigma[k, n], s, n]

Compute for symbolic arguments:

Wolfram Language code: DivisorSigma[k, 30]

Generate a function:

Wolfram Language code: Sum[DivisorSigma[k, n] / n ^ s, {n, Infinity}]

Options  (1)

GaussianIntegers  (1)

Find the sum of the divisors of over integers:

Wolfram Language code: DivisorSigma[1, 6]

Gaussian integers:

Wolfram Language code: DivisorSigma[1, 6, GaussianIntegers -> True]

Applications  (13)

Basic Applications  (3)

In general, DivisorSigma[d,n]=∑k|nkd:

Wolfram Language code: Table[{DivisorSigma[d, 2 ^ 12 - 1], Sum[k ^ d, {k, Divisors[2 ^ 12 - 1]}]}, {d, 0, 5}]//Grid

The ratio of Gaussian divisors to integer divisors:

Wolfram Language code: ListPlot[Table[DivisorSigma[0, n, GaussianIntegers -> True] / DivisorSigma[0, n], {n, 200}], Filling -> Axis]

Plot DivisorSigma with log-scaled values:

Wolfram Language code: DiscretePlot[{DivisorSigma[0, n], DivisorSigma[1, n], DivisorSigma[2, n]}, {n, 50}, ...]

Special Sequences  (4)

Recognize perfect numbers, numbers n such that the sum of their divisors is equal to :

Wolfram Language code: Select[Range[30], DivisorSigma[1, #] == 2#&]

Deficient numbers, numbers n such that the sum of their divisors is smaller than :

Wolfram Language code: Select[Range[30], DivisorSigma[1, #] < 2#&]

Abundant numbers, numbers n such that the sum of their divisors is greater than :

Wolfram Language code: Select[Range[30], DivisorSigma[1, #] > 2#&]

Recognize highly composite numbers: [more info]

Wolfram Language code: highlyCompositeQ[n_] := Length[Select[Range[n - 1], DivisorSigma[0, #] ≥ DivisorSigma[0, n]&]] == 0;
Wolfram Language code: Select[Range[20], highlyCompositeQ]

Recognize amicable numbers, two different numbers such that the sum of the proper divisors of each is equal to the other number:

Wolfram Language code: amicablePairQ[n_, m_] := DivisorSigma[1, n] - n == m && DivisorSigma[1, m] - m == n;
Wolfram Language code: amicablePairQ[220, 284]
Wolfram Language code: amicablePairQ[10, 4]

Recognize -multiperfect numbers, numbers such that the sum of their divisors is equal to :

Wolfram Language code: kPerfectQ[k_, n_] := DivisorSigma[1, n] == k n;

The first -perfect number is :

Wolfram Language code: kPerfectQ[3, 120]

Numbers that are -perfect are called perfect numbers:

Wolfram Language code: kPerfectQ[2, 6]

Number Theory  (6)

If n is a power of , then the sum of the divisors of n equals , which makes n almost perfect:

Wolfram Language code: n = 2 ^ 10; {DivisorSigma[1, n], 2 n - 1}

The number of the divisors is odd if and only if the number is a perfect square:

Wolfram Language code: DivisorSigma[0, #]&@{2, 3, 5, 6, 7, 8, 10}
Wolfram Language code: DivisorSigma[0, #]&@{1, 4, 9}

Compare the number of divisors with Euler's totient function:

Wolfram Language code: DiscretePlot[{EulerPhi[n], DivisorSigma[0, n]}, {n, 50}, Rule[...]]

Plot the running average of the number of divisors with its asymptotic value:

Wolfram Language code: Show[ListPlot[Table[Sum[DivisorSigma[0, i], {i, n}] / n, {n, 50}]], Plot[Log[n] + 2EulerGamma - 1, {n, 1, 50}]]

Compute an iterated aliquot sum:

Wolfram Language code: NestList[DivisorSigma[1, #] - #&, 276, 20]
Wolfram Language code: ListLinePlot[Log[10, NestList[DivisorSigma[1, #] - #&, 276, 100]]]

Show the evolution of the limit :

Wolfram Language code: ListLinePlot[Table[Table[Log[DivisorSigma[n, n + m] / DivisorSigma[n, n]], {n, 100}], {m, 5}]]

Properties & Relations  (6)

DivisorSigma is the sum of the powers of the divisors:

Wolfram Language code: Total[Divisors[100] ^ 5]
Wolfram Language code: DivisorSigma[5, 100]

Use DivisorSum to find the sum of divisors:

Wolfram Language code: DivisorSum[100, # ^ 5&]

DivisorSigma is a multiplicative function:

Wolfram Language code: DivisorSigma[3, 18] DivisorSigma[3, 25] == DivisorSigma[3, 18 25]

The reciprocals of the divisors of a perfect number n must add up to :

Wolfram Language code: PerfectNumberQ[28]
Wolfram Language code: DivisorSigma[-1, 28]

The sum of divisors of a prime power n is less than 2n:

Wolfram Language code: (DivisorSigma[1, #] < 2#) & /@ Select[Range[100], PrimePowerQ]

For a prime number p, the number of the divisors is :

Wolfram Language code: p = RandomPrime[100];
Wolfram Language code: DivisorSigma[0, p] == 2

The sum of the divisors is :

Wolfram Language code: DivisorSigma[1, p] == p + 1

The number of divisors of is :

Wolfram Language code: n = 5; DivisorSigma[0, p ^ n] == n + 1

Use DivisorSigma to find the product of divisors:

Wolfram Language code: a = 24; Product[d, {d, Divisors[a]}]
Wolfram Language code: a ^ (1 / 2DivisorSigma[0, a])

Possible Issues  (1)

With GaussianIntegers->True, the naive definition does not give the correct result:

Wolfram Language code: DivisorSigma[2, 100, GaussianIntegers -> True]
Wolfram Language code: Total[Divisors[100, GaussianIntegers -> True] ^ 2]

To make DivisorSigma a multiplicative function, a definition involving factors is used:

Wolfram Language code: Times@@((#1 ^ ((#2 + 1)2) - 1) / (#1 ^ 2 - 1)&@@@({Select[#1 {1, -1, I, -I}, (Re[#] > 0 && Im[#] > 0)&][[1]], #2}&@@@FactorInteger[100, GaussianIntegers -> True]))

Neat Examples  (4)

Plot the arguments of the Fourier transform of DivisorSigma:

Wolfram Language code: ArrayPlot[Arg[Fourier[Table[DivisorSigma[m, n], {m, 100}, {n, 100}]]], ColorFunction -> Hue]

Plot the absolute values of the Fourier transform of DivisorSigma:

Wolfram Language code: ArrayPlot[Abs[Fourier[Table[DivisorSigma[m, n], {m, 100}, {n, 100}]]], ColorFunction -> Hue]

Plot the arguments of the Fourier transform of DivisorSigma:

Wolfram Language code: ArrayPlot[Arg[Fourier[Table[If[x + I y == 0, 0, DivisorSigma[4, x + I y, GaussianIntegers -> True]], {x, 0, 128}, {y, 0, 128}]]], ColorFunction -> "Rainbow"]

Plot the Ulam spiral of the mean of the divisors:

Wolfram Language code: ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table [(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n];
Wolfram Language code: ArrayPlot[DivisorSigma[0, ulam[71]], ColorFunction -> "Rainbow"]
Wolfram Research (1988), DivisorSigma, Wolfram Language function, https://reference.wolfram.com/language/ref/DivisorSigma.html.

Text

Wolfram Research (1988), DivisorSigma, Wolfram Language function, https://reference.wolfram.com/language/ref/DivisorSigma.html.

CMS

Wolfram Language. 1988. "DivisorSigma." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DivisorSigma.html.

APA

Wolfram Language. (1988). DivisorSigma. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DivisorSigma.html

BibTeX

@misc{reference.wolfram_2026_divisorsigma, author="Wolfram Research", title="{DivisorSigma}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/DivisorSigma.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_divisorsigma, organization={Wolfram Research}, title={DivisorSigma}, year={1988}, url={https://reference.wolfram.com/language/ref/DivisorSigma.html}, note=[Accessed: 12-June-2026]}