WOLFRAM

Wolfram Language & System Documentation Center

Flatten[list]

flattens out nested lists.

Flatten[list,n]

flattens to level n.

Flatten[list,n,h]

flattens subexpressions with head h.

Flatten[list,{{s11,s12,…},{s21,s22,…},…}]

flattens list by combining all levels sij to make each level i in the result.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Level Specification  
Input Arrays  
Applications  
Properties & Relations  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

Flatten

Flatten[list]

flattens out nested lists.

Flatten[list,n]

flattens to level n.

Flatten[list,n,h]

flattens subexpressions with head h.

Flatten[list,{{s11,s12,…},{s21,s22,…},…}]

flattens list by combining all levels sij to make each level i in the result.

Details

  • Flatten "unravels" lists, effectively just deleting inner braces.
  • Flatten[list,n] effectively flattens the top level in list n times.
  • Flatten[f[e,…]] flattens out subexpressions with head f.
  • If the mij are matrices, Flatten[{{m11,m12},{m21,m22}},{{1,3},{2,4}}] effectively constructs a single matrix from the "blocks" mij.
  • Flatten[list,{{i1},{i2},…}] effectively transposes levels in list, putting level ik in list at level k in the result. Note that the function Transpose in effect uses an inverse of this specification.
  • Flatten flattens out levels in SparseArray objects just as in the corresponding ordinary arrays. »

Examples

open all close all

Basic Examples  (3)

Flatten out lists at all levels:

Wolfram Language code: Flatten[{{a, b}, {c, {d}, e}, {f, {g, h}}}]

Flatten only at level 1:

Wolfram Language code: Flatten[{{a, b}, {c, {d}, e}, {f, {g, h}}}, 1]

Flatten levels 2 and 3 of an array of depth 3 into the first level of the resulting matrix:

Wolfram Language code: Flatten[RandomReal[1, {3, 5, 7}], {{2, 3}, {1}}]//Dimensions

Scope  (10)

Level Specification  (6)

No flattening:

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}, 0]

Flatten to level 1:

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}, 1]

Flatten to level 2:

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}, 2]

Flatten to level 3:

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}, 3]

Flatten to level 4:

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}, 4]

This is the same as using level :

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}, ∞]

And the same as not specifying a level:

Wolfram Language code: Flatten[{0, {1}, {{2, -2}}, {{{3}, {-3}}}, {{{{4}}}}}]

Here is a matrix:

Wolfram Language code: u = {{a, b}, {c, d}}

Flatten an array of blocks with the shape of u into a single matrix:

Wolfram Language code: Flatten[{{u, 0 u}, {0 u, u}}, {{1, 3}, {2, 4}}]//MatrixForm

Flatten into a single matrix, effectively using the transpose of the blocks:

Wolfram Language code: Flatten[{{u, 0 u}, {0 u, u}}, {{1, 4}, {2, 3}}]//MatrixForm

Input Arrays  (4)

Flatten a sparse array:

Wolfram Language code: Flatten[SparseArray[{{1, 2} -> a, {6, 4} -> b}]]
Wolfram Language code: Normal[%]

Flatten a QuantityArray object:

Wolfram Language code: Flatten[QuantityArray[{{1, 2}, {3, 4}, {5, 6}}, "Knots"]]
Wolfram Language code: Normal[%]

Flatten works with any head:

Wolfram Language code: Flatten[f[f[x, y], z]]

Flatten all levels with respect to g:

Wolfram Language code: Flatten[f[g[u, v], f[x, y]], Infinity, g]

Flatten all levels with respect to f:

Wolfram Language code: Flatten[f[g[u, v], f[x, y]], Infinity, f]

Applications  (5)

Join lists and individual elements:

Wolfram Language code: Range[5]
Wolfram Language code: Flatten[{%, x, %, %, y}]

Unravel a matrix:

Wolfram Language code: Table[i ^ j, {i, 3}, {j, 4}]
Wolfram Language code: Flatten[%]

Make a flattened list of rules:

Wolfram Language code: Table[i -> j, {i, 4}, {j, 3}]
Wolfram Language code: Flatten[%]

Do a "transpose" on a ragged array:

Wolfram Language code: list = Table[i + j - 1, {i, 4}, {j, i}]
Wolfram Language code: Flatten[list, {{2}, {1}}]

Contract three levels of arrays in a single Dot operation by flattening them first:

Wolfram Language code: array = RandomInteger[10, {2, 5, 6, 4}];
Wolfram Language code: Flatten[array, {{1}, {2, 3, 4}}].Flatten[array, {{2, 3, 4}, {1}}]

Obtain the same result by explicit contraction of three pairs of levels:

Wolfram Language code: TensorContract[TensorProduct[array, array], {{2, 6}, {3, 7}, {4, 8}}]

Properties & Relations  (5)

Flatten acts as an inverse of Partition:

Wolfram Language code: Range[20]
Wolfram Language code: Partition[%, 4]
Wolfram Language code: Flatten[%]

ArrayReshape acts as an inverse for Flatten on rectangular arrays:

Wolfram Language code: array = RandomInteger[9, {3, 2, 4}]
Wolfram Language code: Flatten[array]
Wolfram Language code: ArrayReshape[%, {3, 2, 4}]

For a rectangular array a, ArrayFlatten[a,r] is equivalent to Flatten[a,{{1,r+1},{2,r+2},…,{r,2r}}]:

Wolfram Language code: array = RandomInteger[10, {2, 3, 4, 5, 6, 7, 8}];
Wolfram Language code: ArrayFlatten[array, 3] === Flatten[array, {{1, 4}, {2, 5}, {3, 6}}]

Flatten effectively arranges elements in the lexicographic order of their indices:

Wolfram Language code: Flatten[Array[a, {3, 4}]]
Wolfram Language code: Flatten[Array[100#1 + 10#2 + #3&, {3, 3, 3}]]

For a permutation p with inverse , Flatten[a,List/@p-1]==Transpose[a,p]:

Wolfram Language code: list = Array[Subscript[a, ##]&, {2, 3, 4, 2}];

A random permutation:

Wolfram Language code: p = RandomSample[Range[4]]

Get its inverse:

Wolfram Language code: invp = InversePermutation[p]
Wolfram Language code: Flatten[list, List /@ invp] == Transpose[list, p]

Neat Examples  (1)

Peel off successive layers of Framed:

Wolfram Language code: NestList[Flatten[#, 1]&, Nest[Framed, x, 6], 10]
Wolfram Research (1988), Flatten, Wolfram Language function, https://reference.wolfram.com/language/ref/Flatten.html (updated 2007).

Text

Wolfram Research (1988), Flatten, Wolfram Language function, https://reference.wolfram.com/language/ref/Flatten.html (updated 2007).

CMS

Wolfram Language. 1988. "Flatten." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2007. https://reference.wolfram.com/language/ref/Flatten.html.

APA

Wolfram Language. (1988). Flatten. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Flatten.html

BibTeX

@misc{reference.wolfram_2026_flatten, author="Wolfram Research", title="{Flatten}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Flatten.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_flatten, organization={Wolfram Research}, title={Flatten}, year={2007}, url={https://reference.wolfram.com/language/ref/Flatten.html}, note=[Accessed: 12-June-2026]}