WOLFRAM

Wolfram Language & System Documentation Center

PrimeZetaP[s]

gives prime zeta function TemplateBox[{s}, PrimeZetaP].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Applications  
Neat Examples  
See Also
Related Guides
History
Cite this Page

PrimeZetaP

PrimeZetaP[s]

gives prime zeta function TemplateBox[{s}, PrimeZetaP].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • TemplateBox[{s}, PrimeZetaP] is defined by for and by analytic continuation for .
  • PrimeZetaP can be evaluated to arbitrary numerical precision.
  • PrimeZetaP automatically threads over lists. »

Examples

open all close all

Basic Examples  (2)

Evaluate to high precision:

Wolfram Language code: N[PrimeZetaP[2], 50]

Plot over a subset of the reals:

Wolfram Language code: Plot[{Re[PrimeZetaP[t]], Im[PrimeZetaP[t]]}, {t, 0.01, 1}]//Quiet

Scope  (14)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: PrimeZetaP[12.]
Wolfram Language code: PrimeZetaP[.53]

Evaluate to high precision:

Wolfram Language code: N[PrimeZetaP[4 / 11], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: PrimeZetaP[2.3000000000000000000000000]

Complex number input:

Wolfram Language code: PrimeZetaP[2.5 + I]

Evaluate efficiently at high precision:

Wolfram Language code: PrimeZetaP[3 / 5`100]//Timing
Wolfram Language code: PrimeZetaP[1 / 11`1000];//Timing

Compute the elementwise values of an array:

Wolfram Language code: PrimeZetaP[{{2.5, 5.2}, {I + .1, 1.2}}]

Or compute the matrix PrimeZetaP function using MatrixFunction:

Wolfram Language code: MatrixFunction[PrimeZetaP, {{2.5, 5.2}, {I + .1, 1.2}}]//FullSimplify

Compute average-case statistical intervals using Around:

Wolfram Language code: PrimeZetaP[ Around[2, 0.01]]

Specific Values  (3)

Simple exact values are generated automatically:

Wolfram Language code: Table[PrimeZetaP[s ], {s, {1 / 4, 2, 2 / 5, 3}}]//N

Some singular points of PrimeZetaP:

Wolfram Language code: Table[PrimeZetaP[s ], {s, {1 / 5, 1 / 3, 1 / 2, 1}}]

Find a value of s for which Re[PrimeZetaP[s]]=-2:

Wolfram Language code: sval = s /. FindRoot[Re[PrimeZetaP[s]] == -2, {s, 0.3}]
Wolfram Language code: Plot[Re[PrimeZetaP[s]], {s, 0.1, 0.5}, Epilog -> Style[Point[{sval, Re[PrimeZetaP[sval]]}], PointSize[Large], Red]]//Quiet

Visualization  (2)

Plot the real and imaginary parts of PrimeZetaP function:

Wolfram Language code: Plot[{Re[PrimeZetaP[x]], Im[PrimeZetaP[x]]}, {x, 0.01, 1}]//Quiet

Plot the real part of PrimeZetaP function:

Wolfram Language code: ComplexContourPlot[Re[PrimeZetaP[z]], {z, 0.01 + 0.01 I, 1 + I}, Contours -> 20]

Function Properties  (3)

Real domain of PrimeZetaP:

Wolfram Language code: FunctionDomain[PrimeZetaP[x], x]

Complex domain:

Wolfram Language code: FunctionDomain[PrimeZetaP[z], z, Complexes]//FullSimplify

PrimeZetaP threads element-wise over lists:

Wolfram Language code: PrimeZetaP[{2.0, 3.0, 4.0}]

TraditionalForm formatting:

Wolfram Language code: PrimeZetaP[s]//TraditionalForm

Applications  (2)

Compute Artin's constant:

Wolfram Language code: Exp[-NSum[ ((LucasL[n] - 1)/n)PrimeZetaP[n], {n, 2, Infinity}, WorkingPrecision -> 50, NSumTerms -> 200]]

Compute an approximation to the first Mertens constant:

Wolfram Language code: EulerGamma + PrimeZetaP[1 + E^-n] - n /. {n -> 20.}

Neat Examples  (1)

A twisted curve in the complex plane, based on the prime zeta function:

Wolfram Language code: ParametricPlot[ReIm[PrimeZetaP[1 / 2 + I t]], {t, 1 / 2, 25}, Exclusions -> None]
Wolfram Research (2008), PrimeZetaP, Wolfram Language function, https://reference.wolfram.com/language/ref/PrimeZetaP.html.

Text

Wolfram Research (2008), PrimeZetaP, Wolfram Language function, https://reference.wolfram.com/language/ref/PrimeZetaP.html.

CMS

Wolfram Language. 2008. "PrimeZetaP." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/PrimeZetaP.html.

APA

Wolfram Language. (2008). PrimeZetaP. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PrimeZetaP.html

BibTeX

@misc{reference.wolfram_2026_primezetap, author="Wolfram Research", title="{PrimeZetaP}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/PrimeZetaP.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_primezetap, organization={Wolfram Research}, title={PrimeZetaP}, year={2008}, url={https://reference.wolfram.com/language/ref/PrimeZetaP.html}, note=[Accessed: 13-June-2026]}