WOLFRAM

Wolfram Language & System Documentation Center

EstimatedPointProcess[pdata,pproc]

estimates the parametric point process pproc from point data pdata.

EstimatedPointProcess[pdata,pproc,{{p,p0},{q,q0},…}]

estimates the parameters p, q, … with starting values p0, q0, ….

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Cluster point processes  
Gibbs point processes  
Options  
PointProcessEstimator  
WorkingPrecision  
See Also
Related Guides
History
Cite this Page

EstimatedPointProcess

EstimatedPointProcess[pdata,pproc]

estimates the parametric point process pproc from point data pdata.

EstimatedPointProcess[pdata,pproc,{{p,p0},{q,q0},…}]

estimates the parameters p, q, … with starting values p0, q0, ….

Details and Options

  • EstimatedPointProcess takes point data pdata and returns the symbolic point process pproc with parameter estimates inserted for any non-numeric values.
  • In general, a process pproc can be better estimated from an ensemble of point data.
  • The points pdata can have the following forms:
  • {p1,p2,…}points pi
    GeoPosition[…],GeoPositionXYZ[…],…geographic points
    SpatialPointData[…]spatial point collection
    {pts,reg}point collection pts and observation region reg
  • The points are converted to a SpatialPointData object and a Ripley–Rasson estimator is used to generate the observation region if it is not provided in pdata.
  • The following options can be given:
  • AccuracyGoalAutomaticthe accuracy sought
    PointProcessEstimator Automaticwhat process parameter estimator to use
    PrecisionGoalAutomaticthe precision sought
    WorkingPrecision Automaticthe precision used in internal computations
  • Settings for PointProcessEstimator are documented under the individual point process reference pages.

Examples

open all close all

Basic Examples  (1)

Estimate the parameter of a PoissonPointProcess:

Wolfram Language code: data = RandomPointConfiguration[PoissonPointProcess[20, 2], Disk[]];
Wolfram Language code: eproc = EstimatedPointProcess[data, PoissonPointProcess[mu, 2]]

Compare the nearest neighbor function of the estimated process to the original data:

Wolfram Language code: gdata = NearestNeighborG[data]; gproc = NearestNeighborG[eproc];
Wolfram Language code: Plot[{gdata[r], gproc[r]}, {r, 0, 0.3}]

Scope  (3)

Cluster point processes  (1)

Simulate a point configuration from a Matern point process:

Wolfram Language code: proc = MaternPointProcess[20, 30, 1, 2]; points = RandomPointConfiguration[proc, Rectangle[]];
Wolfram Language code: ListPlot[points]

Use the "FindClusters" method to estimate a point process model:

Wolfram Language code: est = EstimatedPointProcess[points, MaternPointProcess[a, b, c, d], PointProcessEstimator -> "FindClusters"]

Compare the Ripley measure between the original process and the estimated model:

Wolfram Language code: DiscretePlot[{RipleyK[est, r], RipleyK[proc, r]}, {r, 0.1, .5, .005}, PlotLegends -> {"original process", "estimated model"}]

Gibbs point processes  (2)

Estimate a hardcore point process:

Wolfram Language code: proc = HardcorePointProcess[30, .1, 2]; points = RandomPointConfiguration[proc, Disk[]];
Wolfram Language code: ListPlot[points]

Use automatic method:

Wolfram Language code: EstimatedPointProcess[points, HardcorePointProcess[a, b, c]]

Explicitly specify estimation method and starting values for parameters:

Wolfram Language code: a0 = points["MeanPointCount"]; b0 = Min[DeleteCases[Flatten[DistanceMatrix[points["Points"]]], 0. | 0]];
Wolfram Language code: EstimatedPointProcess[points, HardcorePointProcess[a, b, 2], {{a, a0}, {b, b0}}, Method -> "MaximumPseudoLikelihood"]

Estimate an interaction point process:

Wolfram Language code: proc = StraussPointProcess[100, 0.5, 0.1, 2]; reg = Rectangle[];
Wolfram Language code: pts = RandomPointConfiguration[proc, reg, 3]
Wolfram Language code: ListPlot[pts]

Estimate the point process:

Wolfram Language code: EstimatedPointProcess[pts, StraussPointProcess[μ, γ, R, 2]]

Options  (3)

PointProcessEstimator  (2)

Estimate a cluster point process:

Wolfram Language code: proc = ThomasPointProcess[20, 30, 1, 2]; points = RandomPointConfiguration[proc, Rectangle[]];

Use the "FindClusters" method to estimate a point process model:

Wolfram Language code: EstimatedPointProcess[points, ThomasPointProcess[a, b, c, d], PointProcessEstimator -> "FindClusters"]

Use the method of moments:

Wolfram Language code: EstimatedPointProcess[points, ThomasPointProcess[a, b, c, d], PointProcessEstimator -> "MethodOfMoments"]

Estimate an interaction process:

Wolfram Language code: proc = HardcorePointProcess[40, .1, 2]; points = RandomPointConfiguration[proc, Rectangle[]];

Use "MaximumPseudoLikelihood" method:

Wolfram Language code: EstimatedPointProcess[points, HardcorePointProcess[a, b, c], PointProcessEstimator -> "MaximumPseudoLikelihood"]

Use "MaximumLikelihood" method:

Wolfram Language code: EstimatedPointProcess[points, HardcorePointProcess[a, b, c], PointProcessEstimator -> "MaximumLikelihood"]

WorkingPrecision  (1)

Estimate a cluster point process with arbitrary precision:

Wolfram Language code: proc = PoissonPointProcess[30, 2]; points = RandomPointConfiguration[proc, Disk[], WorkingPrecision -> 20];

Specify WorkingPrecision:

Wolfram Language code: EstimatedPointProcess[points, PoissonPointProcess[μ, d], WorkingPrecision -> 20]

EstimatedPointProcess uses MachinePrecision as default:

Wolfram Language code: EstimatedPointProcess[points, PoissonPointProcess[μ, d]]
Wolfram Research (2020), EstimatedPointProcess, Wolfram Language function, https://reference.wolfram.com/language/ref/EstimatedPointProcess.html.

Text

Wolfram Research (2020), EstimatedPointProcess, Wolfram Language function, https://reference.wolfram.com/language/ref/EstimatedPointProcess.html.

CMS

Wolfram Language. 2020. "EstimatedPointProcess." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/EstimatedPointProcess.html.

APA

Wolfram Language. (2020). EstimatedPointProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EstimatedPointProcess.html

BibTeX

@misc{reference.wolfram_2026_estimatedpointprocess, author="Wolfram Research", title="{EstimatedPointProcess}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/EstimatedPointProcess.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_estimatedpointprocess, organization={Wolfram Research}, title={EstimatedPointProcess}, year={2020}, url={https://reference.wolfram.com/language/ref/EstimatedPointProcess.html}, note=[Accessed: 13-June-2026]}