WOLFRAM

Wolfram Language & System Documentation Center

PolynomialGCD[poly1,poly2,…]

gives the greatest common divisor of the polynomials polyi.

PolynomialGCD[poly1,poly2,…,Modulusp]

evaluates the GCD modulo the prime p.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Advanced Uses  
Options  
Extension  
Modulus  
Trig  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

PolynomialGCD

PolynomialGCD[poly1,poly2,…]

gives the greatest common divisor of the polynomials polyi.

PolynomialGCD[poly1,poly2,…,Modulusp]

evaluates the GCD modulo the prime p.

Details and Options

  • In PolynomialGCD[poly1,poly2,…], all symbolic parameters are treated as variables.
  • PolynomialGCD[poly1,poly2,…] will by default treat algebraic numbers that appear in the polyi as independent variables.
  • PolynomialGCD takes the following options:
  • Extension Nonegenerators for the algebraic number field to be used
    Modulus 0modulus to assume for integers
    Trig Falsewhether to do trigonometric as well as algebraic transformations
  • PolynomialGCD[poly1,poly2,…,Extension->Automatic] extends the coefficient field to include algebraic numbers that appear in the polyi.

Examples

open all close all

Basic Examples  (3)

Compute the greatest common divisor of polynomials:

Wolfram Language code: PolynomialGCD[(1 + x) ^ 2(2 + x)(4 + x), (1 + x)(2 + x)(3 + x)]

Compute the GCD of multivariate polynomials:

Wolfram Language code: PolynomialGCD[(x + y) ^ 2(y + z), (x + y)(y + z) ^ 3]

Show that polynomials are relatively prime:

Wolfram Language code: PolynomialGCD[x ^ 2 + 4x + 4, x ^ 2 + 2x + 1]

Scope  (10)

Basic Uses  (4)

The GCD of univariate polynomials:

Wolfram Language code: PolynomialGCD[x ^ 4 - 4, x ^ 4 + 4 x ^ 2 + 4]

The GCD of multivariate polynomials:

Wolfram Language code: PolynomialGCD[x ^ 2 + 2 x y + y ^ 2, x ^ 3 + y ^ 3]

The GCD of more than two polynomials:

Wolfram Language code: PolynomialGCD[x ^ 2 - 1, x ^ 3 - 1, x ^ 4 - 1, x ^ 5 - 1, x ^ 6 - 1, x ^ 7 - 1]

The GCD of polynomials with complex coefficients:

Wolfram Language code: PolynomialGCD[x ^ 2 + 1, x ^ 3 + 3I x ^ 2 - 3x - I]

Advanced Uses  (6)

With Extension->Automatic, PolynomialGCD detects algebraically dependent coefficients:

Wolfram Language code: PolynomialGCD[x ^ 2 - 3, x - Sqrt[3], Extension -> Automatic]

Compute the GCD of polynomials over the integers modulo :

Wolfram Language code: PolynomialGCD[(x ^ 2 - 1) ^ 2, x ^ 3 - 1, Modulus -> 3]

Compute the GCD of polynomials over a finite field:

Wolfram Language code: ℱ = FiniteField[17, 3];
Wolfram Language code: PolynomialGCD[ℱ[1]x ^ 2 + ℱ[246]x + ℱ[4436], ℱ[3]x ^ 2 + ℱ[1771]]

With Trig->True, PolynomialGCD recognizes dependencies between trigonometric functions:

Wolfram Language code: PolynomialGCD[Sin[2x], 1 - Cos[x] ^ 2, Trig -> True]

The GCD of rational functions:

Wolfram Language code: PolynomialGCD[(x - 1)(x - 2) / ((x - 3)(x - 4)), (x - 1)(x - 5) / ((x - 3)(x - 6))]

Compute the GCD of two polynomials of degree :

Wolfram Language code: rpoly[n_] := RandomInteger[{-2 ^ 10, 2 ^ 10}, {n + 1}].x ^ Range[0, n] SeedRandom[1234]; p = rpoly[10000]; q = rpoly[10000]; r = rpoly[10000]; pp = Expand[p r]; qq = Expand[q r];
Wolfram Language code: (d = PolynomialGCD[pp, qq]);//AbsoluteTiming
Wolfram Language code: Exponent[d, x]

Options  (3)

Extension  (1)

By default, algebraic numbers are treated as independent variables:

Wolfram Language code: PolynomialGCD[x ^ 2 - 2, x - Sqrt[2]]

With Extension->Automatic, PolynomialGCD detects algebraically dependent coefficients:

Wolfram Language code: PolynomialGCD[x ^ 2 - 2, x - Sqrt[2], Extension -> Automatic]

Modulus  (1)

Compute the GCD over the integers modulo 2:

Wolfram Language code: PolynomialGCD[(x + 1) ^ 3, x ^ 3 + x, Modulus -> 2]

Trig  (1)

By default, PolynomialGCD treats trigonometric functions as independent variables:

Wolfram Language code: PolynomialGCD[Sin[2x], 1 - Cos[x] ^ 2]

With Trig->True, PolynomialGCD recognizes dependencies between trigonometric functions:

Wolfram Language code: PolynomialGCD[Sin[2x], 1 - Cos[x] ^ 2, Trig -> True]

Applications  (2)

Find common roots of univariate polynomials:

Wolfram Language code: f = x ^ 7 - 2x ^ 5 - x ^ 4 + 5x ^ 3 + 4x ^ 2 - 12x + 5; g = x ^ 7 - 9x ^ 5 + x ^ 4 + 17x ^ 3 - 7x ^ 2 - 6x + 3; d = PolynomialGCD[f, g]
Wolfram Language code: x /. Solve[d == 0, x]
Wolfram Language code: Intersection[x /. Solve[f == 0, x], x /. Solve[g == 0, x]]

Find multiple roots of univariate polynomials:

Wolfram Language code: f = x ^ 9 - 7x ^ 8 + 19x ^ 7 - 27x ^ 6 + 35x ^ 5 - 77x ^ 4 + 145x ^ 3 - 157x ^ 2 + 88x - 20; d = PolynomialGCD[f, D[f, x]]
Wolfram Language code: x /. Solve[d == 0, x]
Wolfram Language code: N[x /. Solve[f == 0, x]]

Properties & Relations  (3)

The GCD of polynomials divides the polynomials; use PolynomialMod to prove it:

Wolfram Language code: f = x ^ 7 - 2x ^ 5 - x ^ 4 + 5x ^ 3 + 4x ^ 2 - 12x + 5; g = x ^ 7 - 9x ^ 5 + x ^ 4 + 17x ^ 3 - 7x ^ 2 - 6x + 3; d = PolynomialGCD[f, g]
Wolfram Language code: PolynomialMod[{f, g}, d]

Cancel divides the numerator and the denominator of a rational function by their GCD:

Wolfram Language code: Cancel[f / g]

PolynomialLCM finds the least common multiple of polynomials:

Wolfram Language code: PolynomialLCM[f, g]
Wolfram Language code: % - (f g) / d //Together

Resultant of two polynomials is zero if and only if their GCD has a nonzero degree:

Wolfram Language code: Resultant[x ^ 2 - 4, x ^ 2 + 4x + 4, x]
Wolfram Language code: PolynomialGCD[x ^ 2 - 4, x ^ 2 + 4x + 4]
Wolfram Language code: Resultant[3 x + 9, 6x ^ 3 - 3x + 12, x]
Wolfram Language code: PolynomialGCD[3 x + 9, 6x ^ 3 - 3x + 12]

Discriminant of a polynomial f is zero if and only if the degree of GCD(f,f') is nonzero:

Wolfram Language code: f = x ^ 3 - 3x + 2; g = x ^ 3 - 2x + 1;
Wolfram Language code: Discriminant[f, x]
Wolfram Language code: PolynomialGCD[f, D[f, x]]
Wolfram Language code: Discriminant[g, x]
Wolfram Language code: PolynomialGCD[g, D[g, x], x]

Discriminant of a polynomial f is zero if and only if the polynomial has multiple roots:

Wolfram Language code: x /. Solve[f == 0, x]
Wolfram Language code: x /. Solve[g == 0, x]
Wolfram Research (1991), PolynomialGCD, Wolfram Language function, https://reference.wolfram.com/language/ref/PolynomialGCD.html (updated 2023).

Text

Wolfram Research (1991), PolynomialGCD, Wolfram Language function, https://reference.wolfram.com/language/ref/PolynomialGCD.html (updated 2023).

CMS

Wolfram Language. 1991. "PolynomialGCD." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/PolynomialGCD.html.

APA

Wolfram Language. (1991). PolynomialGCD. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PolynomialGCD.html

BibTeX

@misc{reference.wolfram_2026_polynomialgcd, author="Wolfram Research", title="{PolynomialGCD}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/PolynomialGCD.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_polynomialgcd, organization={Wolfram Research}, title={PolynomialGCD}, year={2023}, url={https://reference.wolfram.com/language/ref/PolynomialGCD.html}, note=[Accessed: 13-June-2026]}