Wolfram Language & System Documentation Center

Length

Length[expr]

gives the number of elements in expr.

Details

For special objects like SparseArray, QuantityArray, NumericArray or Association, Length returns the length of the corresponding ordinary list. »
Otherwise, Length[expr] returns 0 whenever AtomQ[expr] is True.

Examples

open all close all

Basic Examples (2)

Find the length of a list:

Wolfram Language code: Length[{a, b, c, d}]

Find the length of an Association:

Wolfram Language code: Length[<||>]

Wolfram Language code: Length[<|1 -> 2, 3 -> 4|>]

Scope (2)

Length works with any head:

Wolfram Language code: Length[a + b + c + d]

Length[expr] gives the number of elements in the top level of expr:

Wolfram Language code: Length[f[g[x, y], z]]

Generalizations & Extensions (5)

The length of a symbol is 0:

Wolfram Language code: Length[x]

The length of a string is 0:

Wolfram Language code: Length["string"]

StringLength gives the number of characters:

Wolfram Language code: StringLength["string"]

Explicit numbers have length 0:

Wolfram Language code: Length[123456]

Wolfram Language code: Length[1 / 10]

Wolfram Language code: Length[3 + I]

Length works on SparseArray objects:

Wolfram Language code: SparseArray[{a, b, c, d, e}]

Wolfram Language code: Length[%]

Length works on structured arrays, like SymmetrizedArray objects:

Wolfram Language code: SymmetrizedArray[{{1, 2} -> a, {2, 3} -> b}, {4, 4}, Antisymmetric[{1, 2}]]

Wolfram Language code: Length[%]

Applications (5)

Find the number of rows in a matrix:

Wolfram Language code: Length[{{a, b, c}, {d, e, f}}]

Find the length of each sublist:

Wolfram Language code: Map[Length, {{a, b}, {a, b, c}, {x}}]

Find the number of terms in a polynomial:

Wolfram Language code: Length[1 + x + x ^ 2 + x ^ 9]

Find the number of digits in 1000!:

Wolfram Language code: Length[IntegerDigits[1000!]]

Get the number of points used to plot a curve:

Wolfram Language code: p = Plot[Sin[x], {x, 0, 20}]

Wolfram Language code: Total[Cases[p, x_Line :> Length[x[[1]]], Infinity]]

Properties & Relations (2)

Length gives the maximum index that can be used:

Wolfram Language code: Length[{a, b, c, d}]

Wolfram Language code: {a, b, c, d}[[4]]

For expressions with length greater than 0, Length[expr] equals First[Dimensions[expr]]:

Wolfram Language code: mat = {{1, 2, 3}, {4, 5, 6}}

Wolfram Language code: Length[mat] == First[Dimensions[mat]]

Possible Issues (5)

Length operates on the FullForm of expressions, not their displayed form:

Wolfram Language code: Sqrt[x]

Wolfram Language code: Length[%]

Wolfram Language code: FullForm[Sqrt[x]]

Rational and complex numbers are atoms, so they have length 0:

Wolfram Language code: Length[1 / 3]

Wolfram Language code: FullForm[1 / 3]

Wolfram Language code: Length[2 + I]

Wolfram Language code: FullForm[2 + I]

Numeric expressions are treated like other expressions, not like explicit numbers:

Wolfram Language code: Length[Sqrt[7]]

Wolfram Language code: Length[7]

Length counts only "arguments", not parts of heads:

Wolfram Language code: Length[h[a, b][x, y, z]]

For nonatomic e, Length[e] is equivalent to First[Dimensions[e]]:

Wolfram Language code: exprs = {1, {}, {2}, {{3, 4}, {5, 6}}, SparseArray[{{7}}, {8, 9}]};

Wolfram Language code:

TableForm[Table[{e//OutputForm, Length[e], Dimensions[e], If[Dimensions[e] === {}, 0, First[Dimensions[e]]]}, {e, exprs}], TableDepth -> 2, TableHeadings -> {{}, {"e", "Length[e]", "Dimensions[e]", "\"First\" dimension"}}]