WOLFRAM

Wolfram Language & System Documentation Center

FilteredEntityClass[class,f]

represents a class of entities where only entities for which the EntityFunction object f yields True are kept.

FilteredEntityClass[class,prop]

represents a class of entities where only entities for which the property prop is True are kept.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
Neat Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

FilteredEntityClass

FilteredEntityClass[class,f]

represents a class of entities where only entities for which the EntityFunction object f yields True are kept.

FilteredEntityClass[class,prop]

represents a class of entities where only entities for which the property prop is True are kept.

Details

Examples

open all close all

Basic Examples  (3)

Filter by a Boolean EntityProperty:

Wolfram Language code: FilteredEntityClass["Country", EntityProperty["Country", "HasPolygon"]]["EntityCount"]

Filter entities by a Boolean EntityFunction:

Wolfram Language code: EntityList[FilteredEntityClass["Country", EntityFunction[c, c["Population"] > Quantity[1*10^8, "People"] || c["Continent"] === EntityClass["Country", "Oceania"]]]]

When used with relational-database-backed entities, FilteredEntityClass is effectively compiled to a WHERE statement:

Wolfram Language code: EntityRegister[EntityStore[RelationalDatabase[FindFile["ExampleData/ecommerce-database.sqlite"]]]]
Wolfram Language code: FilteredEntityClass["employees", EntityFunction[x, StringStartsQ[x["firstName"], "L"]]][{"firstName", "lastName"}]

Scope  (2)

Get a list of volcanoes in Italy with an elevation over 1 kilometer:

Wolfram Language code: FilteredEntityClass["Volcano", EntityFunction[m, m["Elevation"] > Quantity[1, "Kilometers"] && MemberQ[m["Countries"], Entity["Country", "Italy"]] ]][{"Name", "Countries", "Elevation"}]

Get a list of elements that have a multiple of nine protons in their nucleus:

Wolfram Language code: FilteredEntityClass["Element", EntityFunction[m, Divisible[m["AtomicNumber"], 9] ]][{"Name", "AtomicNumber"}]

Properties & Relations  (1)

Get a list of mountains in Africa with an elevation over 5 kilometers, using FilteredEntityClass:

Wolfram Language code: mountains1 = EntityList[ FilteredEntityClass["Mountain", EntityFunction[m, m["Elevation"] > Quantity[5, "Kilometers"] && m["Continent"] === Entity["GeographicRegion", "Africa"] ]]]

Use an implicitly defined EntityClass to get the same list of mountains:

Wolfram Language code: mountains2 = EntityList[EntityClass["Mountain", { "Elevation" -> GreaterThan[Quantity[5, "Kilometers"]], "Continent" -> Entity["GeographicRegion", "Africa"] }]]

Sort both results to compare them:

Wolfram Language code: ContainsExactly[mountains1, mountains2]

Neat Examples  (1)

Make an image collage of paintings by Rembrandt:

Wolfram Language code: ImageCollage[EntityValue[ FilteredEntityClass["Artwork", EntityFunction[m, MemberQ[m["Artist"], Entity["Person", "Rembrandt::v33s2"]] ]], "Image"]]
Wolfram Research (2019), FilteredEntityClass, Wolfram Language function, https://reference.wolfram.com/language/ref/FilteredEntityClass.html.

Text

Wolfram Research (2019), FilteredEntityClass, Wolfram Language function, https://reference.wolfram.com/language/ref/FilteredEntityClass.html.

CMS

Wolfram Language. 2019. "FilteredEntityClass." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FilteredEntityClass.html.

APA

Wolfram Language. (2019). FilteredEntityClass. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FilteredEntityClass.html

BibTeX

@misc{reference.wolfram_2026_filteredentityclass, author="Wolfram Research", title="{FilteredEntityClass}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/FilteredEntityClass.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_filteredentityclass, organization={Wolfram Research}, title={FilteredEntityClass}, year={2019}, url={https://reference.wolfram.com/language/ref/FilteredEntityClass.html}, note=[Accessed: 12-June-2026]}