WOLFRAM

Wolfram Language & System Documentation Center

FindPointProcessParameters[pdata,pproc]

estimates the parameters of the point process pproc from point data pdata.

FindPointProcessParameters[pdata,pproc,{{p,p0},{q,q0},…}]

estimates the parameters p, q, … with starting values p0, q0, ….

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Cluster point processes  
Gibbs point processes  
Options  
PointProcessEstimator  
WorkingPrecision  
See Also
Related Guides
History
Cite this Page

FindPointProcessParameters

FindPointProcessParameters[pdata,pproc]

estimates the parameters of the point process pproc from point data pdata.

FindPointProcessParameters[pdata,pproc,{{p,p0},{q,q0},…}]

estimates the parameters p, q, … with starting values p0, q0, ….

Details and Options

Examples

open all close all

Basic Examples  (1)

Estimate the parameter of a PoissonPointProcess:

Wolfram Language code: data = RandomPointConfiguration[PoissonPointProcess[20, 2], Disk[]];
Wolfram Language code: procparam = FindPointProcessParameters[data, PoissonPointProcess[mu, 2]]

Obtain the estimated process:

Wolfram Language code: eproc = PoissonPointProcess[mu, 2] /. procparam

Compare the nearest neighbor function of the estimated process to the original data:

Wolfram Language code: gdata = NearestNeighborG[data]; gproc = NearestNeighborG[eproc];
Wolfram Language code: Plot[{gdata[r], gproc[r]}, {r, 0, 0.3}]

Scope  (3)

Cluster point processes  (1)

Simulate a point configuration from a Matérn point process:

Wolfram Language code: proc = MaternPointProcess[20, 30, 1, 2]; points = RandomPointConfiguration[proc, Rectangle[]];
Wolfram Language code: ListPlot[points]

Use the "FindClusters" method to estimate a point process model:

Wolfram Language code: est = FindPointProcessParameters[points, MaternPointProcess[a, b, c, d], PointProcessEstimator -> "FindClusters"]

Compare the Ripley measure between the original process and the estimated model:

Wolfram Language code: DiscretePlot[{RipleyK[MaternPointProcess[a, b, c, d] /. est, r], RipleyK[proc, r]}, {r, 0.1, .5, .005}, PlotLegends -> {"original process", "estimated model"}]

Gibbs point processes  (2)

Estimate a hardcore point process:

Wolfram Language code: proc = HardcorePointProcess[30, .1, 2]; points = RandomPointConfiguration[proc, Disk[]];
Wolfram Language code: ListPlot[points]

Use automatic method:

Wolfram Language code: FindPointProcessParameters[points, HardcorePointProcess[a, b, dim]]

Use fixed and starting values for parameters:

Wolfram Language code: a0 = points["MeanPointCount"]; b0 = Min[DeleteCases[Flatten[DistanceMatrix[points["Points"]]], 0. | 0]];
Wolfram Language code: FindPointProcessParameters[points, HardcorePointProcess[a, b, 2], {{a, a0}, {b, b0}}]

Estimate an interaction point process:

Wolfram Language code: proc = StraussPointProcess[100, 0.5, 0.1, 2]; reg = Rectangle[];
Wolfram Language code: pts = RandomPointConfiguration[proc, reg, 3]
Wolfram Language code: ListPlot[pts]

Find the point process parameters:

Wolfram Language code: FindPointProcessParameters[pts, StraussPointProcess[μ, γ, R, 2]]

Options  (3)

PointProcessEstimator  (2)

Estimate a cluster point process:

Wolfram Language code: proc = ThomasPointProcess[20, 30, 1, 2]; points = RandomPointConfiguration[proc, Rectangle[]];

Use the "FindClusters" method to estimate a point process model:

Wolfram Language code: FindPointProcessParameters[points, ThomasPointProcess[a, b, c, d], PointProcessEstimator -> "FindClusters"]

Use the method of moments:

Wolfram Language code: FindPointProcessParameters[points, ThomasPointProcess[a, b, c, d], PointProcessEstimator -> "MethodOfMoments"]

Estimate an interaction process:

Wolfram Language code: proc = HardcorePointProcess[40, .1, 2]; points = RandomPointConfiguration[proc, Rectangle[]];

Use "MaximumPseudoLikelihood" method:

Wolfram Language code: FindPointProcessParameters[points, HardcorePointProcess[a, b, c], PointProcessEstimator -> "MaximumPseudoLikelihood"]

Use "MaximumLikelihood" method:

Wolfram Language code: FindPointProcessParameters[points, HardcorePointProcess[a, b, c], PointProcessEstimator -> "MaximumLikelihood"]

WorkingPrecision  (1)

Estimate a cluster point process with arbitrary precision:

Wolfram Language code: proc = PoissonPointProcess[30, 2]; points = RandomPointConfiguration[proc, Disk[], WorkingPrecision -> 20];

Specify WorkingPrecision:

Wolfram Language code: FindPointProcessParameters[points, PoissonPointProcess[μ, d], WorkingPrecision -> 20]

FindPointProcessParameters uses MachinePrecision as default:

Wolfram Language code: FindPointProcessParameters[points, PoissonPointProcess[μ, d]]
Wolfram Research (2020), FindPointProcessParameters, Wolfram Language function, https://reference.wolfram.com/language/ref/FindPointProcessParameters.html.

Text

Wolfram Research (2020), FindPointProcessParameters, Wolfram Language function, https://reference.wolfram.com/language/ref/FindPointProcessParameters.html.

CMS

Wolfram Language. 2020. "FindPointProcessParameters." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FindPointProcessParameters.html.

APA

Wolfram Language. (2020). FindPointProcessParameters. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FindPointProcessParameters.html

BibTeX

@misc{reference.wolfram_2026_findpointprocessparameters, author="Wolfram Research", title="{FindPointProcessParameters}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/FindPointProcessParameters.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_findpointprocessparameters, organization={Wolfram Research}, title={FindPointProcessParameters}, year={2020}, url={https://reference.wolfram.com/language/ref/FindPointProcessParameters.html}, note=[Accessed: 13-June-2026]}