FindSolarEclipse
returns the next solar eclipse for which the umbra covers the current geo location.
FindSolarEclipse[loc]
returns the next eclipse for which the umbra covers the geo location loc.
FindSolarEclipse[loc,datespec]
returns the eclipses for which the umbra covers loc during the given datespec.
Details and Options
- Find the date of solar eclipses visible from a given location or geo region. Study the frequency of eclipses in which totality covers a given location.
- FindSolarEclipse reports umbral eclipses, which are those for which the umbra cone, either on the umbra or antumbra side, touches the Earth. This includes total, annular and hybrid eclipses, but not partial eclipses.
- As in SolarEclipse, eclipses are identified by date objects indicating the instant of maximum eclipse.
- Possible geo locations loc include:
-
GeoPosition[…] explicit geo position Entity[…] geo entity, such a city or country georegion any geo region, such as GeoPolygon[…] or GeoDisk[…] All,"World" whole planet surface - For extended regions, such as geo polygons or countries, FindSolarEclipse returns all eclipses for which the umbra envelope polygon intersects the region.
- Possible date specifications datespec include:
-
DateObject[…] return the next eclipse after the given date object DateInterval[…] return all eclipses in the given date interval {date1,date2} return all eclipses between date1 and date2 Quantity[…] return all eclipses in a future or past period from now - For a given date specification datespec, FindSolarEclipse[datespec] is equivalent to FindSolarEclipse[Here,datespec].
- Possible options of FindSolarEclipse include:
-
CalendarType Automatic calendar used to return dates DateFormat Automatic format used to display output dates DateGranularity Automatic calendar granularity of output dates EclipseType Automatic type of solar eclipse TimeDirection 1 whether to return the next or last new moon TimeSystem Automatic time system of output dates TimeZone Automatic time zone of output dates
Examples
open all close allBasic Examples (3)
Find the next eclipse for which the umbra covers your geo location:
FindSolarEclipse[]It will be an annular eclipse:
SolarEclipse[%, "Type"]Find the next eclipse for which the umbra envelope intersects with the polygon of the US:
FindSolarEclipse[Entity["Country", "UnitedStates"]]Show that the umbra polygon does intersect the US:
GeoGraphics[SolarEclipse[%, "UmbraEnvelopePolygon"]]Find all total solar eclipses visible from France in the last 500 years:
FindSolarEclipse[Entity["Country", "France"], Quantity[-500, "Years"], EclipseType -> "Total"]GeoGraphics[{{Red, Polygon[Entity["Country", "France"]]}, Tooltip[SolarEclipse[#, "UmbraEnvelopePolygon"], #]& /@ %}, GeoRange -> Entity["Country", "France"]]Scope (8)
Location Specifications (3)
Find the next umbral eclipse covering a point location:
FindSolarEclipse[GeoPosition[{0, 50}]]Find the next umbral eclipse covering an extended region:
FindSolarEclipse[Entity["Country", "Brazil"]]This is equivalent to using the geo polygon of the region:
FindSolarEclipse[Entity["Country", "Brazil"]["Polygon"]]Find the next umbral eclipse anywhere in the world:
FindSolarEclipse["World"]FindSolarEclipse[All]This is equivalent to using SolarEclipse for umbral eclipses:
SolarEclipse[EclipseType -> "Umbral"]Date Specifications (5)
By default, FindSolarEclipse finds the next umbral eclipse after the current instant:
FindSolarEclipse[]FindSolarEclipse[Now]FindSolarEclipse[Here, Now]Find the first umbral eclipse following a given date:
FindSolarEclipse[DateObject[{1700, 1, 1}]]Find all umbral eclipses in a given interval of dates:
FindSolarEclipse[{DateObject[{1900}], DateObject[{2100}]}]The same period can be expressed using DateInterval:
FindSolarEclipse[DateInterval[{{1900}, {2100}}]]Find all umbral eclipses in a future period of time from the current instant:
FindSolarEclipse[Quantity[200, "Years"]]Find all umbral eclipses in a past period of time until the current instant:
FindSolarEclipse[Quantity[-200, "Years"]]Find all umbral eclipses in a period expressed relatively to the current instant:
FindSolarEclipse[Quantity[{-100, 100}, "Years"]]Options (9)
CalendarType (1)
By default, FindSolarEclipse returns dates in the "Gregorian" calendar:
FindSolarEclipse[DateObject[{1200}]]Return the result in another calendar:
FindSolarEclipse[DateObject[{1200}], CalendarType -> "Julian"]DateFormat (1)
FindSolarEclipse returns dates in a long format by default:
FindSolarEclipse[]FindSolarEclipse[DateFormat -> {"Day", "/", "Month", "/", "Year"}]DateGranularity (1)
By default, FindSolarEclipse returns dates with "Instant" granularity:
FindSolarEclipse[]Return the result with a different granularity:
FindSolarEclipse[DateGranularity -> "Day"]EclipseType (1)
By default, FindSolarEclipse finds the next eclipse of any umbral type:
FindSolarEclipse[]SolarEclipse[%, "Type"]Find the next eclipse of a different type:
FindSolarEclipse[EclipseType -> "Total"]SolarEclipse[%, "Type"]Hybrid eclipses are much less frequent:
FindSolarEclipse[EclipseType -> "Hybrid"]SolarEclipse[%, "Type"]TimeDirection (2)
By default, FindSolarEclipse finds the next eclipse covering your location:
FindSolarEclipse[]Find the previous eclipse instead:
FindSolarEclipse[TimeDirection -> -1]Find the first eclipse at your location after a given date:
FindSolarEclipse[DateObject[{1900, 1, 1}]]Find the first eclipse before the same date:
FindSolarEclipse[DateObject[{1900, 1, 1}], TimeDirection -> -1]TimeSystem (2)
By default, FindSolarEclipse returns dates in the default Wolfram Language time system, an implementation of UTC extended to follow UT1 in the far past and future:
FindSolarEclipse[]Specify that the result should be given in a different time system:
FindSolarEclipse[TimeSystem -> "TT"]Find an eclipse in the far past. Note that DateObject uses by default a proleptic Gregorian calendar without year zero:
FindSolarEclipse[DateObject[{-10000, 1, 1}]]Changing to the "TT" time system shifts the date representation by several days:
FindSolarEclipse[DateObject[{-10000, 1, 1}], TimeSystem -> "TT"]%% - %TimeZone (1)
By default, FindSolarEclipse returns dates in your local time zone:
FindSolarEclipse[]Return the same date in a different time zone:
FindSolarEclipse[TimeZone -> 0]FindSolarEclipse[TimeZone -> "Asia/Tokyo"]Applications (3)
Show that three eclipses will be visible from Spain in less than two years:
eclipses = FindSolarEclipse[Entity["Country", "Spain"], DateInterval[{{2026, 6}, {2028, 6}}]]SolarEclipse[#, "Type"]& /@ eclipsesSolarEclipse[#, "UmbraEnvelopePolygon"]& /@ eclipsesGeoGraphics[%, ImageSize -> Large]Show that there was only one solar eclipse visible from Assyria in the eighth century BC:
FindSolarEclipse[Entity["HistoricalCountry", "AssyrianEmpire"], DateInterval[{{-800}, {-700}}]]Convert the date into the Julian calendar:
CalendarConvert[%, "Julian"]Find all umbral eclipses visible from Costa Rica in a period of 10K years:
Length[eclipses = FindSolarEclipse[Entity["Country", "CostaRica"], Quantity[{-5000, 5000}, "Years"]]]Represent them on a map showing all of the Earth:
GeoGraphics[{SolarEclipse[eclipses, "UmbraEnvelopePolygon"], Red, GeoBoundary[Entity["Country", "CostaRica"]]}, GeoProjection -> "LambertAzimuthal", ImageSize -> Medium]Properties & Relations (1)
FindSolarEclipse finds eclipses for given locations and dates:
eclipse = FindSolarEclipse[Entity["Country", "Egypt"], DateObject[{-500}]]SolarEclipse can then report properties of those eclipses:
SolarEclipse[eclipse, "Type"]SolarEclipse[eclipse, "Magnitude"]SolarEclipse[eclipse, "EclipseMap"]Text
Wolfram Research (2026), FindSolarEclipse, Wolfram Language function, https://reference.wolfram.com/language/ref/FindSolarEclipse.html.
CMS
Wolfram Language. 2026. "FindSolarEclipse." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FindSolarEclipse.html.
APA
Wolfram Language. (2026). FindSolarEclipse. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FindSolarEclipse.html