WOLFRAM

Wolfram Language & System Documentation Center

GeometricStylingRules

is an option to GeometricScene that specifies how to style structures in GeometricScene.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
History
Cite this Page

GeometricStylingRules

GeometricStylingRules

is an option to GeometricScene that specifies how to style structures in GeometricScene.

Details

  • GeometricStylingRules is typically used to highlight structures in a GeometricScene.
  • The settings for GeometricStylingRules are input as a list of rules, with the following possibilities for the left side of each rule:
  • "PointStyle"highlight points
    "StylingPatterns"highlight hypotheses in the second argument
    "ConclusionStyle"highlight conclusions in the third argument
  • "PointStyle" can be set to the following:
  • Automaticautomatic point styling
    Nonepoints do not appear at all
    {d1,d2,…}list of styling directives
  • "StylingPatterns" can be set to the following:
  • Noneno additional stylings
    {p1d1,p2d2,…}use styling directives di for structures pi
  • In the list of styling rules, the pi may be any pattern that matches a geometric structure as it is entered in the GeometricScene, and the di may be any list of styling directives.
  • "ConclusionStyle" can be set to the following:
  • Automaticautomatic stylings for conclusions
    Noneno additional stylings for conclusions
    {d1,d2,…}list of styling directives

Examples

open all close all

Basic Examples  (3)

Style points brown:

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c, d}, {Polygon[{a, b, c, d}]}, GeometricStylingRules -> {"PointStyle" -> Brown}]]

Style everything green:

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c}, {CircleThrough[{a, b, c}], Triangle[{a, b, c}]}, {}, GeometricStylingRules -> {"StylingPatterns" -> {_ -> Darker[Green]}}]]

Highlight the triangle mentioned in the conclusion as purple:

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c}, {GeometricStep[{Line[{a, b}]}], GeometricStep[{CircleThrough[{b, c}, a], CircleThrough[{a, c}, b]}], GeometricStep[{Triangle[{a, b, c}]}]}, {GeometricAssertion[Triangle[{a, b, c}], "Regular"]}, GeometricStylingRules -> {"ConclusionStyle" -> {Purple}}]]

Scope  (6)

Specify size and font for point labels:

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c}, {Triangle[{a, b, c}]}, {}, GeometricStylingRules -> {"PointStyle" -> Directive[PointSize[0.1], FontSize -> 40, FontFamily -> "Comic Sans MS"]}]]

Remove point labels:

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c}, {Triangle[{a, b, c}]}, {}, GeometricStylingRules -> {"PointStyle" -> None}]]

Only conclusions that can be returned by FindGeometricConjectures will be styled:

Wolfram Language code: FindGeometricConjectures[GeometricScene[{a, b, c, o}, {Triangle[{a, b, c}], CircleThrough[{a, b, c}, o], o == Midpoint[{a, c}]}, {PlanarAngle[{a, b, c}] == 90Degree}, GeometricStylingRules -> {"ConclusionStyle" -> {Green}}]]

Not all conclusions can be styled:

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c, o}, {Triangle[{a, b, c}], CircleThrough[{a, b, c}, o], o == Midpoint[{a, c}]}, {PlanarAngle[{a, c, b}] + PlanarAngle[{b, a, c}] == 90Degree}, GeometricStylingRules -> {"ConclusionStyle" -> {Green}}]]

Styling directives made inside the second argument take precedence over those made via options:

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c}, {Style[CircleThrough[{a, b, c}], Blue], Triangle[{a, b, c}]}, {}, GeometricStylingRules -> {"StylingPatterns" -> {_ -> Red}}]]

Styling rules may be delayed:

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c, d, e, o}, {Polygon[{a, b, c, d, e}], p1 == Triangle[{a, b, o}], p2 == Triangle[{b, o, c}], p3 == Triangle[{c, d, o}], p4 == Triangle[{d, o, e}], p5 == Triangle[{e, o, a}], GeometricAssertion[{p1, p2, p3, p4, p5}, "Similar"] }, GeometricStylingRules -> {"StylingPatterns" -> {_ :> RandomColor[]}} ]]

Properties & Relations  (1)

If no conclusion styling is specified, conclusions that can be returned by FindGeometricConjectures will be highlighted orange:

Wolfram Language code: scene = FindGeometricConjectures[GeometricScene[{a, b, c}, {GeometricStep[{Line[{a, b}]}], GeometricStep[{CircleThrough[{b, c}, a], CircleThrough[{a, c}, b]}], GeometricStep[{Triangle[{a, b, c}]}]}]]

Change the highlighting to magenta:

Wolfram Language code: GeometricScene[scene, GeometricStylingRules -> {"ConclusionStyle" -> Magenta}]

Remove all styling from the conclusion:

Wolfram Language code: GeometricScene[scene, GeometricStylingRules -> {"ConclusionStyle" -> None}]

Possible Issues  (1)

By default, two-dimensional regions are not drawn fully opaque, so the intersection of two such regions may not have the specified color:

Wolfram Language code: RandomInstance[GeometricScene[{{a, b}, {d}}, {Disk[a, d], Disk[b, d], EuclideanDistance[a, b] == d}, GeometricStylingRules -> {"StylingPatterns" -> {Disk[a, d] -> Green, Disk[b, d] -> Blue}}]]

Neat Examples  (3)

Style Napoleon's theorem with images of Le Petit Caporal himself:

Wolfram Language code: RandomInstance[Append[Entity["GeometricScene", "NapoleonsTheorem"]["Scene"], GeometricStylingRules -> {"StylingPatterns" -> {_Triangle -> PatternFilling[[image], 100]}}]]

Style Barrow's equality with smaller representations of itself:

Wolfram Language code: With[{s = Entity["GeometricScene", "BarrowsEquality"]["Scene"]}, Append[RandomInstance[s], GeometricStylingRules -> {"StylingPatterns" -> {_Triangle -> PatternFilling[Rasterize[RandomInstance[s]], 50]}}]]

Style a scene dynamically:

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c}, {Disk[a, EuclideanDistance[b, c] / 2], Disk[b, EuclideanDistance[a, c] / 2], Disk[c, EuclideanDistance[a, b] / 2], Triangle[{a, b, c}]}, GeometricStylingRules -> {"StylingPatterns" -> {_Triangle -> Dynamic[PatternFilling[{"XGridPoint", RandomColor[]}, RandomReal[{0, 20}]], UpdateInterval -> 1], _Disk -> Dynamic[PatternFilling[{"Grain", RandomColor[]}, RandomReal[{0, 20}]], UpdateInterval -> 1 / Pi]}}]]
Wolfram Research (2022), GeometricStylingRules, Wolfram Language function, https://reference.wolfram.com/language/ref/GeometricStylingRules.html.

Text

Wolfram Research (2022), GeometricStylingRules, Wolfram Language function, https://reference.wolfram.com/language/ref/GeometricStylingRules.html.

CMS

Wolfram Language. 2022. "GeometricStylingRules." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/GeometricStylingRules.html.

APA

Wolfram Language. (2022). GeometricStylingRules. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GeometricStylingRules.html

BibTeX

@misc{reference.wolfram_2026_geometricstylingrules, author="Wolfram Research", title="{GeometricStylingRules}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/GeometricStylingRules.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_geometricstylingrules, organization={Wolfram Research}, title={GeometricStylingRules}, year={2022}, url={https://reference.wolfram.com/language/ref/GeometricStylingRules.html}, note=[Accessed: 12-June-2026]}