Enable JavaScript to interact with content and submit forms on Wolfram websites. Learn how

Wolfram Language & System Documentation Center

GraphCenter

GraphCenter

gives the set of vertices with minimum eccentricity in the graph g.

GraphCenter[{vw,…}]

uses rules vw to specify the graph g.

Details and Options

GraphCenter is also known as the Jordan center.

The following options can be given:
EdgeWeight Automatic weight for each edge

Method Automatic method to use
Possible Method settings include "Dijkstra", "FloydWarshall", and "Johnson".

Examples

open all close all

Basic Examples (1)

Give the graph center for a graph:

Wolfram Language code: g = WheelGraph[6, VertexSize -> Small]

Wolfram Language code: GraphCenter[%]

Highlight the center:

Wolfram Language code: HighlightGraph[g, %]

Scope (7)

GraphCenter works with undirected graphs:

Wolfram Language code: GraphCenter[[image]]

Directed graphs:

Wolfram Language code: GraphCenter[[image]]

Weighted graphs:

Wolfram Language code: GraphCenter[[image]]

Multigraphs:

Wolfram Language code: GraphCenter[[image]]

Mixed graphs:

Wolfram Language code: GraphCenter[[image]]

Use rules to specify the graph:

Wolfram Language code: GraphCenter[{1 -> 2, 2 -> 3, 3 -> 1, 3 -> 4, 4 -> 5, 5 -> 3}]

Works with large graphs:

Wolfram Language code: g = GridGraph[{10, 10, 10, 10}];

Wolfram Language code: Timing[GraphCenter[g]//Length]

Wolfram Language code: VertexCount[g]

Applications (1)

People at a family gathering:

Wolfram Language code:

people = {"Elisabeth", "James", "Anna", "John", "Dorothy", "Linda", "Michael", "Larry", "Carol", "Nancy", "David", "Nora", "Julia", "Ben", "Oscar", "Felicia", "Arlene", "Rudy"};

Use Subsets to create edges between all members of the family:

Wolfram Language code: UndirectedEdge@@@Subsets[{"John", "Dorothy", "David"}, {2}]

Wolfram Language code:

relations = Join@@Table[UndirectedEdge@@@Subsets[family, {2}], {family, {{"Elisabeth", "Anna"}, {"James", "Anna", "Linda", "Larry", "Nancy"}, {"John", "Dorothy", "David"}, {"Linda", "Michael", "Nora", "Julia"}, {"Larry", "Carol", "Ben", "Oscar"}, {"Nancy", "David", "Arlene"}, {"Oscar", "Felicia"}, {"Arlene", "Rudy"}}}];

The resulting social graph:

Wolfram Language code: g = Graph[people, relations, VertexShapeFunction -> "Name"]

Find the people who are most closely related to everybody at the gathering:

Wolfram Language code: GraphCenter[g]

Properties & Relations (7)

In a connected graph, the center can be found using VertexEccentricity:

Wolfram Language code: g = GridGraph[{3, 4}]

Wolfram Language code: VertexEccentricity[g, #]& /@ VertexList[g]

Wolfram Language code: Flatten[Position[%, Min[%]]]

Wolfram Language code: GraphCenter[g]

For a CompleteGraph, every vertex is at the center:

Wolfram Language code: HighlightGraph[#, GraphCenter[#]]& /@ Table[CompleteGraph[n, VertexSize -> Small], {n, 3, 6}]

For a PathGraph with positive weights, there is either one center vertex or two center vertices:

Wolfram Language code: HighlightGraph[#, GraphCenter[#]]& /@ Table[PathGraph[Range[n], VertexSize -> Large], {n, 5, 8}]

For a CycleGraph, all vertices are in the center:

Wolfram Language code: HighlightGraph[#, GraphCenter[#]]& /@ Table[CycleGraph[n, VertexSize -> Small], {n, 3, 6}]

For a WheelGraph of size 5 or more, the hub is the graph center:

Wolfram Language code: HighlightGraph[#, GraphCenter[#]]& /@ Table[WheelGraph[n, VertexSize -> Small], {n, 5, 8}]

For a GridGraph, the center forms a grid with all dimensions being one or two:

Wolfram Language code:

HighlightGraph[#, GraphCenter[#]]& /@ Table[GridGraph[dim, VertexSize -> Medium, ImageSize -> {Tiny, Tiny}], {dim, {{3, 3}, {3, 4}, {4, 3}, {4, 4}}}]

For a CompleteKaryTree, the root vertex is the center:

Wolfram Language code: HighlightGraph[#, GraphCenter[#]]& /@ Table[CompleteKaryTree[n, VertexSize -> Large], {n, 3, 5}]

Top