WOLFRAM

Wolfram Language & System Documentation Center

symbol::tag

is a name for a message.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
Related Workflows
History
Cite this Page

MessageName

symbol::tag

is a name for a message.

Details

  • You can specify messages by defining values for symbol::tag.
  • symbol::tag is converted to MessageName[symbol,"tag"]. tag can contain any characters that can appear in symbol names. symbol::"tag" can also be used. »
  • Assignments for s::tag are stored in the Messages value of the symbol s. »
  • The f::usage message is typically defined for functions intended for general use, giving a description of how to use the function.
  • ?f prints out the message f::usage. »
  • When ?form finds more than one function, only the names of the functions are printed.
  • You can switch on and off messages using On[s::tag] and Off[s::tag].
  • MessageName[symbol,"tag","lang"] or symbol::tag::lang represents a message in a particular language. »

Examples

open all close all

Basic Examples  (2)

Define a usage message for a function:

Wolfram Language code: f::usage = "f[x] gives (x - 1)(x + 1)";

Show the usage message:

Wolfram Language code: ? f

Define an error message:

Wolfram Language code: g::err = "An error occurred";

Use the message:

Wolfram Language code: Message[g::err]

Scope  (1)

Define separate messages for English and Spanish:

Wolfram Language code: g::err::English = "There is a problem!"; g::err::Spanish = "¡Hay problema!";

When $Language is English, the English text is used:

Wolfram Language code: Block[{$Language = "English"}, Message[g::err]]

When $Language is set to Spanish, the Spanish text is used:

Wolfram Language code: Block[{$Language = "Spanish"}, Message[g::err]]

For any other language, no text is found:

Wolfram Language code: Block[{$Language = "French"}, Message[g::err]]

Applications  (2)

Process messages generated during an evaluation:

Wolfram Language code: {Sin[1, 2.], BesselJ[3, 4.], Log[5, 6.], Exp[7, 8.]}
Wolfram Language code: mess = MessageList[-1]
Wolfram Language code: mest = Cases[mess, HoldForm[MessageName[f_, s_]] -> {f, s}]

Define a function that will test another function and give the argx message if needed:

Wolfram Language code: oneargtest[f_, args___] := Module[{nargs = Length[{args}]}, If[nargs ≠ 1, Message[MessageName[f, "argx"], nargs, 1];False, True]]
Wolfram Language code: oneargtest[g, 1, 2]

Define g to use the test and return unevaluated when it fails:

Wolfram Language code: g[args___] := Module[{x = First[{args}]}, (x - 1)(x + 1)] /; oneargtest[g, args]
Wolfram Language code: g[1, 2]
Wolfram Language code: g[1.5]

Properties & Relations  (3)

The forms symbol::tag and SymbolName[g,"tag"] are equivalent:

Wolfram Language code: MessageName[g, "err"] === g::err

The messages assigned specifically to symbol are returned by Messages[symbol]:

Wolfram Language code: f::usage = "f[] returns the answer"; f::err = "There was an error"; Messages[f]

A message defined using the three-argument form is used when the third argument matches $Language:

Wolfram Language code: MessageName[f, "err"] = "This is bad!"; MessageName[f, "err", "Spanish"] = "¡Esto es malo!";
Wolfram Language code: Block[{$Language = "Spanish"}, Message[f::err]]

If there is no matching three-argument form defined, the text of the two-argument form is used:

Wolfram Language code: Block[{$Language = "Hebrew"}, Message[f::err]]
Wolfram Research (1988), MessageName, Wolfram Language function, https://reference.wolfram.com/language/ref/MessageName.html (updated 2002).

Text

Wolfram Research (1988), MessageName, Wolfram Language function, https://reference.wolfram.com/language/ref/MessageName.html (updated 2002).

CMS

Wolfram Language. 1988. "MessageName." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2002. https://reference.wolfram.com/language/ref/MessageName.html.

APA

Wolfram Language. (1988). MessageName. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MessageName.html

BibTeX

@misc{reference.wolfram_2026_messagename, author="Wolfram Research", title="{MessageName}", year="2002", howpublished="\url{https://reference.wolfram.com/language/ref/MessageName.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_messagename, organization={Wolfram Research}, title={MessageName}, year={2002}, url={https://reference.wolfram.com/language/ref/MessageName.html}, note=[Accessed: 12-June-2026]}