WOLFRAM

Wolfram Language & System Documentation Center

FareySequence[n]

generates the Farey sequence of order n.

FareySequence[n,k]

gives the k^(th) element of the Farey sequence of order n.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Related Guides
Related Links
History
Cite this Page

FareySequence

FareySequence[n]

generates the Farey sequence of order n.

FareySequence[n,k]

gives the k^(th) element of the Farey sequence of order n.

Details

  • The Farey sequence of order n is the sorted sequence of completely reduced fractions between 0 and 1 with denominators not exceeding n.

Examples

open all close all

Basic Examples  (1)

Generate the Farey sequence of order 5:

Wolfram Language code: FareySequence[5]

Find the 17^(th) element of the Farey sequence of order 24:

Wolfram Language code: FareySequence[24, 17]

Scope  (1)

Give the Farey sequence of order 3:

Wolfram Language code: FareySequence[3]

Give the second term of the Farey sequence of order 3:

Wolfram Language code: FareySequence[3, 2]

Applications  (5)

Farey arc diagram, connecting adjacent rationals in a Farey sequence:

Wolfram Language code: FareyPairArc[r1_, r2_] := Circle[{(r1 + r2) / 2, 0}, (r2 - r1) / 2, {0, Pi}]
Wolfram Language code: Table[Graphics[{ColorData[94, n], FareyPairArc@@@Partition[FareySequence[n], 2, 1]}, PlotLabel -> n], {n, 1, 6}]

Show them together:

Wolfram Language code: Show[%]

Visualize a pattern of denominators of a Farey sequence of order 12:

Wolfram Language code: Denominator /@ FareySequence[12]
Wolfram Language code: MatrixPlot[SparseArray[MapIndexed[Prepend[#2, #1] -> 1&, %]], Mesh -> All]

The length of a Farey sequence for a few small orders:

Wolfram Language code: Table[Length[FareySequence[n]], {n, 1, 12}]

Compare with a closed-form formula in terms of Euler's totient function:

Wolfram Language code: Table[1 + Underoverscript[∑, k = 1, n]EulerPhi[k], {n, 1, 12}]

The product of all nonzero elements of the Farey sequence for a few small orders:

Wolfram Language code: Table[Apply[Times, Rest[FareySequence[n]]], {n, 2, 12}]

Compare with a closed-form formula:

Wolfram Language code: Table[Underoverscript[∏, k = 1, n]((BarnesG[Quotient[n, k] + 2]/Hyperfactorial[Quotient[n, k]]))^MoebiusMu[k], {n, 2, 12}]

Construct Ford circles from a Farey sequence:

Wolfram Language code: FordCircle[r_] := With[{den = (2 Denominator[r] ^ 2)}, Disk[{r, 1 / den}, 1 / den]]
Wolfram Language code: Graphics[{GrayLevel[3 / (2 + 3Denominator[#])], Tooltip[FordCircle[#], #]}& /@ FareySequence[10], PlotRange -> {{0, 1}, {0, 1}}]

Properties & Relations  (2)

Obtain a Farey sequence as a union of Subdivide lists:

Wolfram Language code: FareySequence[5]
Wolfram Language code: % === Union@@(Subdivide /@ Range[5])

FareySequence[n,k] is equivalent to FareySequence[n]〚k〛:

Wolfram Language code: FareySequence[50, 500]
Wolfram Language code: FareySequence[50][[500]]

FareySequence[n,k] is much faster:

Wolfram Language code: FareySequence[5000, 1000000]//AbsoluteTiming
Wolfram Language code: FareySequence[5000][[1000000]]//AbsoluteTiming
Wolfram Research (2014), FareySequence, Wolfram Language function, https://reference.wolfram.com/language/ref/FareySequence.html (updated 2016).

Text

Wolfram Research (2014), FareySequence, Wolfram Language function, https://reference.wolfram.com/language/ref/FareySequence.html (updated 2016).

CMS

Wolfram Language. 2014. "FareySequence." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/FareySequence.html.

APA

Wolfram Language. (2014). FareySequence. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FareySequence.html

BibTeX

@misc{reference.wolfram_2026_fareysequence, author="Wolfram Research", title="{FareySequence}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/FareySequence.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_fareysequence, organization={Wolfram Research}, title={FareySequence}, year={2016}, url={https://reference.wolfram.com/language/ref/FareySequence.html}, note=[Accessed: 12-June-2026]}