WOLFRAM

Wolfram Language & System Documentation Center

PreprocessingRules

is an option that specifies how the input should be preprocessed.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

PreprocessingRules

PreprocessingRules

is an option that specifies how the input should be preprocessed.

Details

  • The rules given by PreprocessingRules are applied to each expression.
  • Typical settings are:
  • Automatican automatic choice of preprocessing
    Noneno preprocessing
    rulesexplicit set of preprocessing rules
  • Rules for PreprocessingRules can involve patterns.

Examples

open all close all

Basic Examples  (2)

Preprocess a specific word:

Wolfram Language code: WordCloud[Alphabet[], PreprocessingRules -> {"a" -> Style["A", 7, StandardGray]}]

Use a pattern to select and process input words:

Wolfram Language code: WordCloud[RandomInteger[9, 100], PreprocessingRules -> {n_ ? OddQ :> Style[n, StandardGray]}]

Scope  (2)

Specify a default processing rule:

Wolfram Language code: WordCloud[RandomInteger[9, 100], PreprocessingRules -> {n_ ? PrimeQ :> Style[n, Red], n_ :> Style[n, Blue]}]

Without a default rule, automatic styling is used:

Wolfram Language code: WordCloud[data = RandomInteger[9, 100], PreprocessingRules -> {n_ ? PrimeQ :> Style[n, Red]}]

Compare with all default styles:

Wolfram Language code: WordCloud[data]

Applications  (3)

Spellcheck strings before displaying them:

Wolfram Language code: WordCloud[{"dog", "bananna", "elefant", "peple"}, PreprocessingRules -> s_String :> First[SpellingCorrectionList[s]]]

Round real numbers to their closest integers:

Wolfram Language code: WordCloud[RandomReal[10, 100]]
Wolfram Language code: WordCloud[RandomReal[10, 100], PreprocessingRules -> x_Real :> Round[x]]

Create a function that takes the first match in the dictionary given a word stem:

Wolfram Language code: string = DeleteStopwords@Import["https://en.wikipedia.org/wiki/Word_stem"];
Wolfram Language code: stems = GroupBy[DictionaryLookup[], WordStem]; firstByStem[s_] := First[Lookup[stems, WordStem[s], {s}]]

Use it to regularize the input of WordCloud:

Wolfram Language code: WordCloud[string, PreprocessingRules -> s_String :> firstByStem[s]]

Modify the function to only return verbs:

Wolfram Language code: firstVerbByStem[s_] := First[Flatten[TextCases[Lookup[stems, WordStem[s], {s}], "Verb"]], {}]
Wolfram Language code: WordCloud[string, PreprocessingRules -> s_String :> firstVerbByStem[s]]

Properties & Relations  (2)

When the preprocessing splits the word into multiple words, weights are propagated to new words:

Wolfram Language code: words = Tally[TextWords[Import["http://www.wolfram.com"]]]; Short[words]
Wolfram Language code: WordCloud[words]
Wolfram Language code: WordCloud[words, PreprocessingRules -> s_String :> Characters[s]]

If a word matches more than one pattern, the first match is used:

Wolfram Language code: WordCloud[Range[100], PreprocessingRules -> { n_ ? PrimeQ :> Style[n, Red, Italic], n_ /; n > 50 :> Style[n, Darker@Green]}, ColorFunction -> StandardGray, WordSpacings -> {6, 2} ]
Wolfram Research (2017), PreprocessingRules, Wolfram Language function, https://reference.wolfram.com/language/ref/PreprocessingRules.html.

Text

Wolfram Research (2017), PreprocessingRules, Wolfram Language function, https://reference.wolfram.com/language/ref/PreprocessingRules.html.

CMS

Wolfram Language. 2017. "PreprocessingRules." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/PreprocessingRules.html.

APA

Wolfram Language. (2017). PreprocessingRules. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PreprocessingRules.html

BibTeX

@misc{reference.wolfram_2026_preprocessingrules, author="Wolfram Research", title="{PreprocessingRules}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/PreprocessingRules.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_preprocessingrules, organization={Wolfram Research}, title={PreprocessingRules}, year={2017}, url={https://reference.wolfram.com/language/ref/PreprocessingRules.html}, note=[Accessed: 12-June-2026]}