WOLFRAM

Wolfram Language & System Documentation Center

PopupMenu[x,{val1,val2,…}]

represents a popup menu with setting x and possible values vali.

PopupMenu[Dynamic[x],{val1,…}]

takes the setting to be the dynamically updated current value of x, with the value of x being reset every time an item is selected from the menu.

PopupMenu[x,{val1lbl1,val2lbl2,…}]

represents a popup menu in which possible value vali is indicated by lbli.

PopupMenu[x,{val1lbl1,…},dlbl]

displays the menu item as dlbl if x is none of the vali.

PopupMenu[x,{…},dlbl,base]

displays as base when it is not being clicked.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
PopupMenu Content  
PopupMenu Control  
Options  
Alignment  
BaselinePosition  
Enabled  
Show More Show More
FieldSize  
FrameMargins  
ImageMargins  
ImageSize  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

PopupMenu

PopupMenu[x,{val1,val2,…}]

represents a popup menu with setting x and possible values vali.

PopupMenu[Dynamic[x],{val1,…}]

takes the setting to be the dynamically updated current value of x, with the value of x being reset every time an item is selected from the menu.

PopupMenu[x,{val1lbl1,val2lbl2,…}]

represents a popup menu in which possible value vali is indicated by lbli.

PopupMenu[x,{val1lbl1,…},dlbl]

displays the menu item as dlbl if x is none of the vali.

PopupMenu[x,{…},dlbl,base]

displays as base when it is not being clicked.

Details and Options

  • PopupMenu[x,{val1,val2,…}] displays with the vali as successive entries in the menu.
  • The vali and lbli can be strings, boxes, graphics or any other expressions, including dynamic expressions.
  • In PopupMenu[x,list], Delimiter can appear as an element of list, specifying a horizontal delimiter in the displayed popup menu.
  • The following options can be given:
  • AppearanceAutomaticthe overall appearance of the menu
    BaselinePosition Automaticalignment relative to surrounding text
    BaseStyle{}base style specifications for the menu
    ContentPaddingTruewhether to shrink the margins tightly around the contents
    Enabled Automaticwhether the menu is enabled, or grayed out
    FieldSize {{1.,50.},{1.,10.}}the size of the field for menu items
    FrameMargins Automaticmargins to leave inside the menu frame
    ImageMargins 0margins around the displayed menu
    ImageSize Allthe overall image size of the displayed menu
    MenuStyle{}style specifications for menu items
  • The settings for BaseStyle are appended to the default style typically given by the "PopupMenu" style in the current stylesheet.

Examples

open all close all

Basic Examples  (2)

Select values from a popup menu:

Wolfram Language code: PopupMenu[a, {a, b, c, d}]

Connect PopupMenu to a dynamic state:

Wolfram Language code: {PopupMenu[Dynamic[x], {a, b, c, d}], Dynamic[x]}

Scope  (7)

PopupMenu Content  (4)

Use graphics as content in PopupMenu:

Wolfram Language code: PopupMenu[Dynamic[x], Table[Plot[Sin[n x], {x, 0, 10}], {n, 5}]]

Use any expression as a label:

Wolfram Language code: {PopupMenu[Dynamic[y], Table[Plot[Sin[x ^ n], {x, 0, 2π}] -> Sin[x ^ n], {n, 5}]], Dynamic[y]}

Use Null to indicate a blank label:

Wolfram Language code: {PopupMenu[Dynamic[x], {a -> Null, b -> "Some text"}], Dynamic[x]}

By default, a PopupMenu leaves enough space to display without ever resizing:

Wolfram Language code: d = Table[Graphics[Circle[], ImageSize -> s], {s, 20, 50, 10}]
Wolfram Language code: {PopupMenu[Graphics[Circle[], ImageSize -> 20], d], PopupMenu[Graphics[Circle[], ImageSize -> 50], d]}

With ImageSize->Automatic, PopupMenu resizes for each pane:

Wolfram Language code: {PopupMenu[Graphics[Circle[], ImageSize -> 20], d, ImageSize -> Automatic], PopupMenu[Graphics[Circle[], ImageSize -> 50], d, ImageSize -> Automatic]}

PopupMenu Control  (3)

Start with value selected:

Wolfram Language code: PopupMenu[c, {a, b, c, d}]

The setting is based on value, regardless of labels:

Wolfram Language code: {PopupMenu[Dynamic[x], {a, b, c}], Dynamic[x]}
Wolfram Language code: {PopupMenu[Dynamic[y], {a -> "one", b -> "two", c -> "three"}], Dynamic[y]}

Connect a PopupMenu to a slider:

Wolfram Language code: {PopupMenu[Dynamic[i], {a, b, c, d}], Slider[Dynamic[i], {{a, b, c, d}}]}

Options  (9)

Alignment  (1)

Specify an alignment within the menu:

Wolfram Language code: Grid[Table[PopupMenu[a, {a, b, c, d}, ImageSize -> {60, 30}, Alignment -> {w, h}], {h, {Top, Center, Bottom}}, {w, {Left, Center, Right}}]]

BaselinePosition  (1)

Align with surrounding text:

Wolfram Language code: Row[Table[PopupMenu[a, {a, b, c, d}, BaselinePosition -> p], {p, {Top, Center, Bottom}}], "xxx"]

Enabled  (1)

By default, PopupMenu is enabled:

Wolfram Language code: PopupMenu[a, {a, b, c, d}]

By setting Enabled->False, PopupMenu is disabled, but visible in its current state:

Wolfram Language code: PopupMenu[a, {a, b, c, d}, Enabled -> False]

FieldSize  (3)

Use a predefined size:

Wolfram Language code: Table[PopupMenu[a, {a, b, c, d}, FieldSize -> s], {s, {Tiny, Small, Medium, Large}}]

Specify width and height:

Wolfram Language code: Grid[Table[PopupMenu[a, {a, b, c, d}, FieldSize -> {w, h}], {h, {1, 2, 4}}, {w, {2, 4, 10}}]]

Allow a width and height between set values:

Wolfram Language code: Column[Table[PopupMenu[N[Pi, n], {N[Pi, n], 2, 3, 4}, FieldSize -> {{2, 10}, {1, 2}}], {n, {4, 15, 25, 40}}]]

FrameMargins  (1)

Add margins within the view:

Wolfram Language code: Table[PopupMenu[a, {a, b, c, d}, FrameMargins -> m], {m, {0, 10, 20}}]

ImageMargins  (1)

Add margins outside the view:

Wolfram Language code: Table[Framed[PopupMenu[a, {a, b, c, d}, ImageMargins -> m]], {m, {0, 10, 20}}]

ImageSize  (1)

Control the overall height and width:

Wolfram Language code: Grid[Table[PopupMenu[a, {a, b, c, d}, ImageSize -> {w, h}], {h, {20, 40, 60}}, {w, {40, 60, 80}}]]

Applications  (1)

Dynamically update the base view:

Wolfram Language code: PopupMenu[Dynamic[x], {1 -> "one", 2 -> "two", 3 -> "three"}, 1, Graphics[Dynamic[Table[Disk[{2i, 0}], {i, x}]], ImageSize -> {Dynamic[x]15, 15}]]

Properties & Relations  (1)

In PopupMenu, the setting is associated with the value of the element in the list:

Wolfram Language code: PopupMenu[a, {a, b, c, d}]

In PopupView, the setting is associated with the position of the element in the list:

Wolfram Language code: PopupView[{a, b, c, d}, 1]
Wolfram Research (2007), PopupMenu, Wolfram Language function, https://reference.wolfram.com/language/ref/PopupMenu.html (updated 2010).

Text

Wolfram Research (2007), PopupMenu, Wolfram Language function, https://reference.wolfram.com/language/ref/PopupMenu.html (updated 2010).

CMS

Wolfram Language. 2007. "PopupMenu." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2010. https://reference.wolfram.com/language/ref/PopupMenu.html.

APA

Wolfram Language. (2007). PopupMenu. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PopupMenu.html

BibTeX

@misc{reference.wolfram_2026_popupmenu, author="Wolfram Research", title="{PopupMenu}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/PopupMenu.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_popupmenu, organization={Wolfram Research}, title={PopupMenu}, year={2010}, url={https://reference.wolfram.com/language/ref/PopupMenu.html}, note=[Accessed: 13-June-2026]}