WOLFRAM

Wolfram Language & System Documentation Center

FresnelG[z]

gives the Fresnel auxiliary function TemplateBox[{z}, FresnelG].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation and Integration  
Series Expansions  
Function Identities and Simplifications  
Other Features  
Applications  
Neat Examples  
See Also
Related Guides
History
Cite this Page

FresnelG

FresnelG[z]

gives the Fresnel auxiliary function TemplateBox[{z}, FresnelG].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • TemplateBox[{z}, FresnelG]=(1/2-TemplateBox[{z}, FresnelC]) cos(pi z^2/2)+(1/2-TemplateBox[{z}, FresnelS]) sin(pi z^2/2).
  • FresnelG[z] is an entire function of z with no branch cut discontinuities.
  • For certain special arguments, FresnelG automatically evaluates to exact values.
  • FresnelG can be evaluated to arbitrary numerical precision.
  • FresnelG automatically threads over lists.
  • FresnelG can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples  (4)

Evaluate numerically:

Wolfram Language code: FresnelG[1.1]

Plot over a subset of the reals:

Wolfram Language code: Plot[FresnelG[z], {z, -4, 4}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[FresnelG[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[FresnelG[x], {x, 0, 8}]

Scope  (32)

Numerical Evaluation  (5)

Evaluate numerically to high precision:

Wolfram Language code: N[FresnelG[1], 20]

Precision of the output tracks the precision of the input:

Wolfram Language code: FresnelG[1.00000000000000000000000]

Evaluate for complex argument:

Wolfram Language code: FresnelG[1.2 + 2. I]

Evaluate FresnelG efficiently at high precision:

Wolfram Language code: FresnelG[2`500]//Timing
Wolfram Language code: FresnelG[2`10000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: FresnelG[Interval[{1.23, 1.24}]]
Wolfram Language code: FresnelG[CenteredInterval[1 / 2, 1 / 1000]]
Wolfram Language code: FresnelG[CenteredInterval[1 + I, (1 + I) / 10 ^ 6]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: FresnelG[ Around[1 / 2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: FresnelG[{{1.1, .2}, {.2, 1.2}}]

Or compute the matrix FresnelG function using MatrixFunction:

Wolfram Language code: MatrixFunction[FresnelG, {{1.1, .2}, {.2, 1.2}}]

Specific Values  (3)

Value at a fixed point:

Wolfram Language code: FresnelG[0]

Values at infinity:

Wolfram Language code: FresnelG[Infinity]
Wolfram Language code: FresnelG[ComplexInfinity]

Find a local maximum as a root of (dTemplateBox[{x}, FresnelG])/(dx)=0:

Wolfram Language code: xmax = Solve[D[FresnelG[x], x] == 0 && -1.0 < x < 0, x][[1, 1, 2]]//Quiet
Wolfram Language code: Plot[FresnelG[x], {x, -2, 2}, Epilog -> Style[Point[{xmax, FresnelG[xmax]}], PointSize[Large], Red]]

Visualization  (2)

Plot the FresnelG function:

Wolfram Language code: Plot[FresnelG[x], {x, -7, 7}]

Plot the real part of TemplateBox[{z}, FresnelG]:

Wolfram Language code: ComplexContourPlot[Re[FresnelG[z]], {z, -2 - 2I, 2 + 2 I}, Contours -> 20]

Plot the imaginary part of TemplateBox[{z}, FresnelG]:

Wolfram Language code: ComplexContourPlot[Im[FresnelG[z]], {z, -2 - 2I, 2 + 2 I}, Contours -> 20]

Function Properties  (9)

FresnelG is defined for all real and complex values:

Wolfram Language code: FunctionDomain[FresnelG[x], x]
Wolfram Language code: FunctionDomain[FresnelG[z], z, Complexes]

Approximate function range of FresnelG:

Wolfram Language code: FunctionRange[FresnelG[x], x, y]//N

FresnelG is an analytic function of x:

Wolfram Language code: FunctionAnalytic[FresnelG[x], x]

FresnelG is monotonic in a specific range:

Wolfram Language code: FunctionMonotonicity[FresnelG[x], x]
Wolfram Language code: FunctionMonotonicity[{FresnelG[x], 0 < x < 3}, x]

FresnelG is not injective:

Wolfram Language code: FunctionInjective[FresnelG[x], x]
Wolfram Language code: Plot[{FresnelG[x], 1 / 2}, {x, -6, 6}]

FresnelG is not surjective:

Wolfram Language code: FunctionSurjective[FresnelG[x], x]
Wolfram Language code: Plot[{FresnelG[x], 2}, {x, -6, 6}]

FresnelG is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[FresnelG[x], x]

FresnelG has no singularities or discontinuities:

Wolfram Language code: FunctionSingularities[FresnelG[x], x]
Wolfram Language code: FunctionDiscontinuities[FresnelG[x], x]

Neither convex nor concave:

Wolfram Language code: FunctionConvexity[FresnelG[x], x]

Differentiation and Integration  (5)

First derivative:

Wolfram Language code: D[FresnelG[x], x]

Higher derivatives:

Wolfram Language code: Table[D[FresnelG[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -2, 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

Indefinite integral of FresnelG:

Wolfram Language code: Integrate[FresnelG[x], x]//FullSimplify

More integrals:

Wolfram Language code: ∫ z^αFresnelG[z^2]ⅆz//TraditionalForm
Wolfram Language code: ∫ FresnelG[Sqrt[z]]ⅆz//TraditionalForm

Approximation of the definite integral of FresnelG:

Wolfram Language code: NIntegrate[FresnelG[x], {x, -4, 4}]

Series Expansions  (4)

Taylor expansion for FresnelG:

Wolfram Language code: Series[FresnelG[x], {x, 0, 6}]

Plot the first three approximations for FresnelG around :

Wolfram Language code: terms = Normal@{Series[FresnelG[x], {x, 0, 1}], Series[FresnelG[x], {x, 0, 2}], Series[FresnelG[x], {x, 0, 4}]}; Plot[{FresnelG[x], terms}, {x, -1, 1}]

Taylor expansion for FresnelG at a generic point:

Wolfram Language code: Series[FresnelG[x], {x, x0, 1}]

Find series expansion at infinity:

Wolfram Language code: Series[FresnelG[x], {x, Infinity, 9}]

Give the result for an arbitrary symbolic direction :

Wolfram Language code: Series[FresnelG[x], {x, DirectedInfinity[z], 5}]

Function Identities and Simplifications  (2)

Primary definition:

Wolfram Language code: FresnelG[z] == (1 / 2 - FresnelC[z]) Cos[π z^2 / 2] + (1 / 2 - FresnelS[z])Sin[π z^2 / 2] //FullSimplify

Argument simplifications:

Wolfram Language code: FresnelG[I z]//FunctionExpand
Wolfram Language code: FresnelG[Sqrt[z^2]]//FunctionExpand

Other Features  (2)

FresnelG threads elementwise over lists and matrices:

Wolfram Language code: FresnelG[{-1., 1., 2.}]
Wolfram Language code: FresnelG[(| | | | :- | :- | | 0 | u | | v | ∞ |) ]//MatrixForm

TraditionalForm typesetting:

Wolfram Language code: FresnelG[z]//TraditionalForm

Applications  (3)

Interference pattern at the edge of a shadow:

Wolfram Language code: Plot[FresnelF[x] ^ 2 + FresnelG[x] ^ 2, {x, -8, 8}]

Plot a clothoid:

Wolfram Language code: ParametricPlot[(1/2) - RotationMatrix[(π t^2/2)].{FresnelG[t], FresnelF[t]}, {t, -5, 5}]

A solution of the time‐dependent 1D Schrödinger equation for a sudden opening of a shutter:

Wolfram Language code: ψ[x_, t_] = E^-(I (t - 2 x)/2) (1 - E^(I (t - x)^2/2 t)((1 + I/2)FresnelF[(t - x/Sqrt[π t])] + (1 - I/2)FresnelG[(t - x/Sqrt[π t])]));

Check the Schrödinger equation:

Wolfram Language code: I D[ψ[x, t], t] == -(1/2)D[ψ[x, t], x, x]//Expand

Plot the time‐dependent solution:

Wolfram Language code: Plot3D[Abs[ψ[x, t]], {x, -5, 5}, {t, 0, 5}]

Neat Examples  (1)

A generalized helix in terms of Fresnel auxiliary functions:

Wolfram Language code: ParametricPlot3D[{FresnelF[x], FresnelG[x], x}, {x, -7, 2}]
Wolfram Research (2014), FresnelG, Wolfram Language function, https://reference.wolfram.com/language/ref/FresnelG.html.

Text

Wolfram Research (2014), FresnelG, Wolfram Language function, https://reference.wolfram.com/language/ref/FresnelG.html.

CMS

Wolfram Language. 2014. "FresnelG." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FresnelG.html.

APA

Wolfram Language. (2014). FresnelG. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FresnelG.html

BibTeX

@misc{reference.wolfram_2026_fresnelg, author="Wolfram Research", title="{FresnelG}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/FresnelG.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_fresnelg, organization={Wolfram Research}, title={FresnelG}, year={2014}, url={https://reference.wolfram.com/language/ref/FresnelG.html}, note=[Accessed: 12-June-2026]}