GroupSetwiseStabilizer
GroupSetwiseStabilizer[group,{p1,…,pn}]
returns the subgroup of group for which the images of the points pi are still in the list {p1,…,pn}.
GroupSetwiseStabilizer[group,{p1,…,pn},f]
returns the setwise stabilizer subgroup under the action given by the function f.
Details
- Group elements in the setwise stabilizer do not necessarily fix the points pi.
- The pointwise stabilizer of a list of points, computed with GroupStabilizer, is a subgroup of the setwise stabilizer of the same list of points.
- The output is a subgroup of group defined by generators, but possibly using different generators.
- Evaluation of f[p,g] for an action function f, a point p and a permutation g of the given group, is assumed to return another point p'.
- For permutation groups, the default group action is taken to be PermutationReplace.
Examples
open all close allBasic Examples (1)
Setwise stabilizer of four points:
GroupSetwiseStabilizer[PermutationGroup[{Cycles[{{1, 7, 2}, {3, 10, 5, 4}, {6, 8, 9}}],
Cycles[{{1, 4, 2, 5, 3}}]}], {3, 7, 1, 9}]Take an element of the stabilizer:
First@GroupElements[%, {100}]It moves the points of the list among them:
PermutationReplace[{3, 7, 1, 9}, %]Scope (3)
Compute the setwise stabilizer of a permutation group defined by generators:
GroupSetwiseStabilizer[PermutationGroup[{Cycles[{{1, 2}, {3, 4}}], Cycles[{{1, 4}}]}], {1, 3}]Possible results of the action of the elements of the setwise stabilizer:
GroupOrbits[%, {{1, 3}}]Compute the setwise stabilizer of a named permutation group:
GroupSetwiseStabilizer[AlternatingGroup[8], {1, 2, 3}]Possible results of the action of the elements of the setwise stabilizer:
GroupOrbits[%, {{1, 2, 3}}]Subgroup of permutations that leave invariant a set of lists of objects under Permute action:
setwisestab = GroupSetwiseStabilizer[SymmetricGroup[5], {{a, a, b, a, b}, {b, b, a, a, a}}, Permute]Check that such a set does indeed form a single orbit under Permute action:
GroupOrbits[setwisestab, {{a, a, b, a, b}, {b, b, a, a, a}}, Permute]Properties & Relations (2)
GroupOrder[group = PermutationGroup[{Cycles[{{1, 7, 2}, {3, 10, 5, 4}, {6, 8, 9}}],
Cycles[{{1, 4, 2, 5, 3}}]}]]And the list of points to stabilize:
list = {3, 7, 1, 9};Compute the setwise stabilizer:
setstab = GroupSetwiseStabilizer[group, list]GroupOrder[setstab]stab = GroupStabilizer[group, list]GroupOrder[stab]Check that the pointwise stabilizer is a subgroup of the setwise stabilizer:
GroupElementQ[setstab, #]& /@ GroupGenerators[stab]Compare the possible reorderings of the list in both cases. The six reorderings correspond to the six cosets of the stabilizer in the setwise stabilizer:
GroupOrbits[setstab, {list}]GroupOrbits[stab, {list}]Subgroup of permutations that leave invariant a set of lists of objects under Permute action:
setwisestab = GroupSetwiseStabilizer[SymmetricGroup[5], {{a, a, b, a, b}, {b, b, a, a, a}}, Permute]Check that such a set does indeed form a single orbit under Permute action:
GroupOrbits[setwisestab, {{a, a, b, a, b}, {b, b, a, a, a}}, Permute]Compare with the result of GroupStabilizer, giving a smaller subgroup:
stab = GroupStabilizer[SymmetricGroup[5], {{a, a, b, a, b}, {b, b, a, a, a}}, Permute]Now each list of objects forms its own orbit:
GroupOrbits[stab, {{a, a, b, a, b}, {b, b, a, a, a}}, Permute]Text
Wolfram Research (2010), GroupSetwiseStabilizer, Wolfram Language function, https://reference.wolfram.com/language/ref/GroupSetwiseStabilizer.html (updated 2012).
CMS
Wolfram Language. 2010. "GroupSetwiseStabilizer." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2012. https://reference.wolfram.com/language/ref/GroupSetwiseStabilizer.html.
APA
Wolfram Language. (2010). GroupSetwiseStabilizer. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GroupSetwiseStabilizer.html