WOLFRAM

Wolfram Language & System Documentation Center

KnotData[knot,"property"]

gives the specified property for a knot.

KnotData[knot]

gives an image of the knot.

KnotData["class"]

gives a list of knots in the specified class.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Names and Classes  
Properties  
Property Values  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
Related Links
History
Cite this Page

KnotData

KnotData[knot,"property"]

gives the specified property for a knot.

KnotData[knot]

gives an image of the knot.

KnotData["class"]

gives a list of knots in the specified class.

Details

  • Prime knots with crossing numbers up to 10 can be specified in Alexander–Briggs notation {n,k} .
  • Knots can also be specified in Dowker notation {i1,i2,i3,…}, and in Conway notation "nnnn".
  • Special knot specifications include:
  • {"PretzelKnot",{n1,n2,…}}(n1, n2, …)-pretzel knot
    {"TorusKnot",{m,n}}(m, n)-torus knot (m, n coprime)
  • Knots with standard names can be specified by their names, such as "Trefoil" and "FigureEight".
  • KnotData[] gives a list of classical named knots.
  • KnotData[All] gives a list of knots that have Alexander–Briggs notations.
  • KnotData["Properties"] gives a list of possible properties for knots.
  • Graphical representations for knots include:
  • "Image"3D image of the knot
    "ImageData"graphics data for the 3D knot image
    "KnotDiagram"2D diagram of the knot
    "KnotDiagramData"graphics data for the 2D knot diagram
  • Region-related representations include:
  • "BoundaryMeshRegion"boundary mesh representation
    "MeshRegion"mesh representation
    "Region"geometric region
  • Invariants for knots include:
  • "ArfInvariant"Arf invariant
    "BraidIndex"braid index
    "BridgeIndex"bridge index
    "ColoringNumberSet"list of colorable numbers
    "ConcordanceOrder"concordance order
    "CrossingNumber"crossing number
    "DegreeThreeVassiliev"degree-3 Vassiliev invariant
    "DegreeTwoVassiliev"degree-2 Vassiliev invariant
    "Determinant"determinant
    "Genus"genus of knot complement
    "HyperbolicVolume"hyperbolic volume
    "NakanishiIndex"Nakanishi index
    "OzsvathSzaboTau"Ozsvath–Szabo tau invariant
    "Signature"signature
    "SmoothFourGenus"smooth 4-genus
    "StickNumber"stick number
    "SuperbridgeIndex"superbridge index
    "ThurstonBennequin"Thurston–Bennequin number
    "TopologicalFourGenus"topological 4-genus
    "UnknottingNumber"unknotting number
  • Polynomial invariants given as pure functions include:
  • "AlexanderPolynomial"Alexander polynomial
    "BLMHoPolynomial"BLMHo polynomial
    "BracketPolynomial"normalized bracket polynomial
    "ConwayPolynomial"Conway polynomial
    "HOMFLYPolynomial"HOMFLY polynomial
    "JonesPolynomial"Jones polynomial
    "KauffmanPolynomial"Kauffman polynomial
  • Other properties include:
  • "SeifertMatrix"Seifert matrix
    "SpaceCurve"space curve function for a knot embedding
  • Graphical representations for knots as braids include:
  • "BraidDiagram"2D diagram of the knot as a braid
    "BraidDiagramData"graphics data for the 2D braid diagram
    "BraidImage"3D image of the knot as a braid
    "BraidImageData"graphics data for the 3D braid image
  • Notations for knots include:
  • "AlexanderBriggsList"Alexander–Briggs {n,k} list
    "AlexanderBriggsNotation"Alexander–Briggs notation for display
    "BraidWord"braid word as a list
    "BraidWordNotation"braid word in algebraic notation
    "ConwayNotation"Conway notation for display
    "ConwayString"Conway notation as a string
    "DowkerList"Dowker {i1,i2,i3,…} list
    "DowkerNotation"Dowker notation for display
  • Naming-related properties include:
  • "AlternateNames"alternate English names
    "Name"English or mathematical name
    "StandardName"standard Wolfram Language name
  • KnotData[knot,"Classes"] gives a list of the classes in which knot occurs.
  • KnotData["class"] gives a list of knots in the specified class.
  • KnotData[knot,"class"] gives True or False depending on whether knot is in the specified class.
  • Basic classes of knots include:
  • "AlmostAlternating"almost alternating
    "Alternating"alternating
    "Amphichiral"amphichiral
    "Chiral"chiral
    "Hyperbolic"hyperbolic
    "Invertible"invertible
    "Nonalternating"non-alternating
    "Prime"prime
    "Ribbon"ribbon
    "Satellite"satellite
    "Slice"slice
    "Torus"torus
    "Twist"twist
  • Negative classes of knots include:
  • "Composite"not prime
    "NonalmostAlternating"not almost alternating
    "Nonhyperbolic"not hyperbolic
    "Noninvertible"not invertible
    "Nonribbon"not ribbon
    "Nonsatellite"not satellite
    "Nonslice"not slice
    "Nontorus"not torus
    "Nontwist"not twist
  • KnotData[name,"Information"] gives a hyperlink to more information about the knot with the specified name.
  • Using KnotData may require internet connectivity.

Examples

open all close all

Basic Examples  (2)

The trefoil knot:

Wolfram Language code: KnotData["Trefoil"]

The Alexander polynomial of the trefoil knot:

Wolfram Language code: KnotData["Trefoil", "AlexanderPolynomial"][x]

Scope  (26)

Names and Classes  (10)

Obtain a list of classical named knots:

Wolfram Language code: KnotData[]

Obtain a list of knots that have Alexander–Briggs notations:

Wolfram Language code: KnotData[All]//Short
Wolfram Language code: Length[%]

A knot can be specified by its standard Wolfram Language name:

Wolfram Language code: KnotData["FigureEight"]

Knots can also be specified in Alexander–Briggs notation:

Wolfram Language code: KnotData[{4, 1}, "ArfInvariant"]

Conway notation:

Wolfram Language code: KnotData["22", "ArfInvariant"]

Dowker notation:

Wolfram Language code: KnotData[{4, 6, 8, 2}, "ArfInvariant"]

A torus knot is specified by a pair of coprime integers:

Wolfram Language code: KnotData[{"TorusKnot", {3, 5}}]

A pretzel knot is specified by the number of crossings of its tangles:

Wolfram Language code: KnotData[{"PretzelKnot", {5, 3, 2}}]

Find the English name of a knot:

Wolfram Language code: KnotData[{3, 1}, "Name"]

A list of alternate names can also be found:

Wolfram Language code: KnotData[{3, 1}, "AlternateNames"]

Find the list of knot classes:

Wolfram Language code: KnotData["Classes"]

Find the list of knots belonging to a class:

Wolfram Language code: KnotData["Torus"]
Wolfram Language code: KnotData["Noninvertible"]

Test whether an element belongs to a class:

Wolfram Language code: KnotData[{3, 1}, "Torus"]

Get a list of classes in which a knot belongs:

Wolfram Language code: KnotData[{3, 1}, "Classes"]

A list of knots which are noninvertible and alternating:

Wolfram Language code: KnotData[{"Noninvertible", "Alternating"}]

Properties  (7)

Get a list of possible properties:

Wolfram Language code: KnotData["Properties"]
Wolfram Language code: Length[%]

Get a list of available properties for a particular knot:

Wolfram Language code: KnotData[{4, 1}, "Properties"] //Short

Image of a knot:

Wolfram Language code: KnotData[{5, 2}, "Image"]

Diagram of a knot:

Wolfram Language code: KnotData[{"TorusKnot", {11, 21}}, "KnotDiagram"]

Get more information about a knot:

Wolfram Language code: KnotData[{3, 1}, "Information"]

Get different notational forms:

Wolfram Language code: KnotData[{8, 18}, "AlexanderBriggsNotation"]
Wolfram Language code: KnotData[{8, 18}, "ConwayNotation"]
Wolfram Language code: KnotData[{8, 18}, "DowkerNotation"]

Get different notational forms, useful for input:

Wolfram Language code: KnotData[{8, 18}, "AlexanderBriggsList"]
Wolfram Language code: KnotData[{8, 18}, "ConwayString"]
Wolfram Language code: KnotData[{8, 18}, "DowkerList"]

Property Values  (9)

A property value can be any valid Wolfram Language expression:

Wolfram Language code: KnotData[{7, 1}, "ArfInvariant"]
Wolfram Language code: KnotData[{10, 122}, "ColoringNumberSet"]
Wolfram Language code: KnotData[{3, 1}, "AlexanderBriggsNotation"]

Polynomial invariants are given as pure functions:

Wolfram Language code: p = KnotData["FigureEight", "HOMFLYPolynomial"]
Wolfram Language code: p[x, y]

A space curve for a knot is given as Function or InterpolatingFunction:

Wolfram Language code: f = KnotData[{3, 1}, "SpaceCurve"]
Wolfram Language code: ParametricPlot3D[f[t], {t, 0, 2Pi}, Axes -> False]
Wolfram Language code: g = KnotData[{7, 2}, "SpaceCurve"]
Wolfram Language code: ParametricPlot3D[g[t], {t, 0, 2Pi}, Axes -> False]

3D images of knots are Graphics3D objects:

Wolfram Language code: KnotData[{7, 1}, "Image"]//Head

Get the 3D primitives for the "Image":

Wolfram Language code: KnotData[{7, 1}, "ImageData"]//Short

2D diagrams of knots are Graphics objects:

Wolfram Language code: KnotData[{7, 1}, "KnotDiagram"]//Head

Get the 2D primitives for the "KnotDiagram":

Wolfram Language code: KnotData[{7, 1}, "KnotDiagramData"]//Short

A property that is not applicable to a knot has the value Missing["NotApplicable"]:

Wolfram Language code: KnotData[{"TorusKnot", {3, 2}}, "HyperbolicVolume"]

A property that is not available for a knot has the value Missing["NotAvailable"]:

Wolfram Language code: KnotData[{"PretzelKnot", {2, 3, 5}}, "OzsvathSzaboTau"]

A property that is unknown for a knot has the value Missing["Unknown"]:

Wolfram Language code: KnotData[{8, 13}, "ConcordanceOrder"]

Specify a list of properties for a knot:

Wolfram Language code: KnotData[{5, 2}, {"AlexanderBriggsNotation", "ConwayNotation", "Prime"}]

Generalizations & Extensions  (4)

Braid index of a knot:

Wolfram Language code: KnotData[{4, 1}, "BraidIndex"]

Braid word as a list:

Wolfram Language code: KnotData[{4, 1}, "BraidWord"]

Braid word notation:

Wolfram Language code: KnotData[{4, 1}, "BraidWordNotation"]

Braid image:

Wolfram Language code: KnotData[{4, 1}, "BraidImage"]

Applications  (5)

The 20 amphichiral knots having 10 or fewer crossings:

Wolfram Language code: KnotData["Amphichiral"]

Number of prime knots per crossing numbers:

Wolfram Language code: a = KnotData[#, {"CrossingNumber", "Prime"}]& /@ KnotData[All];
Wolfram Language code: Count[a, {#, True}]& /@ Range[10]

The trefoil is a tricolorable knot:

Wolfram Language code: KnotData["Trefoil", "ColoringNumberSet"]

Tricolorable trefoil:

Wolfram Language code: Graphics[Transpose[{{Red, Blue, Green, Red}, KnotData["Trefoil", "KnotDiagramData"]}]]

The two-bridge knots are exactly the rational knots:

Wolfram Language code: knots = Select[KnotData[All], KnotData[#, "BridgeIndex"] == 2&]

Number of rational knots per crossing numbers:

Wolfram Language code: Function[x, Count[%, _ ? (KnotData[#, "CrossingNumber"] == x&)]] /@ Range[10]
Wolfram Language code: ListPlot[%, Filling -> Axis]

A stick knot:

Wolfram Language code: points = Table[KnotData[{5, 2}, "SpaceCurve"][t], {t, 0, 2Pi, 0.5}];
Wolfram Language code: Graphics3D[{Red, Cylinder[#, 0.2]& /@ Transpose[{points, Append[Rest[points], First[points]]}]}, Boxed -> False, ViewPoint -> {0, -0.5, 5}]

Properties & Relations  (13)

Graphics data of knots can be used in Graphics and Graphics3D:

Wolfram Language code: data1 = KnotData[{6, 2}, "ImageData"];
Wolfram Language code: data2 = KnotData[{6, 2}, "BraidDiagramData"];

A 3D image:

Wolfram Language code: Graphics3D[{Green, data1}]

A braid image:

Wolfram Language code: Graphics[Transpose[{{Red, Green, Blue}, data2}]]

Alexander polynomials are symmetric:

Wolfram Language code: (KnotData[#, "AlexanderPolynomial"][t] == KnotData[#, "AlexanderPolynomial"][1 / t])& /@ Take[KnotData[All], 10]

Alexander polynomials of oriented knots take values 1 or -1 at 1:

Wolfram Language code: KnotData[#, "AlexanderPolynomial"][1]& /@ Take[KnotData[All], 10]

Alexander polynomials can be expressed in terms of the Seifert matrix:

Wolfram Language code: Det[t # - Transpose[#]]&@KnotData[{3, 1}, "SeifertMatrix"]
Wolfram Language code: t KnotData[{3, 1}, "AlexanderPolynomial"][t]//Apart

Conway polynomials are modified versions of Alexander polynomials:

Wolfram Language code: KnotData["Trefoil", "AlexanderPolynomial"][t ^ 2]
Wolfram Language code: KnotData["Trefoil", "ConwayPolynomial"][t - 1 / t]//Apart

Identities for Jones polynomials:

Wolfram Language code: KnotData[#, "JonesPolynomial"][1] == 1& /@ {"Trefoil", "FigureEight"}
Wolfram Language code: KnotData[#, "JonesPolynomial"][E ^ (2Pi I / 3)] == 1& /@ {{7, 1}, {8, 2}}
Wolfram Language code: KnotData[#, "JonesPolynomial"]'[1] == 0& /@ {{9, 14}, {10, 165}}

A torus knot has a mirror :

Wolfram Language code: {Framed[KnotData[{"TorusKnot", {4, 9}}, "KnotDiagram"]], Framed[KnotData[{"TorusKnot", {4, -9}}, "KnotDiagram"]]}

The tori knots and are equivalent:

Wolfram Language code: {Framed[KnotData[{"TorusKnot", {8, 11}}, "KnotDiagram"]], Framed[KnotData[{"TorusKnot", {-8, -11}}, "KnotDiagram"]]}

Kauffman polynomials are generalizations of Jones polynomials:

Wolfram Language code: KnotData[{5, 2}, "KauffmanPolynomial"][-t ^ (3 / 4), t ^ (-1 / 4) + t ^ (1 / 4)]//Apart
Wolfram Language code: KnotData[{5, 2}, "JonesPolynomial"][1 / t]

Kauffman polynomials extend BLMHo polynomials to two variables:

Wolfram Language code: KnotData[{5, 2}, "KauffmanPolynomial"][1, t]
Wolfram Language code: KnotData[{5, 2}, "BLMHoPolynomial"][t]

Kauffman and normalized bracket polynomials:

Wolfram Language code: KnotData[{5, 2}, "KauffmanPolynomial"][-t ^ -3, 1 / t + t]//Apart
Wolfram Language code: KnotData[{5, 2}, "BracketPolynomial"][t]

Relation between normalized bracket polynomials and Jones polynomials:

Wolfram Language code: KnotData[{5, 2}, "BracketPolynomial"][t]
Wolfram Language code: KnotData[{5, 2}, "JonesPolynomial"][t ^ 4]

The Arf invariant of a knot is related to the Alexander polynomial:

Wolfram Language code: a = Select[KnotData[All], Mod[KnotData[#, "AlexanderPolynomial"][-1], 8] == 1&];
Wolfram Language code: KnotData[#, "ArfInvariant"]& /@ Take[a, 10]
Wolfram Language code: b = Select[KnotData[All], Abs[Mod[KnotData[#, "AlexanderPolynomial"][-1], 8]] == 5&];
Wolfram Language code: KnotData[#, "ArfInvariant"]& /@ Take[b, 10]

Possible Issues  (2)

The Perko pair is represented by the unique knot :

Wolfram Language code: KnotData["PerkoPair", "AlexanderBriggsNotation"]

Exactly 165 distinct prime knots with 10 crossings are listed:

Wolfram Language code: Count[KnotData["Prime"], _ ? (KnotData[#, "CrossingNumber"] == 10&)]

Braids of an even pretzel knot are shifted to end with a braid having an even crossing number:

Wolfram Language code: KnotData[{"PretzelKnot", {5, 2, 3}}]

Neat Examples  (6)

A tabbed list of knot diagrams:

Wolfram Language code: TabView[Graphics[KnotData[#, "KnotDiagramData"], Epilog -> Inset[Style[KnotData[#, "AlexanderBriggsNotation"], Large], {Right, Bottom}, {Right, Bottom}]]& /@ Take[KnotData[All], {2, 6}]]

Random-colored torus knots:

Wolfram Language code: Graphics[Transpose[{Table[RGBColor@@RandomReal[{0, 1}, 3], {Length[#]}], #}]]&@KnotData[{"TorusKnot", {7, 30}}, "KnotDiagramData"]

A torus knot sits on a torus:

Wolfram Language code: torus = First@ParametricPlot3D[{Cos[2Pi r](4 + Cos[2Pi s]), Sin[2Pi r](4 + Cos[2Pi s]), Sin[2Pi s]} / 11, {r, 0, 1}, {s, 0, 1}, Mesh -> None, Axes -> None, Boxed -> False, ColorFunction -> Function[{x, y, z}, RGBColor[x, y, 0.]]];
Wolfram Language code: torusknot = KnotData[{"TorusKnot", {3, 11}}, "ImageData"];
Wolfram Language code: Graphics3D[{torus, torusknot}, Boxed -> False]

The knot :

Wolfram Language code: Graphics3D[{Orange, Specularity[White, 70], KnotData[{8, 3}, "ImageData"]}, Boxed -> False, ViewPoint -> {0, 0.1, 5}]

A pretzel knot rendered with spheres:

Wolfram Language code: pretzel[t_] = KnotData[{"PretzelKnot", {3, 5, 7}}, "SpaceCurve"][t];
Wolfram Language code: Graphics3D[Table[{Red, Specularity[0.9, 50], Sphere[pretzel[t], 0.3]}, {t, 0, 2Pi, 0.015}], Boxed -> False]

Color a knot:

Wolfram Language code: coloredknot[knot_, colorFunction_] := With[{a = First@KnotData[knot, "ImageData"]}, Graphics3D[GraphicsComplex[a[[1]], a[[2]], a[[3]], VertexColors -> colorFunction@@@a[[1]]], Boxed -> False]]
Wolfram Language code: coloredknot[{"TorusKnot", {3, 8}}, Hue[Sin[#1]]&]
Wolfram Research (2007), KnotData, Wolfram Language function, https://reference.wolfram.com/language/ref/KnotData.html (updated 2025).

Text

Wolfram Research (2007), KnotData, Wolfram Language function, https://reference.wolfram.com/language/ref/KnotData.html (updated 2025).

CMS

Wolfram Language. 2007. "KnotData." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/KnotData.html.

APA

Wolfram Language. (2007). KnotData. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/KnotData.html

BibTeX

@misc{reference.wolfram_2026_knotdata, author="Wolfram Research", title="{KnotData}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/KnotData.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_knotdata, organization={Wolfram Research}, title={KnotData}, year={2025}, url={https://reference.wolfram.com/language/ref/KnotData.html}, note=[Accessed: 12-June-2026]}