WOLFRAM

Wolfram Language & System Documentation Center

FactorInteger[n]

gives a list of the prime factors of the integer n, together with their exponents.

FactorInteger[n,k]

does partial factorization, pulling out at most k distinct factors.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
GaussianIntegers  
Applications  
Basic Applications  
Number Theory  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

FactorInteger

FactorInteger[n]

gives a list of the prime factors of the integer n, together with their exponents.

FactorInteger[n,k]

does partial factorization, pulling out at most k distinct factors.

Details and Options

  • FactorInteger is also known as prime factorization.
  • For a positive number n=p1k1⋯ pmkm with pi primes, FactorInteger[n] gives a list {{p1,k1},…,{pm,km}}.
  • For negative numbers, the unit {-1,1} is included in the list of factors.
  • FactorInteger also works on rational numbers. The prime factors of the denominator are given with negative exponents.
  • FactorInteger[n,GaussianIntegers->True] factors over Gaussian integers.
  • FactorInteger[m+I n] automatically works over Gaussian integers.
  • When necessary, a unit of the form {-1,1}, {I,1} or {-I,1} is included in the list of factors.
  • The last element in the list FactorInteger[n,k] gives what is left after the partial factorization.
  • FactorInteger[n,Automatic] pulls out only factors that are easy to find.
  • FactorInteger uses PrimeQ to determine whether factors are prime.

Examples

open all close all

Basic Examples  (2)

Find prime factors of and their exponents:

Wolfram Language code: FactorInteger[120]

Plot the number of distinct prime factors of the first 100 numbers:

Wolfram Language code: DiscretePlot[Length[FactorInteger[n]], {n, 100}]

Scope  (6)

FactorInteger works over integers:

Wolfram Language code: FactorInteger[36]

Rational numbers:

Wolfram Language code: FactorInteger[3 / 8]

Gaussian integers:

Wolfram Language code: FactorInteger[9 + 12I]
Wolfram Language code: FactorInteger[36, GaussianIntegers -> True]

Find a partial factorization:

Wolfram Language code: FactorInteger[20!, 4]
Wolfram Language code: FactorInteger[10 ^ 100 + 3, Automatic]

Compute for large integers:

Wolfram Language code: FactorInteger[10 ^ 50 + 3]

FactorInteger threads over lists:

Wolfram Language code: FactorInteger[{11, 101, 1001}]

Options  (1)

GaussianIntegers  (1)

Factor a number over integers:

Wolfram Language code: FactorInteger[5]

Gaussian integers:

Wolfram Language code: FactorInteger[5, GaussianIntegers -> True]

Applications  (12)

Basic Applications  (5)

Every positive integer can be represented as a product of prime factors:

Wolfram Language code: FactorInteger[60]

A unit factor:

Wolfram Language code: FactorInteger[-60]

Plot the number of distinct prime factors of numbers up to :

Wolfram Language code: ListPlot[Table[Length[FactorInteger[n]], {n, 100}]]

Compare with the number of distinct prime factors over the Gaussian integers:

Wolfram Language code: ListPlot[Table[Length[FactorInteger[n, GaussianIntegers -> True]], {n, 100}]]

Display as an explicit product of factors:

Wolfram Language code: FactorInteger[20!]
Wolfram Language code: CenterDot@@(Superscript@@@%)

Use FactorInteger to test for prime powers:

Wolfram Language code: MatchQ[FactorInteger[2401], {{_Integer, _Integer}}]
Wolfram Language code: PrimePowerQ[2401]

Use FactorInteger to find all prime divisors of a number:

Wolfram Language code: Part[FactorInteger[2434500], All, 1]
Wolfram Language code: Select[Divisors[2434500], PrimeQ]

Number Theory  (7)

Use FactorInteger to compute the number of divisors of the number:

Wolfram Language code: Times@@(FactorInteger[6!][[All, -1]] + 1)
Wolfram Language code: Length[Divisors[6!]]

Use FactorInteger to recognize powerful numbers, numbers whose prime factors are all repeated:

Wolfram Language code: powQ[n_] := AllTrue[Part[FactorInteger[n], All, 2], # > 1&];
Wolfram Language code: powQ[324]
Wolfram Language code: powQ[75]

Find factorizations of numbers of the form :

Wolfram Language code: Table[FactorInteger[2 ^ 2 ^ n + 1], {n, 7}]//Column

Find all natural numbers up to 100 that are primes or prime powers:

Wolfram Language code: Select[Range[100], Length[FactorInteger[#]] == 1&]

The highest power of a prime in numbers up to 100:

Wolfram Language code: Table[Max[Last /@ FactorInteger[n]], {n, 2, 100}]

Find primes that appear in prime factorization of only to the first power:

Wolfram Language code: FactorInteger[20!]
Wolfram Language code: Cases[%, {p_, 1} -> p]

Use FactorInteger to compute the square-free part of a number:

Wolfram Language code: squareFreePart[n_] := Times@@Cases[FactorInteger[n], {x_, _} -> x];
Wolfram Language code: squareFreePart[18]

Visualize the distribution:

Wolfram Language code: ListPlot[Table[squareFreePart[a], {a, 1, 1000}]]

Properties & Relations  (9)

The prime factorization of a prime number is itself:

Wolfram Language code: PrimeQ[11]
Wolfram Language code: FactorInteger[11]

Prime powers:

Wolfram Language code: PrimePowerQ[125]
Wolfram Language code: FactorInteger[125]

Composite numbers have at least two prime factors including multiplicities:

Wolfram Language code: CompositeQ[60]
Wolfram Language code: FactorInteger[60]

Compute the original number from a factorization:

Wolfram Language code: FactorInteger[30]
Wolfram Language code: Times@@Cases[FactorInteger[30], {a_, b_} -> a ^ b ]

Exponents in the prime factorization of a square-free number are all :

Wolfram Language code: SquareFreeQ[210]
Wolfram Language code: FactorInteger[210]

Divisors gives the list of divisors including prime divisors:

Wolfram Language code: Select[Divisors[20], PrimeQ]
Wolfram Language code: FactorInteger[20]

PrimeNu gives the number of distinct prime factors:

Wolfram Language code: Length[FactorInteger[10!]]
Wolfram Language code: PrimeNu[10!]

PrimeOmega gives the number of prime factors counting multiplicities:

Wolfram Language code: Total[FactorInteger[48][[All, -1]]]
Wolfram Language code: PrimeOmega[48]

Coprime numbers have no prime factors in common:

Wolfram Language code: CoprimeQ[20, 39]
Wolfram Language code: FactorInteger[20]
Wolfram Language code: FactorInteger[39]

If the prime factorization of n is given by , then the number of divisors of n is :

Wolfram Language code: Times@@(FactorInteger[5!][[All, -1]] + 1)
Wolfram Language code: Length[Divisors[5!]]

Possible Issues  (2)

Timings can increase rapidly and unpredictably with the size of the input:

Wolfram Language code: Table[Timing[FactorInteger[2 ^ n - 1];n], {n, 50, 300, 50}]

FactorInteger at zero:

Wolfram Language code: FactorInteger[0]
Wolfram Research (1988), FactorInteger, Wolfram Language function, https://reference.wolfram.com/language/ref/FactorInteger.html (updated 2007).

Text

Wolfram Research (1988), FactorInteger, Wolfram Language function, https://reference.wolfram.com/language/ref/FactorInteger.html (updated 2007).

CMS

Wolfram Language. 1988. "FactorInteger." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2007. https://reference.wolfram.com/language/ref/FactorInteger.html.

APA

Wolfram Language. (1988). FactorInteger. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FactorInteger.html

BibTeX

@misc{reference.wolfram_2026_factorinteger, author="Wolfram Research", title="{FactorInteger}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/FactorInteger.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_factorinteger, organization={Wolfram Research}, title={FactorInteger}, year={2007}, url={https://reference.wolfram.com/language/ref/FactorInteger.html}, note=[Accessed: 13-June-2026]}