WOLFRAM

Wolfram Language & System Documentation Center

GeoReposition[gdata,pos1pos2]

moves the geo data gdata along the great circle from pos1 to pos2, preserving North.

GeoReposition[gdata,{pos1pos2,α}]

performs an additional rotation of angle α around pos2.

GeoReposition[gdata,mat]

performs the rotation specified by the 3D rotation matrix mat.

GeoReposition[rot]

represents an operator form of GeoReposition that can be applied to an expression.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Possible Issues  
See Also
History
Cite this Page

GeoReposition

GeoReposition[gdata,pos1pos2]

moves the geo data gdata along the great circle from pos1 to pos2, preserving North.

GeoReposition[gdata,{pos1pos2,α}]

performs an additional rotation of angle α around pos2.

GeoReposition[gdata,mat]

performs the rotation specified by the 3D rotation matrix mat.

GeoReposition[rot]

represents an operator form of GeoReposition that can be applied to an expression.

Details

  • GeoReposition moves locations and geo primitives using spherical rotations, hence approximately preserving shapes and areas on ellipsoidal geo models.
  • Rotations are performed clockwise around the rotation axis.
  • The geo data gdata can be a GeoPosition object, a geo entity, a geo primitive or a list of any of them, possibly including graphics directives, that are left unmodified.
  • GeoReposition[gdata,{pos,α}] is equivalent to GeoReposition[gdata,{pospos,α}], performing a clockwise rotation of angle α around pos.
  • The angle α in GeoReposition[gdata,{…,α}] can be given as a Quantity angle or a number of degrees.
  • GeoReposition[rot][gdata] is equivalent to GeoReposition[gdata,rot].

Examples

open all close all

Basic Examples  (2)

Move the US polygon over Europe:

Wolfram Language code: GeoReposition[Entity["Country", "UnitedStates"]["Polygon"], Entity["City", {"KansasCity", "Missouri", "UnitedStates"}] -> Entity["City", {"Vienna", "Vienna", "Austria"}]]
Wolfram Language code: GeoGraphics[%]

Displace and rotate 90 degrees the polygon of Argentina over Australia:

Wolfram Language code: GeoReposition[{Red, Entity["Country", "Argentina"]["Polygon"]}, {Entity["City", {"BuenosAires", "BuenosAires", "Argentina"}] -> GeoPosition[{-31, 137}], 90}]
Wolfram Language code: GeoGraphics[%, GeoRange -> Entity["Country", "Australia"]]

Scope  (5)

Move a geo location 90 degrees about the North Pole:

Wolfram Language code: GeoReposition[GeoPosition[{40, 0}], {"NorthPole", 90}]

Compare the US East Coast with the northwest coast of Australia:

Wolfram Language code: GeoReposition[Entity["Country", "Australia"]["Polygon"], {GeoPosition[{-15, -230}] -> GeoPosition[{42, -67}], -12}]
Wolfram Language code: GeoGraphics[%, GeoRange -> {{13, 52}, {-116, -43}}]

Move 85 degrees west the polygon of Portugal:

Wolfram Language code: portugal = EntityValue[Entity["Country", "Portugal"], "Polygon"]
Wolfram Language code: GeoReposition[portugal, {GeoPosition[{90, 0}], 85}]

Compare it with the polygon of the state of Illinois:

Wolfram Language code: GeoGraphics[{Red, %, Blue, Polygon[Entity["AdministrativeDivision", {"Illinois", "UnitedStates"}]]}, GeoBackground -> "MinimalGray"]

Move Chile over Australia:

Wolfram Language code: GeoReposition[Entity["Country", "Chile"]["Polygon"], {Entity["City", {"Santiago", "Metropolitana", "Chile"}] -> GeoPosition[{-27, 137}], 90}]
Wolfram Language code: GeoGraphics[%]

Use GeoReposition as an operator form:

Wolfram Language code: rot = GeoReposition[{Entity["City", {"Rome", "Lazio", "Italy"}] -> Entity["City", {"BuenosAires", "BuenosAires", "Argentina"}], -90}]
Wolfram Language code: Entity["Country", "Italy"]["Polygon"]
Wolfram Language code: rot[%]

Applications  (1)

Show the large area distortion of the Mercator projection by moving Greenland over Africa:

Wolfram Language code: greenland = EntityValue[Entity["Country", "Greenland"], "Polygon"]

Take a point p in Greenland and a point q in Africa:

Wolfram Language code: p = GeoPosition[{75, -40}]; q = GeoPosition[{0, 20}];

Rotate the polygon of Greenland so that point p is moved to q:

Wolfram Language code: rotated = GeoReposition[greenland, p -> q]

Show the difference in sizes:

Wolfram Language code: GeoGraphics[{GeoStyling@Orange, Polygon[Entity["GeographicRegion", "Africa"]], GeoStyling@Blue, Polygon[Entity["Country", "Greenland"]], rotated, Arrow[GeoPath[{p, q}]]}, GeoProjection -> "Mercator", GeoRange -> "World", GeoGridLines -> Automatic]

The area of Africa is much larger than the area of Greenland:

Wolfram Language code: GeoArea[Entity["GeographicRegion", "Africa"]] / GeoArea[Entity["Country", "Greenland"]]

Show the same transformation in an equal-area projection:

Wolfram Language code: GeoGraphics[{GeoStyling@Orange, Polygon[Entity["GeographicRegion", "Africa"]], GeoStyling@Blue, Polygon[Entity["Country", "Greenland"]], rotated, Arrow[GeoPath[{p, q}]]}, GeoProjection -> "Mollweide", GeoRange -> "World"]

Possible Issues  (1)

GeoReposition performs spherical rotations, so ellipsoidal GeoArea results may change slightly:

Wolfram Language code: brazil = Entity["Country", "Brazil"]["Polygon"];
Wolfram Language code: newbrazil = GeoReposition[brazil, Entity["City", {"Brasilia", "DistritoFederal", "Brazil"}] -> Entity["City", {"Reykjavik", "Hofudhborgarsvaedhi", "Iceland"}]];
Wolfram Language code: {GeoArea[brazil], GeoArea[newbrazil]}

The GeoArea results coincide when using a spherical model for the Earth:

Wolfram Language code: {GeoArea[brazil, GeoModel -> "SphericalEarth"], GeoArea[newbrazil, GeoModel -> "SphericalEarth"]}
Wolfram Research (2025), GeoReposition, Wolfram Language function, https://reference.wolfram.com/language/ref/GeoReposition.html.

Text

Wolfram Research (2025), GeoReposition, Wolfram Language function, https://reference.wolfram.com/language/ref/GeoReposition.html.

CMS

Wolfram Language. 2025. "GeoReposition." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/GeoReposition.html.

APA

Wolfram Language. (2025). GeoReposition. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GeoReposition.html

BibTeX

@misc{reference.wolfram_2026_georeposition, author="Wolfram Research", title="{GeoReposition}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/GeoReposition.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_georeposition, organization={Wolfram Research}, title={GeoReposition}, year={2025}, url={https://reference.wolfram.com/language/ref/GeoReposition.html}, note=[Accessed: 12-June-2026]}