WOLFRAM

Wolfram Language & System Documentation Center

Sow[e]

specifies that e should be collected by the nearest enclosing Reap.

Sow[e,tag]

specifies that e should be collected by the nearest enclosing Reap whose pattern matches tag.

Sow[e,{tag1,tag2,…}]

specifies that e should be collected once for each pattern that matches a tagi.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

Sow

Sow[e]

specifies that e should be collected by the nearest enclosing Reap.

Sow[e,tag]

specifies that e should be collected by the nearest enclosing Reap whose pattern matches tag.

Sow[e,{tag1,tag2,…}]

specifies that e should be collected once for each pattern that matches a tagi.

Details

  • Sow[e,…] returns e.
  • By having several identical tagi, a single expression can be made to appear multiple times in a list returned by Reap.
  • Sow[e] is equivalent to Sow[e,None].
  • Sow[e,{{tag}}] sows an expression with tag {tag}.

Examples

open all close all

Basic Examples  (4)

Evaluate a sequence of expressions, "sowing" some to be collected by Reap:

Wolfram Language code: Reap[Sow[a];b;Sow[c];Sow[d];e]

Compute a sum, "sowing" i^2 at each step:

Wolfram Language code: Reap[Sum[Sow[i ^ 2] + 1, {i, 10}]]

Make separate lists for expressions "sown" with different tags:

Wolfram Language code: Reap[Sow[1, x];Sow[2, y];Sow[3, x];Sow[4, y]]

Reap only expressions "sown" with tag x:

Wolfram Language code: Reap[Sow[1, x];Sow[2, y];Sow[3, x];Sow[4, y], x]

Scope  (5)

Sow can be used anywhere in a computation:

Wolfram Language code: Reap[MapAll[If[PrimeQ[#], Sow[#]]&, Integrate[1 / (x ^ 5 - 1), x]];]

It still works inside a function:

Wolfram Language code: f[e_] := If[PrimeQ[e], Sow[e]]
Wolfram Language code: Reap[MapAll[f, Integrate[1 / (x ^ 5 - 1), x]];]

A single expression can be "sown" with multiple tags:

Wolfram Language code: Reap[Sow[1, x];Sow[2, {x, y}];Sow[3, y]]

If a single tag is repeated, the expression is sown repeatedly:

Wolfram Language code: Reap[Sow[1, {x, x, x}];Sow[2, {x, y}];Sow[3, y]]

A pattern in Reap can be used to specify which tags to collect:

Wolfram Language code: Reap[Sow[1, x];Sow[2, {x, y}];Sow[3, {y, z}];Sow[4, {x, y, z}], x | y]

The default is the pattern _, so that everything is collected:

Wolfram Language code: Reap[Sow[1, x];Sow[2, {x, y}];Sow[3, {y, z}];Sow[4, {x, y, z}]]

Tags can have any form; here they are True and False:

Wolfram Language code: Reap[Sow[#, # > 0]& /@ {1, -1, 2, -3, 1, 4, 5};]
Wolfram Language code: Reap[Sow[#, # > 0]& /@ {1, -1, 2, -3, 1, 4, 5};, True]

Applications  (3)

Make a list of all the steps taken in evaluating FindRoot:

Wolfram Language code: Reap[FindRoot[Cos[x] == x, {x, 1}, StepMonitor :> Sow[x]]]

Evaluate an iterated map, keeping iterates that are below 1/100:

Wolfram Language code: Reap[Nest[(If[# < 1 / 100, Sow[#]];4 #(1 - #))&, 0.2, 100]]

Find equivalence classes with respect to the value of mod 10:

Wolfram Language code: Reap[Do[Sow[i, Mod[i ^ 2, 10]], {i, 20}]]

Properties & Relations  (2)

Sow[x] returns x, "sowing" it as a side effect:

Wolfram Language code: Sow[x]

Expressions sown are reaped by the innermost enclosing Reap:

Wolfram Language code: Reap[Reap[Sow[2 ^ 20];Sow[2 ^ 30]]]
Wolfram Research (2003), Sow, Wolfram Language function, https://reference.wolfram.com/language/ref/Sow.html.

Text

Wolfram Research (2003), Sow, Wolfram Language function, https://reference.wolfram.com/language/ref/Sow.html.

CMS

Wolfram Language. 2003. "Sow." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Sow.html.

APA

Wolfram Language. (2003). Sow. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Sow.html

BibTeX

@misc{reference.wolfram_2026_sow, author="Wolfram Research", title="{Sow}", year="2003", howpublished="\url{https://reference.wolfram.com/language/ref/Sow.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_sow, organization={Wolfram Research}, title={Sow}, year={2003}, url={https://reference.wolfram.com/language/ref/Sow.html}, note=[Accessed: 12-June-2026]}