WOLFRAM

Wolfram Language & System Documentation Center

RootSum[f,form]

represents the sum of form[x] for all x that satisfy the polynomial equation f[x]==0.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

RootSum

RootSum[f,form]

represents the sum of form[x] for all x that satisfy the polynomial equation f[x]==0.

Details

  • f must be a Function object such as (#^5-2#+1)&.
  • form need not correspond to a polynomial function.
  • Normal[expr] expands RootSum objects into explicit sums involving Root objects.
  • f and form can contain symbolic parameters.
  • RootSum[f,form] is automatically simplified whenever form is a rational function.
  • RootSum is often generated in computing integrals of rational functions.

Examples

open all close all

Basic Examples  (2)

Integrating a rational function of any order:

Wolfram Language code: Integrate[1 / (x ^ 5 + 11 x + 1), {x, 1, 3}]

Evaluate numerically:

Wolfram Language code: N[%, 50]

Automatic simplification of RootSum objects:

Wolfram Language code: RootSum[# ^ 5 - 11 # + 1&, (# ^ 2 - 1) / (# ^ 3 - 2# + c)&]

Scope  (11)

Compute a numerical approximation of a RootSum:

Wolfram Language code: N[RootSum[# ^ 5 - 3# - 7&, Sin]]

Evaluate to high precision:

Wolfram Language code: N[RootSum[# ^ 5 - 3# - 7&, Sin], 50]

Sums over roots of polynomials with inexact number coefficients:

Wolfram Language code: RootSum[# ^ 5 - 3.2# + 2.1&, f]

Sums of numeric functions over roots of quadratics:

Wolfram Language code: RootSum[# ^ 2 - # + a&, Sin[#]&]

Sums of rational functions of roots:

Wolfram Language code: RootSum[# ^ 5 - a # + b&, (# ^ 2 - 1) / (# ^ 3 - 2# + c)&]

Sums of logarithms of linear functions over roots of polynomials with rational coefficients:

Wolfram Language code: RootSum[# ^ 5 - 2 # + 3 / 7&, Log[2# + 1]&]

Sums of numeric functions over roots of polynomials with multiple factors:

Wolfram Language code: RootSum[(# ^ 3 - a) ^ 2(# ^ 4 - b) ^ 3&, 5Tan[#] + 7&]

Represent a RootSum explicitly in terms of Root objects:

Wolfram Language code: Normal[RootSum[# ^ 5 - 3# - 7&, Sin]]

Derivatives:

Wolfram Language code: D[RootSum[# ^ 5 + 11# + 1&, Exp[a #]&], a]
Wolfram Language code: D[RootSum[# ^ 5 + a # + 1&, Exp[#]&], a]

Integrals:

Wolfram Language code: Integrate[RootSum[# ^ 5 + 11# + 1&, Exp[-a #]&], a]
Wolfram Language code: Integrate[RootSum[# ^ 5 + 11# + 1&, Sin[a #]&], {a, 0, 1}]

Limits:

Wolfram Language code: Limit[RootSum[# ^ 5 + 11# + 1&, Exp[a #]&], a -> 1]
Wolfram Language code: Limit[RootSum[# ^ 5 + 2# ^ 4 + 11# + 1&, Sin[a #] / a&], a -> 0]

Series:

Wolfram Language code: Series[RootSum[# ^ 5 + 2# ^ 4 + 11# + 1&, Sin[a #] / a&], {a, 0, 5}]
Wolfram Language code: Series[RootSum[# ^ 5 + a # + 1&, Exp[#]&], {a, 0, 2}]

Applications  (3)

Integrate a rational function:

Wolfram Language code: Integrate[(x - 2) / (x ^ 5 - 2x + 5), x]

Sum a rational function:

Wolfram Language code: Sum[1 / (k ^ 3 + 11k + 1), {k, 1, n}]

Matrix exponential of any order:

Wolfram Language code: m = {{1, 2, 3}, {1, 0, 0}, {0, 1, 0}};
Wolfram Language code: MatrixExp[m t]

Properties & Relations  (2)

Vieta's formulas:

Wolfram Language code: Table[RootSum[# ^ 4 + a # ^ 3 + b # ^ 2 + c # + d&, # ^ k&], {k, 4}]
Wolfram Language code: Table[SymmetricReduction[r ^ k + s ^ k + t ^ k + u ^ k, {r, s, t, u}, {-a, b, -c, d}][[1]], {k, 4}]

The residue theorem:

Wolfram Language code: NIntegrate[1 / (x ^ 6 - 2x + 4), {x, -Infinity, Infinity}]
Wolfram Language code: N[RootSum[# ^ 6 - 2# + 4&, If[Im[#] > 0, 2Pi I / (6# ^ 5 - 2), 0]&]]
Wolfram Research (1996), RootSum, Wolfram Language function, https://reference.wolfram.com/language/ref/RootSum.html.

Text

Wolfram Research (1996), RootSum, Wolfram Language function, https://reference.wolfram.com/language/ref/RootSum.html.

CMS

Wolfram Language. 1996. "RootSum." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/RootSum.html.

APA

Wolfram Language. (1996). RootSum. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RootSum.html

BibTeX

@misc{reference.wolfram_2026_rootsum, author="Wolfram Research", title="{RootSum}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/RootSum.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_rootsum, organization={Wolfram Research}, title={RootSum}, year={1996}, url={https://reference.wolfram.com/language/ref/RootSum.html}, note=[Accessed: 13-June-2026]}