WOLFRAM

Wolfram Language & System Documentation Center

EllipticExpPrime[u,{a,b}]

gives the derivative of EllipticExp[u,{a,b}] with respect to u.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Integration  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

EllipticExpPrime

EllipticExpPrime[u,{a,b}]

gives the derivative of EllipticExp[u,{a,b}] with respect to u.

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • For certain special arguments, EllipticExpPrime automatically evaluates to exact values.
  • EllipticExpPrime can be evaluated to arbitrary numerical precision.

Examples

open all close all

Basic Examples  (2)

Evaluate numerically:

Wolfram Language code: EllipticExpPrime[-0.4, {4., 1}]

Plot the components of EllipticExpPrime over several real periods:

Wolfram Language code: Plot[{EllipticExpPrime[x, {4, 1}]//First, EllipticExpPrime[x, {4, 1}]//Last}, {x, 0, 4 2.83147}]

Scope  (9)

Numerical Evaluation  (4)

Evaluate numerically:

Wolfram Language code: EllipticExpPrime[6., {4, 1}]
Wolfram Language code: EllipticExpPrime[-.2, {3, 2}]

Evaluate to high precision:

Wolfram Language code: N[EllipticExpPrime[1 / 3, {5, 1}], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: EllipticExpPrime[0.3333330003333333333, {5, 1}]

Complex number inputs:

Wolfram Language code: N[EllipticExpPrime[27 + I, {5 - I, 2}]]

Evaluate efficiently at high precision:

Wolfram Language code: N[EllipticExpPrime[157`10, {5, 1}], 50]//Timing
Wolfram Language code: N[EllipticExpPrime[157`10000, {5, 1}], 50];//Timing

Specific Values  (2)

Values at fixed points:

Wolfram Language code: Table[EllipticExpPrime[x, {0 , 0}], {x, {-1, 2}}]

Value at zero:

Wolfram Language code: EllipticExpPrime[0, {1, 2}]

Visualization  (2)

Plot the EllipticExpPrime function for various parameters:

Wolfram Language code: Plot[{EllipticExpPrime[u, {2, 3}], EllipticExpPrime[u, {4, 3}], EllipticExpPrime[-u, {4, 3}]}, {u, -3, 3}]

Plot the real part of EllipticExpPrime[z,{1,2}]:

Wolfram Language code: ComplexContourPlot[Re[EllipticExpPrime[z, {1, 2}]], {z, -3 - 3I, 3 + 3 I}, Contours -> 24]

Plot the imaginary part of EllipticExpPrime[z,{1,2}]:

Wolfram Language code: ComplexContourPlot[Im[EllipticExpPrime[z, {1, 2}]], {z, -3 - 3I, 3 + 3 I}, Contours -> 24]

Integration  (1)

Compute the indefinite integral using Integrate:

Wolfram Language code: Integrate[EllipticExpPrime[u, {a, b}], u]

Verify the anti-derivative:

Wolfram Language code: FullSimplify[D[%, u]]

Applications  (1)

Visualize the function:

Wolfram Language code: Plot3D[Norm[EllipticExpPrime[x + I y, {1, 2}]], {x, -3, 3}, {y, -3, 3}]

Properties & Relations  (4)

EllipticExpPrime is the derivative of EllipticExp:

Wolfram Language code: D[EllipticExp[u, {a, b}], u]

EllipticExpPrime is closely related to the WeierstrassP function and its derivative:

Wolfram Language code: ellipticExpPrime[u_, {a_, b_}] := {8 WeierstrassPPrime[2 u, {(1/4)((a^2/3) - b), (1/8)(a/3)((b/2) - ((a/3))^2)}], 48 WeierstrassP[2 u, {(1/4)((a^2/3) - b), (1/8)(a/3)((b/2) - ((a/3))^2)}]^2 - (a^2/3) + b}

Compare numerical values:

Wolfram Language code: ellipticExpPrime[0.5, {3, 4}]//Chop
Wolfram Language code: EllipticExpPrime[0.5, {3, 4}]

Evaluate the elliptic exponential and its derivative:

Wolfram Language code: u = -0.4;{a, b} = {4., 1.};
Wolfram Language code: eExp = EllipticExp[u, {a, b}]
Wolfram Language code: eExpPrime = EllipticExpPrime[u, {a, b}]

EllipticExpPrime can be expressed in terms of the components of EllipticExp:

Wolfram Language code: eExpPrime == {2Indexed[eExp, 2], 3Indexed[eExp, 1]^2 + 2a Indexed[eExp, 1] + b}

WeierstrassHalfPeriods can be used to compute the two linearly independent periods of EllipticExpPrime:

Wolfram Language code: {a, b} = {4., 1.}; {p1, p2} = 2WeierstrassHalfPeriods[{(1/4)((a^2/3) - b), (1/8)(a/3)((b/2) - ((a/3))^2)}]

Compare numerical evaluations of EllipticExpPrime at congruent points in the complex plane:

Wolfram Language code: u = -0.4; {EllipticExpPrime[u, {a, b}], EllipticExpPrime[u + p1, {a, b}], EllipticExpPrime[u + p2, {a, b}]}
Wolfram Research (1991), EllipticExpPrime, Wolfram Language function, https://reference.wolfram.com/language/ref/EllipticExpPrime.html.

Text

Wolfram Research (1991), EllipticExpPrime, Wolfram Language function, https://reference.wolfram.com/language/ref/EllipticExpPrime.html.

CMS

Wolfram Language. 1991. "EllipticExpPrime." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/EllipticExpPrime.html.

APA

Wolfram Language. (1991). EllipticExpPrime. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EllipticExpPrime.html

BibTeX

@misc{reference.wolfram_2026_ellipticexpprime, author="Wolfram Research", title="{EllipticExpPrime}", year="1991", howpublished="\url{https://reference.wolfram.com/language/ref/EllipticExpPrime.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_ellipticexpprime, organization={Wolfram Research}, title={EllipticExpPrime}, year={1991}, url={https://reference.wolfram.com/language/ref/EllipticExpPrime.html}, note=[Accessed: 13-June-2026]}