WOLFRAM

Wolfram Language & System Documentation Center

GeoMarker[]

is a GeoGraphics primitive that represents a marker at the current $GeoLocation.

GeoMarker[loc]

is a GeoGraphics primitive that represents a marker at the location loc.

GeoMarker[{loc1,loc2,…}]

is a GeoGraphics primitive that represents markers at locations loci.

GeoMarker[loc,marker]

is a GeoGraphics primitive that represents a custom marker at the location loc.

GeoMarker[{loc1,loc2,…},marker]

is a GeoGraphics primitive that represents custom markers at locations loci.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Location  
Marker  
Options  
"Alignment"  
"Color"  
"Scale"  
Applications  
Neat Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

GeoMarker

GeoMarker[]

is a GeoGraphics primitive that represents a marker at the current $GeoLocation.

GeoMarker[loc]

is a GeoGraphics primitive that represents a marker at the location loc.

GeoMarker[{loc1,loc2,…}]

is a GeoGraphics primitive that represents markers at locations loci.

GeoMarker[loc,marker]

is a GeoGraphics primitive that represents a custom marker at the location loc.

GeoMarker[{loc1,loc2,…},marker]

is a GeoGraphics primitive that represents custom markers at locations loci.

Details and Options

  • GeoMarker is a GeoGraphics primitive.
  • The loci can be specified as latitude and longitude coordinates {lat,lon}, as GeoPosition[{lat,lon}], or as a named Entity[…].
  • Coordinates and entities can be used together. The "Position" property is used for entities.
  • The default marker is a pushpin.
  • A custom marker can be defined as a Graphics or an Image. By default, the marker is centered at the origin of its internal coordinate system.
  • The following options can be given to GeoMarker:
  • "Alignment" Automatichow to align the marker
    "Color" Automaticmarker color
    "Scale" Automaticmarker scale
  • The same settings possible for Alignment can be used for "Alignment", including:
  • Automaticdefault alignment based on the environment
    Leftleft aligned
    Rightright aligned
    Toptop aligned
    Bottombottom aligned
    Centercentered

Examples

open all close all

Basic Examples  (4)

Show the location of a city with a marker:

Wolfram Language code: GeoGraphics[{GeoStyling["OutlineMap"], Polygon[Entity["Country", "Italy"]], GeoMarker[Entity["City", {"Rome", "Lazio", "Italy"}]]}]

Use the Wolfram Spikey as a marker:

Wolfram Language code: GeoGraphics[GeoMarker[$GeoLocation, EntityValue[Entity["Polyhedron", "WolframSpikey"], "Image"]]]

Use an icon as a marker:

Wolfram Language code: GeoGraphics[GeoMarker[GeoNearest["Museum", Entity["City", {"Indianapolis", "Indiana", "UnitedStates"}], {All, Quantity[4, "Mile"]}], Entity["Icon", "Museum"]]]

Use a stylized pin as a custom marker:

Wolfram Language code: Show[mypin = Graphics[GraphicsGroup[{FaceForm[Orange], FilledCurve[{{Line[Join[{{0, 0}}, ({Cos[#1], 3 + Sin[#1]}&) /@ Range[-(2 π/20), π + (2 π/20), (π/20)], {{0, 0}}]]}, {Line[(0.5 {Cos[#1], 6 + Sin[#1]}&) /@ Range[0, 2 π, (π/20)]]}}]}]], Axes -> True, ImageSize -> Small]

Place the pin on London in a map of the UK:

Wolfram Language code: GeoGraphics[{Entity["Country", "UnitedKingdom"], GeoMarker[Entity["City", {"London", "GreaterLondon", "UnitedKingdom"}], mypin, "Alignment" -> Bottom]}]

Scope  (7)

Location  (4)

Place a geo marker at the current location:

Wolfram Language code: GeoGraphics[GeoMarker[]]

Place a geo marker at a specific geo position:

Wolfram Language code: GeoGraphics[GeoMarker[{48.8583, 2.2944}], GeoRange -> Quantity[200, "Meters"], GeoBackground -> "Satellite"]

Place a geo marker at a location specified by an entity:

Wolfram Language code: GeoGraphics[GeoMarker[Entity["Building", "GreatPyramidOfGiza::jbm66"]], GeoRange -> Quantity[500, "Meters"], GeoBackground -> "Satellite"]

Place multiple geo markers:

Wolfram Language code: volcanoes = GeoEntities[Entity["Country", "UnitedStates"], "Volcano"];
Wolfram Language code: GeoGraphics[GeoMarker[volcanoes, "Scale" -> .015], GeoRange -> Entity["Country", "UnitedStates"], ImageSize -> Large, GeoBackground -> "ReliefMap"]

Marker  (3)

Use the default geo marker:

Wolfram Language code: GeoGraphics[GeoMarker[GeoPosition["NorthPole"]], GeoGridLines -> Automatic, GeoRange -> Quantity[2000, "Kilometers"]]

Use a custom marker:

Wolfram Language code: hat = [image];
Wolfram Language code: GeoGraphics[GeoMarker[GeoPosition["NorthPole"], hat, "Scale" -> 0.1], GeoGridLines -> Automatic, GeoRange -> Quantity[2000, "Kilometers"]]

Place a black mountain icon at the given locations:

Wolfram Language code: GeoGraphics[GeoMarker[{Entity["Mountain", "Aconcagua"], Entity["Mountain", "MountEverest"], Entity["Mountain", "MontBlanc"]}, [image], "Color" -> Black], GeoRange -> "World", GeoBackground -> "Plain"]

Options  (4)

"Alignment"  (1)

Center centering:

Wolfram Language code: Show[lonestar = Graphics[GraphicsGroup[{ EdgeForm[], Blue, Opacity[.5], Polygon[{{-1, -1}, {1, -1}, {1, 1}, {-1, 1}}], White, Opacity[.8], Polygon[Table[Through[{Sin, Cos}[4π k / 5]], {k, 5}]], Polygon[Table[{1, -1} / GoldenRatio ^ 2Through[{Sin, Cos}[2π k / 5]], {k, 5}]] }]], Axes -> True, ImageSize -> Small]
Wolfram Language code: GeoGraphics[{Polygon[Entity["AdministrativeDivision", {"Texas", "UnitedStates"}]], GeoMarker[Entity["City", {"Austin", "Texas", "UnitedStates"}], lonestar, "Alignment" -> Center]}]

Bottom centering:

Wolfram Language code: Show[mypin = Graphics[GraphicsGroup[{FaceForm[Red], Opacity[.7], FilledCurve[{{Line[Join[{{0, 0}}, ({Cos[#1], 3 + Sin[#1]}&) /@ Range[-(2 π/20), π + (2 π/20), (π/20)], {{0, 0}}]]}, {Line[(0.5 {Cos[#1], 6 + Sin[#1]}&) /@ Range[0, 2 π, (π/20)]]}}]}]], Axes -> True, ImageSize -> Small]
Wolfram Language code: With[{city = Entity["City", {"Rome", "Lazio", "Italy"}]}, GeoGraphics[ GeoMarker[city, mypin, "Alignment" -> Bottom], GeoCenter -> city, GeoRange -> Quantity[100, "Kilometers"]]]

"Color"  (1)

Use a green pushpin:

Wolfram Language code: GeoGraphics[{ GeoStyling["OutlineMap"], Polygon[Entity["Country", "Italy"]], GeoMarker[Entity["City", {"Rome", "Lazio", "Italy"}], "Color" -> Green] }]

Various colors:

Wolfram Language code: GeoGraphics[{ Polygon[Entity["Country", "UnitedStates"]], GeoMarker[Entity["City", {"NewYork", "NewYork", "UnitedStates"}], "Color" -> Green], GeoMarker[Entity["City", {"LosAngeles", "California", "UnitedStates"}], "Color" -> Red], GeoMarker[Entity["City", {"Chicago", "Illinois", "UnitedStates"}], "Color" -> Blue] }]

"Scale"  (2)

Adjust the scale of the pushpin in absolute points:

Wolfram Language code: GeoGraphics[{GeoStyling["OutlineMap"], Polygon[Entity["Country", "Italy"]], GeoMarker[Entity["City", {"Rome", "Lazio", "Italy"}], "Scale" -> Offset[#]]}]& /@ {10, 20, 50}

The marker size is independent of the size of the graphic:

Wolfram Language code: GeoGraphics[{GeoStyling["OutlineMap"], Polygon[Entity["Country", "Italy"]], GeoMarker[Entity["City", {"Rome", "Lazio", "Italy"}], "Scale" -> Offset[30]]}, ImageSize -> #]& /@ {60, 120, 180}

Adjust the scale of the pushpin in scaled sizes:

Wolfram Language code: GeoGraphics[{GeoStyling["OutlineMap"], Polygon[Entity["Country", "Italy"]], GeoMarker[Entity["City", {"Rome", "Lazio", "Italy"}], "Scale" -> Scaled[#]]}]& /@ {0.05, 0.1, 0.25}

The marker size scales with the size of the graphic:

Wolfram Language code: GeoGraphics[{GeoStyling["OutlineMap"], Polygon[Entity["Country", "Italy"]], GeoMarker[Entity["City", {"Rome", "Lazio", "Italy"}], "Scale" -> Scaled[0.2]]}, ImageSize -> #]& /@ {60, 120, 180}

Applications  (1)

Place geo markers in the 10 largest US cities, with marker size proportional to population:

Wolfram Language code: With[{country = Entity["Country", "UnitedStates"]}, GeoGraphics[{Polygon[country], Tooltip[GeoMarker[GeoPosition[#], "Scale" -> 3*^-8QuantityMagnitude[pop = CityData[#, "Population"]]], Column[{CommonName[#], pop}]]& /@ Take[CityData[{Large, CanonicalName[country]}], 10]}]]

Neat Examples  (1)

Construct a graphic for the most populous large mammal in New Zealand:

Wolfram Language code: Graphics[sheep = Cases[ParametricPlot[Evaluate[EntityValue[Entity["PopularCurve", "SheepCurve"], EntityProperty["PopularCurve", "ParametricEquations"]][t]], {t, 0, 2 π}, Axes -> False],  Line[x_] :> Polygon[x], {1, ∞}], ImageSize -> Tiny]

Use the graphic as a geo marker for the most populous (by humans) Kiwi cities:

Wolfram Language code: With[{NZ = Entity["Country", "NewZealand"]}, GeoGraphics[{GeoStyling["ReliefMap"], Polygon[NZ], GeoStyling["StreetMapLabelsOnly"], Polygon[NZ], Tooltip[GeoMarker[#1, Graphics[{Opacity[0.5], FaceForm[RandomColor[]], EdgeForm[Black], sheep}], "Alignment" -> Center], #2]&@@@EntityValue[CityData[{Large, "NewZealand"}], {"Position", "Name"}]}]]
Wolfram Research (2014), GeoMarker, Wolfram Language function, https://reference.wolfram.com/language/ref/GeoMarker.html.

Text

Wolfram Research (2014), GeoMarker, Wolfram Language function, https://reference.wolfram.com/language/ref/GeoMarker.html.

CMS

Wolfram Language. 2014. "GeoMarker." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/GeoMarker.html.

APA

Wolfram Language. (2014). GeoMarker. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GeoMarker.html

BibTeX

@misc{reference.wolfram_2026_geomarker, author="Wolfram Research", title="{GeoMarker}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/GeoMarker.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_geomarker, organization={Wolfram Research}, title={GeoMarker}, year={2014}, url={https://reference.wolfram.com/language/ref/GeoMarker.html}, note=[Accessed: 13-June-2026]}