WOLFRAM

Wolfram Language & System Documentation Center

ShortestPathFunction[type,data]

represents a function that gives the shortest path from a source vertex s to target vertex t in a graph.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
See Also
Related Guides
History
Cite this Page

ShortestPathFunction

ShortestPathFunction[type,data]

represents a function that gives the shortest path from a source vertex s to target vertex t in a graph.

Details

Examples

open all close all

Basic Examples  (1)

Obtain a function that gives shortest paths from vertex 4:

Wolfram Language code: g = PetersenGraph[4, 1, VertexSize -> {4 -> Medium}]
Wolfram Language code: spf = FindShortestPath[g, 4, All]

Use it to show the shortest paths to all vertices:

Wolfram Language code: Table[HighlightGraph[g, PathGraph@spf[v]], {v, VertexList[g]}]

Scope  (7)

ShortestPathFunction works with undirected graphs:

Wolfram Language code: s = 3; g = GridGraph[{2, 3}, VertexSize -> {s -> Small}]
Wolfram Language code: spf = FindShortestPath[g, s, All]
Wolfram Language code: Table[HighlightGraph[g, PathGraph@spf[t]], {t, VertexList[g]}]

Directed graphs:

Wolfram Language code: s = 3; g = GridGraph[{2, 3}, DirectedEdges -> True, VertexSize -> Small, VertexLabels -> {s -> "s"}, ImagePadding -> 10, EdgeStyle -> Arrowheads[Small]]
Wolfram Language code: spf = FindShortestPath[g, s, All]
Wolfram Language code: Table[HighlightGraph[g, {PathGraph[spf[t], DirectedEdges -> True], Labeled[t, "t", {Above, Before}]}], {t, VertexList[g]}]

Weighted graphs:

Wolfram Language code: s = 1; g = PetersenGraph[4, 1, EdgeWeight -> {4, 0, 3, 1, 3, 2, 7, 8, 5, 2, 1, 6}, VertexSize -> {s -> Medium}]
Wolfram Language code: spf = FindShortestPath[g, s, All]
Wolfram Language code: Table[HighlightGraph[g, PathGraph@spf[t]], {t, VertexList[g]}]

A ShortestPathFunction can give shortest paths from a fixed vertex:

Wolfram Language code: g = CycleGraph[8, DirectedEdges -> True, EdgeStyle -> Arrowheads[Small]];
Wolfram Language code: spf = FindShortestPath[g, 5, All]
Wolfram Language code: Table[HighlightGraph[g, PathGraph[spf[t], DirectedEdges -> True]], {t, VertexList[g]}]

To a fixed vertex:

Wolfram Language code: g = CycleGraph[8, DirectedEdges -> True, EdgeStyle -> Arrowheads[Small]];
Wolfram Language code: spf = FindShortestPath[g, All, 5]
Wolfram Language code: Table[HighlightGraph[g, PathGraph[spf[t], DirectedEdges -> True]], {t, VertexList[g]}]

Between any pair of vertices:

Wolfram Language code: g = GridGraph[{4, 7}, VertexShapeFunction -> "Name"]
Wolfram Language code: spf = FindShortestPath[g, All, All]
Wolfram Language code: spf[8, 18]

ShortestPathFunction returns {} when no path exists:

Wolfram Language code: GridGraph[{2, 3}, DirectedEdges -> True, VertexShapeFunction -> "Name"]
Wolfram Language code: FindShortestPath[%, 3, All]
Wolfram Language code: %[1]
Wolfram Research (2010), ShortestPathFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/ShortestPathFunction.html.

Text

Wolfram Research (2010), ShortestPathFunction, Wolfram Language function, https://reference.wolfram.com/language/ref/ShortestPathFunction.html.

CMS

Wolfram Language. 2010. "ShortestPathFunction." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ShortestPathFunction.html.

APA

Wolfram Language. (2010). ShortestPathFunction. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ShortestPathFunction.html

BibTeX

@misc{reference.wolfram_2026_shortestpathfunction, author="Wolfram Research", title="{ShortestPathFunction}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/ShortestPathFunction.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_shortestpathfunction, organization={Wolfram Research}, title={ShortestPathFunction}, year={2010}, url={https://reference.wolfram.com/language/ref/ShortestPathFunction.html}, note=[Accessed: 13-June-2026]}