WOLFRAM

Wolfram Language & System Documentation Center

QuotientRemainder[m,n]

gives a list of the quotient and remainder from division of m by n.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Basic Applications  
Number Theory  
Properties & Relations  
Neat Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

QuotientRemainder

QuotientRemainder[m,n]

gives a list of the quotient and remainder from division of m by n.

Details

  • QuotientRemainder is also known as the ratio and quantity "left over" from division of m by n.
  • Integer mathematical function, suitable for both symbolic and numerical manipulation.
  • QuotientRemainder[m,n] returns the ratio of m,n and the quantity "left over".

Examples

open all close all

Basic Examples  (2)

Compute the quotient and remainder of two numbers:

Wolfram Language code: QuotientRemainder[7, 2]

Plot the sequence of quotients:

Wolfram Language code: DiscretePlot[First[QuotientRemainder[n, 5]], {n, 0, 40}]

Plot the sequence of remainders:

Wolfram Language code: DiscretePlot[Last[QuotientRemainder[n, 5]], {n, 0, 40}]

Scope  (7)

QuotientRemainder works over integers:

Wolfram Language code: QuotientRemainder[19, 5]

Rational numbers:

Wolfram Language code: QuotientRemainder[15 / 4, 2 / 3]

Inexact real numbers:

Wolfram Language code: QuotientRemainder[5.89, 2.4]

Exact numbers:

Wolfram Language code: QuotientRemainder[E ^ E, Pi]

Complex numbers:

Wolfram Language code: QuotientRemainder[9.4 + 6I, 1. + I]

Compute for large integers:

Wolfram Language code: QuotientRemainder[10 ^ 90, NextPrime[10 ^ 80]]

QuotientRemainder threads elementwise over lists:

Wolfram Language code: QuotientRemainder[{1, 2, 3, 4, 5, 6, 7, 8, 9, 10}, 3]

Applications  (8)

Basic Applications  (3)

Plot the quotient of a number of division by 5:

Wolfram Language code: Plot[First[QuotientRemainder[x, 5]], {x, -10, 10}]

Plot the remainder of a number of division by 5:

Wolfram Language code: Plot[Last[QuotientRemainder[x, 5]], {x, -10, 10}]

Plot the quotient of two integers:

Wolfram Language code: MatrixPlot[Table[Quotient[a, b], {a, 20}, {b, 20}], PlotLegends -> Automatic]

Number Theory  (5)

Use NestWhileList to compute the quotient of positive arguments:

Wolfram Language code: myQuotient[m_, n_] := Length[NestWhileList[n + #&, n, # ≤ m&]] - 1;
Wolfram Language code: myQuotient[26, 7]

Compare with:

Wolfram Language code: QuotientRemainder[26, 7][[1]]

Use Floor to compute the quotient for integers:

Wolfram Language code: Floor[83 / 16]
Wolfram Language code: QuotientRemainder[83, 16][[1]]

Demonstrate how division works:

Wolfram Language code: {q, r} = QuotientRemainder[7, 2];
Wolfram Language code: 2 q + r == 7

Count the number of positive integers less than 1000 divisible by 2 or 3, but not divisible by 6:

Wolfram Language code: With[{n = 1000}, Quotient[n, 2] + Quotient[n, 3] - 2Quotient[n, 6]]

Direct count:

Wolfram Language code: Count[Range[1000], n_ /; (Divisible[n, 2] || Divisible[n, 3]) && !Divisible[n, 6]]

The Euclidean algorithm:

Wolfram Language code: euclid[a_, b_] := FixedPointList[{#2, If[#2 == 0, 0, # - Quotient[##]#2]}&@@#&, {a, b}][[-3, 1]];
Wolfram Language code: euclid[24, 36]

Compare with:

Wolfram Language code: GCD[24, 36]

Properties & Relations  (2)

The first part of QuotientRemainder is the Quotient:

Wolfram Language code: First[QuotientRemainder[11, 2]]
Wolfram Language code: Quotient[11, 2]

The second part of QuotientRemainder is the Mod:

Wolfram Language code: Last[QuotientRemainder[11, 2]]
Wolfram Language code: Mod[11, 2]

Neat Examples  (2)

Plot the arguments of the Fourier transform of the QuotientRemainder:

Wolfram Language code: ArrayPlot[Arg[Fourier[Table[QuotientRemainder[m, n], {m, 100}, {n, 100}]]]]

Plot the Ulam spiral of the QuotientRemainder:

Wolfram Language code: ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table [(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n];
Wolfram Language code: ArrayPlot[QuotientRemainder[ulam[101], 50], ColorFunction -> (Hue[#[[1]] + #[[2]]]&)]
Wolfram Research (2007), QuotientRemainder, Wolfram Language function, https://reference.wolfram.com/language/ref/QuotientRemainder.html.

Text

Wolfram Research (2007), QuotientRemainder, Wolfram Language function, https://reference.wolfram.com/language/ref/QuotientRemainder.html.

CMS

Wolfram Language. 2007. "QuotientRemainder." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/QuotientRemainder.html.

APA

Wolfram Language. (2007). QuotientRemainder. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/QuotientRemainder.html

BibTeX

@misc{reference.wolfram_2026_quotientremainder, author="Wolfram Research", title="{QuotientRemainder}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/QuotientRemainder.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_quotientremainder, organization={Wolfram Research}, title={QuotientRemainder}, year={2007}, url={https://reference.wolfram.com/language/ref/QuotientRemainder.html}, note=[Accessed: 13-June-2026]}