WOLFRAM

Wolfram Language & System Documentation Center

Hold[expr]

maintains expr in an unevaluated form.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
Related Workflows
Related Links
History
Cite this Page

Hold

Hold[expr]

maintains expr in an unevaluated form.

Details

  • Hold allows you to use an expression that has not undergone normal evaluation.
  • Hold has attribute HoldAll and performs no operation on its arguments.
  • Hold is removed by ReleaseHold. »
  • Hold[e1,e2,…] maintains a sequence of unevaluated expressions to which a function can be applied using Apply.
  • Hold can be inserted as a wrapper by such functions as ToExpression and Extract. »
  • Even though expr itself is not evaluated, Hold[expr] may still evaluate if expr is of the form f[args], and upvalues for f have been defined. »

Examples

open all close all

Basic Examples  (1)

Hold an expression to prevent evaluation:

Wolfram Language code: Hold[2 + 2]

Release the hold:

Wolfram Language code: ReleaseHold[%]

Scope  (1)

Extract a part without allowing it to evaluate:

Wolfram Language code: Extract[Hold[{1, 1 + 1, π}], {1, 2}, Hold]

Applications  (2)

Find the length of each expression in a held list without evaluation:

Wolfram Language code: list = Hold[1 + 2, 2 3 4 5, 1 / 0, Quit[]];
Wolfram Language code: Apply[List, Map[Hold, list]]
Wolfram Language code: % /. Hold[e_] :> Length[Unevaluated[e]]

Evaluate every sum (only) inside a held expression:

Wolfram Language code: expr = Hold[{1 + 2, g[3 + 4, 2 3], f[1 + g[2 + 3]]}]
Wolfram Language code: pos = Position[expr, _Plus]
Wolfram Language code: val = Extract[expr, pos]
Wolfram Language code: ReplacePart[expr, Thread[pos -> val]]

Properties & Relations  (10)

Hold is a container with the attribute HoldAll:

Wolfram Language code: Attributes[Hold]
Wolfram Language code: Hold[1 + 2]

Use Evaluate to force evaluation of an argument of Hold:

Wolfram Language code: Hold[Evaluate[1 + 1], 2 + 2]

Unevaluated inside a held expression is not removed:

Wolfram Language code: Hold[Unevaluated[1 + 1]]

Sequence splicing still happens inside Hold:

Wolfram Language code: Hold[Sequence[1 + 1, 2 + 2]]

Use the container HoldComplete to suppress even such transformations:

Wolfram Language code: HoldComplete[Sequence[1 + 1, 2 + 2]]

Upvalues work inside Hold:

Wolfram Language code: h/:Hold[h[x_]] := f[x]
Wolfram Language code: Hold[h[1 + 2]]

They do not work inside HoldComplete:

Wolfram Language code: h/:HoldComplete[h[x_]] := f[x]
Wolfram Language code: HoldComplete[h[1 + 2]]

Substitution works inside Hold:

Wolfram Language code: Hold[f[1 + 2]] /. f[x_] :> g[x]

Insert into a held expression:

Wolfram Language code: Insert[Hold[x + x], y, {1, 2}]

ReleaseHold removes one level of Hold:

Wolfram Language code: ReleaseHold[Hold[1 + 2]]

HoldForm is like Hold but is normally not shown in the output:

Wolfram Language code: HoldForm[1 + 2]
Wolfram Language code: FullForm[%]

Hold can be used to freeze the result of ToExpression before it is evaluated:

Wolfram Language code: ToExpression["1+1", InputForm, Hold]
Wolfram Research (1988), Hold, Wolfram Language function, https://reference.wolfram.com/language/ref/Hold.html.

Text

Wolfram Research (1988), Hold, Wolfram Language function, https://reference.wolfram.com/language/ref/Hold.html.

CMS

Wolfram Language. 1988. "Hold." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Hold.html.

APA

Wolfram Language. (1988). Hold. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Hold.html

BibTeX

@misc{reference.wolfram_2026_hold, author="Wolfram Research", title="{Hold}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/Hold.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_hold, organization={Wolfram Research}, title={Hold}, year={1988}, url={https://reference.wolfram.com/language/ref/Hold.html}, note=[Accessed: 12-June-2026]}