GraphValuePlot
GraphValuePlot[g,{val1,val2,…}]
generates a plot of the graph g in which vertices vi are styled according to the values vali.
GraphValuePlot[g,{val1,val2,…}enc]
uses the visual encoding enc to represent the values vali in the plot.
GraphValuePlot[g,{w1{val1enc1,…},…}]
uses the visual encoding encij to represent the values valij for vertices and edges wi in the plot.
Details and Options
- GraphValuePlot uses visual encodings such as size, colors and shapes to represent values for vertices and edges.
- GraphValuePlot is typically used to enhance data visualization in graphs by using distinct visual representations for vertices and edges.
- GraphValuePlot[g,{val1,val2,…}] generates a plot of g in which the vertices vi are styled according to the values vali.
- The values vali can be quantitative or categorical.
- GraphValuePlot[g,enc{val1,val2,…}] uses the visual encoding enc to represent the values vali for all vertices or all edges of the graph g.
- For quantitative values vali, possible settings for the encoding enci for vertices can be:
-
"VertexColor" 
"VertexOpacity" 
"VertexSize" 
"DiscreteVertexColor" - For categorical values, possible settings for the encoding enci for vertices can be:
-
"VertexShape" 
"VertexLabel" 
"VertexFilling" - For quantitative values, possible settings for the encoding enci for edges can be:
-
"EdgeColor" 
"EdgeThickness" 
"EdgeOpacity" 
"DiscreteEdgeColor" - For categorical values, possible settings for the encoding enci for edges can be:
-
"EdgeShape" - GraphValuePlot[g,{w1{val11enc11,…},w2{val21enc21,…},…}] generates a plot of the graph g in which vertices and edges wi are styled according the values valij using the visual encoding encij.
-
v a vertex e an edge {v1,v2,…} a list of vertices {e1,e2,…} a list of edges patt a pattern All all vertices or edges - GraphValuePlot[g,"ann"] uses the annotation "ann" of the graph g to style vertices and edges.
- Standard vertex and edge annotations "ann" include:
-
"EdgeCapacity" edge capacity "EdgeCost" edge cost "EdgeWeight" edge weight "VertexCapacity" vertex capacity "VertexWeight" vertex weight - Annotations "ann" associated to all vertices or all edges can be used, and the corresponding values are effectively AnnotationValue[g,"ann"].
- GraphValuePlot[g,"ms"] uses the measure "ms" of the graph g to style vertices and edges.
- The following centrality measures can be used:
-
"AuthorityCentrality" authority centrality "BetweennessCentrality" visualize betweenness centrality "DegreeCentrality" visualize degree centrality using vertex size and color "EigenvectorCentrality" egenvector centrality "HubCentrality" hub centrality "PageRankCentrality" page rank centrality
Examples
open all close allBasic Examples (3)
Style vertices of a complete graph according to a list of values:
GraphValuePlot[CompleteGraph[8], {1, 2, 3, 4, 5, 6, 7, 8}]Use vertex size to style a graph:
GraphValuePlot[CompleteGraph[8], {1, 2, 3, 4, 5, 6, 7, 8} -> "VertexSize"]Highlight the most influential Florentine families:
g = ResourceObject[Association["Name" -> "Florentine Families Network",
"UUID" -> "3ea30ebd-fcac-4105-b886-b6ddd63dcbd3", "ResourceType" -> "DataResource",
"Version" -> "1.0.0", "Description" -> "Florentine families network in the early 15th cent ... ,
"ContentElements" -> {"ByteCount", "Description", "EdgeCount", "EdgeProperty", "FullGraph",
"Graph", "LongDescription", "Name", "Source", "StandardName", "Summary", "VertexCount",
"VertexProperty"}], ResourceSystemBase -> Automatic];GraphValuePlot[ResourceData[g], "DegreeCentrality"]Scope (18)
Basic Uses (5)
Style vertices of a graph according to a list of values:
g = GridGraph[{5, 5}];GraphValuePlot[g, Range[25]]Use vertex size to represent the values associated with the vertices:
g = GridGraph[{5, 5}];GraphValuePlot[g, {ClosenessCentrality[g] -> "VertexSize"}]Use vertex color to represent the values associated with the vertices:
g = GridGraph[{5, 5}];GraphValuePlot[g, {ClosenessCentrality[g] -> "VertexColor"}, VertexSize -> .4]Use edge thickness to represent the values associated with the edges:
g = GridGraph[{5, 5}];GraphValuePlot[g, {EdgeBetweennessCentrality[g] -> "EdgeThickness"}]g = GridGraph[{5, 5}];GraphValuePlot[g, {EdgeBetweennessCentrality[g] -> "EdgeThickness", EdgeBetweennessCentrality[g] -> "EdgeColor"}]Visual Encodings (7)
Use vertex color to represent the values associated with the vertices:
g = ResourceData["Dolphin Social Network"];GraphValuePlot[g, {VertexDegree[g] -> "VertexColor"}, VertexSize -> 1]g = ResourceData["Dolphin Social Network"];GraphValuePlot[g, {VertexDegree[g] -> "DiscreteVertexColor"}, VertexSize -> 1]g = ResourceData["Dolphin Social Network"];GraphValuePlot[g, {VertexDegree[g] -> "VertexOpacity"}, VertexSize -> 1]g = ResourceData["Dolphin Social Network"];GraphValuePlot[g, {PageRankCentrality[g] -> "VertexColor", PageRankCentrality[g] -> "VertexSize"}]Use edge color to represent the values associated with the edges:
g = ResourceData["Dolphin Social Network"];GraphValuePlot[g, {EdgeBetweennessCentrality[g] -> "EdgeColor"}]g = ResourceData["Dolphin Social Network"];GraphValuePlot[g, {EdgeBetweennessCentrality[g] -> "EdgeOpacity"}]g = ResourceData["Dolphin Social Network"];GraphValuePlot[g, {EdgeBetweennessCentrality[g] -> "EdgeThickness", EdgeBetweennessCentrality[g] -> "EdgeColor"}]Graph Annotations (1)
Graph Measures (5)
Use page-rank centralities to style vertices and edges:
g = ResourceData["Zachary's Karate Club Network"];GraphValuePlot[g, "PageRankCentrality"]g = PathGraph[Range[20], VertexSize -> Large];GraphValuePlot[g, "AuthorityCentrality"]g = PathGraph[Range[20], VertexSize -> Large];GraphValuePlot[g, "HubCentrality"]g = ExampleData[{"NetworkGraph", "Friendship"}];GraphValuePlot[g, "EigenvectorCentrality"]Edge betweenness centralities:
g = ExampleData[{"NetworkGraph", "Friendship"}];GraphValuePlot[g, "EdgeBetweennessCentrality"]Options (13)
ColorFunction (3)
Use vertex color to represent the values associated with the vertices:
g = GridGraph[{5, 5}, VertexSize -> .4];GraphValuePlot[g, {ClosenessCentrality[g] -> "VertexColor"}]g = GridGraph[{5, 5}, VertexSize -> .4];GraphValuePlot[g, {ClosenessCentrality[g] -> "VertexColor"}, ColorFunction -> "DeepSeaColors"]Use an association to specify the color functions for each encoding:
g = GridGraph[{5, 5}, VertexSize -> .4];GraphValuePlot[g, {ClosenessCentrality[g] -> "VertexColor", RandomReal[{0, 1}, EdgeCount[g]] -> "EdgeColor"}, ColorFunction -> <|"VertexColor" -> Hue, "EdgeColor" -> "Rainbow"|>]ScalingFunctions (6)
Parameters to ColorFunction are normally scaled to be between 0 and 1:
g = GridGraph[{5, 5}, VertexSize -> .4];GraphValuePlot[g, {DegreeCentrality[g] -> "VertexColor"}, ColorFunction -> Hue]g = GridGraph[{5, 5}, VertexSize -> .4];GraphValuePlot[g, {DegreeCentrality[g] -> "VertexColor"}, ColorFunction -> Function[{x}, Hue[x / 4]], ScalingFunctions -> False]Parameters to vertex size are automatically scaled:
g = GridGraph[{5, 5}];GraphValuePlot[g, {DegreeCentrality[g] -> "VertexSize"}]Set the upper bound of vertex scaling:
g = GridGraph[{5, 5}];GraphValuePlot[g, {DegreeCentrality[g] -> "VertexSize"}, ScalingFunctions -> .8]Set the upper bound and the lower bound of vertex scaling:
g = GridGraph[{5, 5}];GraphValuePlot[g, {DegreeCentrality[g] -> "VertexSize"}, ScalingFunctions -> {.5, .8}]Use an association to specify the function scalings for each encoding:
g = GridGraph[{5, 5}];GraphValuePlot[g, {DegreeCentrality[g] -> "VertexColor", DegreeCentrality[g] -> "VertexSize"}, ColorFunction -> <|"VertexColor" -> Function[{x}, Hue[x / 4]]|>, ScalingFunctions -> <|"VertexColor" -> False, "VertexSize" -> .6|>]PlotStyle (4)
Discrete vertex color and related encodings will automatically style multiple values:
g = GridGraph[{5, 5}, VertexSize -> .4];GraphValuePlot[g, {DegreeCentrality[g] -> "DiscreteVertexColor"}]Explicitly style different values:
g = GridGraph[{5, 5}, VertexSize -> .4];GraphValuePlot[g, {DegreeCentrality[g] -> "DiscreteVertexColor"}, PlotStyle -> {Red, Blue, Green}]Use the "Indexed" color scheme from ColorData:
g = GridGraph[{5, 5}, VertexSize -> .4];GraphValuePlot[g, {DegreeCentrality[g] -> "DiscreteVertexColor"}, PlotStyle -> 24]Use an association to specify the plot styles for each encoding:
g = GridGraph[{5, 5}, VertexSize -> .4];GraphValuePlot[g, {DegreeCentrality[g] -> "DiscreteVertexColor", RandomInteger[{1, 10}, EdgeCount[g]] -> "DiscreteEdgeColor", 1 -> "EdgeThickness"}, PlotStyle -> <|"DiscreteVertexColor" -> 24, "DiscreteEdgeColor" -> 15|>]Applications (4)
Basic Applications (2)
Represent values associated to vertices in a plot of a path graph using vertex colors:
GraphValuePlot[[image], Range[15] -> "VertexColor"]Vertex sizes increase on the values:
GraphValuePlot[[image], Range[15] -> "VertexSize"]GraphValuePlot[[image], Range[15] -> "VertexOpacity"]GraphValuePlot[[image], RandomInteger[4, 15] -> "DiscreteVertexColor"]Represent values associated to edges in a plot of a path graph using edge colors:
GraphValuePlot[[image], Range[14] -> "EdgeColor"]GraphValuePlot[[image], Range[14] -> "EdgeThickness"]GraphValuePlot[[image], Range[14] -> "EdgeOpacity"]GraphValuePlot[[image], RandomInteger[4, 14] -> "DiscreteEdgeColor"]Graph Visualization (1)
Social Networks (1)
The Florentine Families network represents marriage alliances among prominent families in Renaissance Florence:
g = ResourceData["Florentine Families Network"];Degree centrality highlights the most connected families in the Florentine social network:
GraphValuePlot[g, "DegreeCentrality"]Betweenness centrality reveals which families acted as important intermediaries between others:
GraphValuePlot[g, "BetweennessCentrality"]Closeness centrality illustrates families that were, on average, socially closer to all others in the network:
GraphValuePlot[g, "ClosenessCentrality"]Eigenvector centrality emphasizes families connected to other well-connected families, identifying influential hubs:
GraphValuePlot[g, "EigenvectorCentrality"]PageRankCentrality ranks families by their overall importance in the network based on recursive influence:
GraphValuePlot[g, "PageRankCentrality"]Text
Wolfram Research (2026), GraphValuePlot, Wolfram Language function, https://reference.wolfram.com/language/ref/GraphValuePlot.html.
CMS
Wolfram Language. 2026. "GraphValuePlot." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/GraphValuePlot.html.
APA
Wolfram Language. (2026). GraphValuePlot. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GraphValuePlot.html