WOLFRAM

Wolfram Language & System Documentation Center

ScheduledTask[expr,timespec]

represents a scheduled task to be evaluated on the schedule defined by timespec.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Time Specifications  
Generalizations & Extensions  
Options  
NotificationFunction  
TimeZone  
Applications  
Possible Issues  
See Also
Related Guides
Related Workflows
History
Cite this Page

ScheduledTask

ScheduledTask[expr,timespec]

represents a scheduled task to be evaluated on the schedule defined by timespec.

Details and Options

  • CloudDeploy[ScheduledTask[…]] deploys a scheduled task to be executed in the cloud.
  • SessionSubmit, LocalSubmit and CloudSubmit submit scheduled tasks for background evaluation in the current session, on the local system or in the cloud.
  • Submitted tasks can be controlled using TaskSuspend, TaskResume, etc.
  • The argument expr can be the Wolfram Language code to be evaluated, or a CloudObject or File containing Wolfram Language input.
  • The following time period specification can be given:
  • "Hourly"run once an hour
    "Daily"run once a day
    "Weekly"run once a week
    "Monthly"run once a month
    "Yearly"run once a year
    Quantity[...]run at a specified time interval
  • The following timespec specifications can be given:
  • periodrun once every period
    {period}run once after the period
    {period, count}run only count times ever
  • The following specifications can be given to limit when the task can be run:
  • {start,timespec}commence runs on date start
    {timespec,end}end runs on date end
    {start,timespec,end}run between dates start and end
  • start and end parameters should be given as a DateObject or other time specification.
  • Additional timespec specifications can be given:
  • DateObject[patt]run at times matching the specified pattern
    "cronspec"run at times specified by a Unix cron specification
    Nowrun immediately
    Nonerun on demand only
  • In DateObject[patt], the pattern patt has the form {y,m,d,h,m,s}, where later elements can be dropped, and where each element can be a literal integer, a choice of integers of the form n1|n2|…, or _ representing any possible value. For the day element, literal days can be replaced by symbols indicating a day of the week, such as Monday.
  • The following options can be given:
  • AutoRemoveFalseremove task after its last scheduled run
    NotificationFunction Automatichow to provide notifications
    TimeZone Automatictime zone for scheduling
  • For purposes of NotificationFunction, a task is considered to have failed if its output is $Failed or a Failure object.
  • In the cloud, the precise times at which scheduled tasks are run are typically determined by load-balancing requirements.
  • The minimum time between repetitions of a task in the cloud is determined by cloud configuration and policies and will typically be a certain fraction of an hour.

Examples

open all close all

Basic Examples  (4)

Create a scheduled task in a local session:

Wolfram Language code: obj = SessionSubmit[ScheduledTask[Print[Now, " ", MemoryInUse[]], Quantity[1, "Minutes"]]]

The Print output goes to the Messages window.

Delete the task:

Wolfram Language code: TaskRemove[obj]

Create a scheduled task on a separate kernel:

Wolfram Language code: obj = LocalSubmit[ScheduledTask[Now, Quantity[15, "Seconds"]], HandlerFunctions -> <|"ResultReceived" -> Print|>, HandlerFunctionsKeys -> "EvaluationResult" ]

The Print output goes to the Messages window.

Delete the task:

Wolfram Language code: TaskRemove[obj]

Create a scheduled cloud task that emails the task owner the temperature daily for the next month:

Wolfram Language code: obj = CloudSubmit[ScheduledTask[SendMail[<|"To" -> $CloudUserID, "Subject" -> DateString[], "Body" -> AirTemperatureData[]|>], "Hourly"]]

Delete the task:

Wolfram Language code: TaskRemove[obj]

Deploy a scheduled cloud task that logs the date and temperature hourly:

Wolfram Language code: obj = CloudDeploy[ScheduledTask[PutAppend[{Now, AirTemperatureData[]}, CloudObject["results.log"]], "Hourly"]]

Run the task manually to test it without waiting for the next scheduled run:

Wolfram Language code: TaskExecute[obj]

Retrieve the list of past results:

Wolfram Language code: ReadList[CloudObject["results.log"]]

Delete the task:

Wolfram Language code: TaskRemove[obj]

Scope  (9)

Time Specifications  (9)

Create a task with no schedule:

Wolfram Language code: task = SessionSubmit[ScheduledTask[Print[Now], None]]

Trigger the task manually:

Wolfram Language code: TaskExecute[task]

Delete the task:

Wolfram Language code: TaskRemove[task]

Submit a task in the current kernel session that runs immediately using a timespec of Now:

Wolfram Language code: task = SessionSubmit[ScheduledTask[MessageDialog["Done"], Now]]

The task is deleted automatically:

Wolfram Language code: Tasks[]

Submit a task in the cloud that runs immediately:

Wolfram Language code: task = CloudSubmit[ScheduledTask[SendMail["Done"], Now]]

After the task runs, it no longer exists in the cloud:

Wolfram Language code: FileExistsQ[CloudObject["uuid:" <> task["TaskUUID"]]]

Deploy a task with no schedule:

Wolfram Language code: task = CloudDeploy[ScheduledTask[SendMail["Done with deployed task."], Now]]

A deployed task (made with CloudDeploy, not CloudSubmit) still exists in the cloud after running:

Wolfram Language code: FileExistsQ[task]

Remove the deployed task:

Wolfram Language code: TaskRemove[task]

Create a task that runs every second for 10 times, showing its progress as it runs:

Wolfram Language code: n = 0; ProgressIndicator[Dynamic[n], {0, 10}] task = SessionSubmit[ScheduledTask[Print[Now, " ", n++], {Quantity[1, "Seconds"], 10}]]

Deploy a daily task that sends a countdown email starting tomorrow:

Wolfram Language code: thisYear = First[DateList[]] task = CloudDeploy[ScheduledTask[SendMail[StringTemplate["`1` left in `2`"][DateObject[{thisYear + 1, 1, 1}] - Today, thisYear]], {Tomorrow, "Daily"}]]

To test the task, trigger it to run now:

Wolfram Language code: TaskExecute[task]

Remove the task:

Wolfram Language code: TaskRemove[task]

Deploy a daily task that sends a countdown email ending once the year is over:

Wolfram Language code: thisYear = First[DateList[]] beginningOfNextYear = DateObject[{thisYear + 1, 1, 1}] task = CloudDeploy[ScheduledTask[SendMail[StringTemplate["`1` left in `2`"][beginningOfNextYear - Today, thisYear]], {"Daily", beginningOfNextYear}]]

To test the task, trigger it to run now:

Wolfram Language code: TaskExecute[task]

Remove the task:

Wolfram Language code: TaskRemove[task]

Deploy a daily task that sends a countdown email starting tomorrow and ending once the year is over:

Wolfram Language code: thisYear = First[DateList[]] beginningOfNextYear = DateObject[{thisYear + 1, 1, 1}] task = CloudDeploy[ScheduledTask[SendMail[StringTemplate["`1` left in `2`"][beginningOfNextYear - Today, thisYear]], {Tomorrow, "Daily", beginningOfNextYear}]]

To test the task, trigger it to run now:

Wolfram Language code: TaskExecute[task]

Remove the task:

Wolfram Language code: TaskRemove[task]

Create a task that runs at 7am on certain days of the week:

Wolfram Language code: task = CloudDeploy[ScheduledTask[SendMail["Reminder: office hours today, 11-12"], DateObject[{_, _, Monday | Wednesday | Thursday, 7}]]]

Confirm the next run date is as expected:

Wolfram Language code: ScheduledTaskInformation[task, "NextRunDate"]

Remove the task:

Wolfram Language code: TaskRemove[task]

Create a scheduled cloud task that logs the opening price of a financial instrument on weekdays using a "cronspec" specification:

Wolfram Language code: obj = CloudDeploy[ScheduledTask[{Now, FinancialData["QQQ", "Open"]}, "* 10 * * 1,2,3,4,5"]]

Delete the task:

Wolfram Language code: TaskRemove[obj]

Create a scheduled cloud task that updates a time stamp in the cloud once a day:

Wolfram Language code: time = DateList[];
Wolfram Language code: var = CloudSave[time];
Wolfram Language code: obj = With[{co = var}, CloudSubmit[ScheduledTask[time = DateList[];CloudSave[time, co], "Daily"]] ]

Get the current time stamp:

Wolfram Language code: CloudGet[var]

Run the scheduled task cloud object using TaskExecute:

Wolfram Language code: TaskExecute[obj]

The time stamp has been updated:

Wolfram Language code: CloudGet[var]

Delete the task:

Wolfram Language code: TaskRemove[obj];

Generalizations & Extensions  (1)

Use TaskSuspend to suspend scheduled executions of a cloud-scheduled task:

Wolfram Language code: obj = CloudSubmit[ScheduledTask[TimeObject[], "Daily"]]
Wolfram Language code: TaskSuspend[obj]

Delete the task:

Wolfram Language code: TaskRemove[obj]

Options  (2)

NotificationFunction  (1)

Notifications allow indicated parties to receive status messages on task evaluation. Deploy a task that notifies multiple parties after every run:

Wolfram Language code: co = CloudSubmit[ScheduledTask[{Now, AirTemperatureData[]}, "Daily", NotificationFunction -> {{$CloudUserID, "a@b.com"} -> All} ]]

Trigger the task to run asynchronously:

Wolfram Language code: TaskExecute[co]

Trigger the task to run again:

Wolfram Language code: TaskExecute[co]

Delete the task:

Wolfram Language code: TaskRemove[co]

TimeZone  (1)

Deploy a task that uses $TimeZone set to GMT+2:

Wolfram Language code: task = CloudDeploy[ScheduledTask[CloudPut[{$TimeZone, $TimeZoneEntity, Now, DateString[]}, "result"], None, TimeZone -> 2]]

Trigger the task to run immediately:

Wolfram Language code: TaskExecute[task]

After waiting a few moments for it to run, read from the result object that it wrote, noting the time zone setting was applied:

Wolfram Language code: CloudGet["result"]

Remove the task:

Wolfram Language code: DeleteObject[task]

Applications  (1)

Create an application that sends an email alert based on a scheduled task:

Wolfram Language code: CheckForFullMoon[] := If[MoonPhase[Tomorrow] > 0.99, SendLunarAlertMail[]]
Wolfram Language code: SendLunarAlertMail[] := SendMail[<|"To" -> $CloudUserID, "Subject" -> "Alert: Full Moon", "Body" -> {"There will be a full moon tomorrow: " <> DateString[Tomorrow], " ", MoonPhase[Tomorrow, "Icon"], " ", "http://www.wolframalpha.com/input/?i=moon+phase"}|>]

Make a scheduled task that evaluates at 18:00 every day and checks tomorrow's moon phase:

Wolfram Language code: obj = CloudSubmit[ScheduledTask[CheckForFullMoon[], DateObject[{_, _, _, 18}]]]

Delete the task:

Wolfram Language code: TaskRemove[obj]

Possible Issues  (3)

Time specification involving numeric values may appear to be ambiguous:

Wolfram Language code: CloudSubmit[ScheduledTask[{Now, AirTemperatureData[]}, {Tomorrow, 3600}]]

Resolve the ambiguity by providing an explicit period and repeat count:

Wolfram Language code: obj = CloudSubmit[ScheduledTask[{Now, AirTemperatureData[]}, {Tomorrow, {3600, Infinity}}]]

Delete the task:

Wolfram Language code: TaskRemove[obj];

Named periods "Monthly" and "Yearly" that align to the calendar may skip a run if the day of the month on which they are deployed does not exist on the next expected run, such as when a "Yearly" task is deployed on February 29:

Wolfram Language code: task = CloudDeploy[ScheduledTask[{Now, AirTemperatureData[]}, "Yearly"]]
Wolfram Language code: ScheduledTaskInformation[task, "NextRunDate"]
Wolfram Language code: DateObject[{2028, 2, 29, 18, 33, 0}, "Instant", "Gregorian", -6.]

Delete the task:

Wolfram Language code: TaskRemove[task]

To avoid this, control the start date so it does not fall on a potentially problematic day toward the end of the month:

Wolfram Language code: task = CloudDeploy[ScheduledTask[{Now, AirTemperatureData[]}, {DateObject["2024-02-28"], "Yearly"}]]

When ScheduledTask is evaluated in the cloud, it has restrictions on memory usage and evaluation time. The limitations are determined by your cloud plan, and the amounts can be found in CloudAccountData as "ScheduledTaskMemoryLimit" and "ScheduledTaskEvaluationTimeLimit":

Wolfram Language code: CloudAccountData /@ {"ScheduledTaskMemoryLimit", "ScheduledTaskEvaluationTimeLimit"}
Wolfram Research (2014), ScheduledTask, Wolfram Language function, https://reference.wolfram.com/language/ref/ScheduledTask.html (updated 2017).

Text

Wolfram Research (2014), ScheduledTask, Wolfram Language function, https://reference.wolfram.com/language/ref/ScheduledTask.html (updated 2017).

CMS

Wolfram Language. 2014. "ScheduledTask." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/ScheduledTask.html.

APA

Wolfram Language. (2014). ScheduledTask. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ScheduledTask.html

BibTeX

@misc{reference.wolfram_2026_scheduledtask, author="Wolfram Research", title="{ScheduledTask}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/ScheduledTask.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_scheduledtask, organization={Wolfram Research}, title={ScheduledTask}, year={2017}, url={https://reference.wolfram.com/language/ref/ScheduledTask.html}, note=[Accessed: 13-June-2026]}