WOLFRAM

Wolfram Language & System Documentation Center

Specularity[s]

is a graphics directive which specifies that surfaces of 3D graphics objects which follow are to be taken to have specularity s.

Specularity[s,n]

uses specular exponent n.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
History
Cite this Page

Specularity

Specularity[s]

is a graphics directive which specifies that surfaces of 3D graphics objects which follow are to be taken to have specularity s.

Specularity[s,n]

uses specular exponent n.

Details

  • Specularity is added to diffuse reflection and glow components to determine the final rendered color of a surface. »
  • With specularity s, a surface is taken to specularly reflect a fraction s of light that falls on it from simulated light sources.
  • The specular exponent n defines how sharply the intensity of reflected light falls off away from the mirror‐reflection direction. »
  • The default specular exponent is 1.5. Higher values lead to more sharply defined reflections, typical of shinier materials. Values above 10 produce definite "specular highlights".
  • Specularity[s] takes the reflected light to have the same color as the incident light from light sources.
  • Specularity[col] specifies that the RGB components of the incident light should be multiplied by the RGB components of col. »
  • Specularity[s] is equivalent to Specularity[GrayLevel[s]]. »
  • Specularity[] is equivalent to Specularity[0] or Specularity[Black], and specifies no specular reflection.
  • Specularity directives do not affect specifications from Glow or RGBColor.

Examples

open all close all

Basic Examples  (3)

A typical specular color:

Wolfram Language code: Graphics3D[{Specularity[1, 20], Sphere[]}]

Specify the specular exponent:

Wolfram Language code: Table[Graphics3D[{Orange, Specularity[White, n], Sphere[]}], {n, {5, 20, 100}}]

Specify the color of specularity:

Wolfram Language code: Table[Graphics3D[{Black, Specularity[c, 10], Sphere[]}, Lighting -> "Neutral"], {c, {Red, Green, Blue}}]

Scope  (1)

Set diffuse, glow, and specular surface colors:

Wolfram Language code: Graphics3D[{Darker[Green, .4], Glow[Darker[Red, .5]], Specularity[White, 20], Sphere[]}, Lighting -> "Neutral"]

Applications  (1)

Using specular surface for plots:

Wolfram Language code: Plot3D[x Sin[x + y ^ 2], {x, -3, 3}, {y, -2, 2}, PlotStyle -> {Orange, Specularity[White, 20]}, Mesh -> None]

Properties & Relations  (6)

Specularity[s] is equivalent to Specularity[GrayLevel[s]]:

Wolfram Language code: Table[Graphics3D[{Orange, Specularity[s, 10], Sphere[]}], {s, {0, .5, 1}}]
Wolfram Language code: Table[Graphics3D[{Orange, Specularity[GrayLevel[s], 10], Sphere[]}], {s, {0, .5, 1}}]

Specularity[color] is equivalent to Specularity[color,1.5]:

Wolfram Language code: {Graphics3D[{Orange, Specularity[White], Sphere[]}], Graphics3D[{Orange, Specularity[White, 1.5], Sphere[]}]}

Specularity[] is equivalent to Specularity[Black] and specifies no specular reflection:

Wolfram Language code: Graphics3D[{Orange, Specularity[], Sphere[]}]

Specularity is strongly affected by Lighting:

Wolfram Language code: Graphics3D[{Black, Specularity[White, 10], Sphere[]}]
Wolfram Language code: Graphics3D[{Black, Specularity[White, 5], Sphere[]}, Lighting -> "Neutral"]
Wolfram Language code: Graphics3D[{Black, Specularity[White, 5], Sphere[]}, Lighting -> {{"Point", Orange, Scaled[{2, 2, 2}]}}]

Specify Lighting to use different colors for diffuse and specular surfaces:

Wolfram Language code: Graphics3D[{White, Specularity[White, 10], Sphere[]}, Lighting -> {{"Point", {Yellow, Specularity[Cyan]}, Scaled[{2, 2, 2}]}}]

Specular colors are mixed with surface colors:

Wolfram Language code: Graphics3D[{Darker[Red, .6], Specularity[Blue, 10], Sphere[]}, Lighting -> "Neutral"]

Possible Issues  (1)

Specularity may not be apparent in flat-faced surfaces:

Wolfram Language code: Graphics3D[{Specularity[Blue, 20], Cuboid[]}, Lighting -> "Neutral"]

Neat Examples  (1)

Metallic balls:

Wolfram Language code: Graphics3D[{Table[{Specularity[White, 20], RGBColor[RandomReal[1, {3}]], Sphere[RandomReal[10, {3}], RandomReal[{.5, 1}]]}, {50}]}]
Wolfram Research (2007), Specularity, Wolfram Language function, https://reference.wolfram.com/language/ref/Specularity.html.

Text

Wolfram Research (2007), Specularity, Wolfram Language function, https://reference.wolfram.com/language/ref/Specularity.html.

CMS

Wolfram Language. 2007. "Specularity." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Specularity.html.

APA

Wolfram Language. (2007). Specularity. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Specularity.html

BibTeX

@misc{reference.wolfram_2026_specularity, author="Wolfram Research", title="{Specularity}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Specularity.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_specularity, organization={Wolfram Research}, title={Specularity}, year={2007}, url={https://reference.wolfram.com/language/ref/Specularity.html}, note=[Accessed: 13-June-2026]}