WOLFRAM

Wolfram Language & System Documentation Center

SplitBy[list,f]

splits list into sublists consisting of runs of successive elements that give the same value when f is applied.

SplitBy[list,{f1,f2,…}]

recursively splits list into sublists by testing elements successively with each of the fi.

SplitBy[f]

represents an operator form of SplitBy that can be applied to an expression.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

SplitBy

SplitBy[list,f]

splits list into sublists consisting of runs of successive elements that give the same value when f is applied.

SplitBy[list,{f1,f2,…}]

recursively splits list into sublists by testing elements successively with each of the fi.

SplitBy[f]

represents an operator form of SplitBy that can be applied to an expression.

Details

  • SplitBy[list,…] splits but does not rearrange list.
  • SplitBy performs comparisons only on adjacent pairs of elements.
  • SplitBy[list,Identity] is equivalent to Split[list]. »
  • SplitBy[list,{f1,f2}] is equivalent to Map[SplitBy[#,f2]&,SplitBy[list,f1]]. »
  • SplitBy[f][list] is equivalent to SplitBy[list,f]. »

Examples

open all close all

Basic Examples  (2)

Split into runs of numbers with identical integer part:

Wolfram Language code: SplitBy[Range[1, 5, 1 / 2], IntegerPart]

Split by sign:

Wolfram Language code: SplitBy[{3, 0, -4, 3, 3, -2, 0, -3, -4, 5}, Sign]

Scope  (4)

Split by quotient:

Wolfram Language code: SplitBy[Range[10], Quotient[#, 3]&]

Split into runs of triples with identical first component:

Wolfram Language code: SplitBy[Tuples[{1, 2}, 3], First]

Split first by their first component and then by their second:

Wolfram Language code: SplitBy[Tuples[{1, 2}, 3], {First, Part[#, 2]&}]

Use Framed to display grouping:

Wolfram Language code: Map[Framed, %, {1, 2}]

Define a SplitBy operator:

Wolfram Language code: op = SplitBy[Last];

Use the operator to split integer data, putting each group on a separate row of a column:

Wolfram Language code: ints = RandomInteger[4, {10, 3}]; op[ints]//Column

Use the operator to split string data:

Wolfram Language code: words = RandomChoice[RandomWord[5], {10, 2}]; op[words]//Column

Create a list of associations:

Wolfram Language code: data = Table[AssociationThread[CharacterRange["a", "c"] -> RandomInteger[1, 3]], {10}]

Split by the value of the key "a":

Wolfram Language code: Framed /@ SplitBy[data, #a&]

Gather by the value of the keys "a" and "b", using the operator form of GatherBy:

Wolfram Language code: Map[Framed, SplitBy[{#a&, #b&}][data], {1, 2}]

Applications  (1)

Split dates into runs with identical year:

Wolfram Language code: Flatten@Table[DateString[{y, m}, {"Month", "/", "YearShort"}], {y, 2007, 2008}, {m, 1, 12}]
Wolfram Language code: SplitBy[%, DateList[{#, {"Month", "/", "YearShort"}}][[1]]&]

Properties & Relations  (4)

SplitBy[expr,Identity] and Split[expr] are the same operation:

Wolfram Language code: SplitBy[{a, a, a, b, b, a, a, c}, Identity] === Split[{a, a, a, b, b, a, a, c}]

SplitBy[list,f] is equivalent to Split[list,(f[#1]===f[#2])&]:

Wolfram Language code: m = RandomInteger[1, {10, 5}]; SplitBy[m, Norm] == Split[m, (Norm[#1] === Norm[#2])&]

Display the groups along with the norm of each group:

Wolfram Language code: Grid[Map[{MatrixForm[#], Norm[First[#]]}&, SplitBy[m, Norm] ]]

SplitBy[list,{f1,f2}] is equivalent to Map[SplitBy[#,f2]&,SplitBy[list,f1]]:

Wolfram Language code: list = RandomInteger[{-4, 4}, 9]; SplitBy[list, {Positive, EvenQ}] === Map[SplitBy[#, EvenQ]&, SplitBy[list, Positive]]

SplitBy[f][list] is equivalent to SplitBy[list,f]:

Wolfram Language code: list = Range[-4, 4]; SplitBy[Positive][list] === SplitBy[list, Positive]
Wolfram Research (2008), SplitBy, Wolfram Language function, https://reference.wolfram.com/language/ref/SplitBy.html (updated 2026).

Text

Wolfram Research (2008), SplitBy, Wolfram Language function, https://reference.wolfram.com/language/ref/SplitBy.html (updated 2026).

CMS

Wolfram Language. 2008. "SplitBy." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/SplitBy.html.

APA

Wolfram Language. (2008). SplitBy. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SplitBy.html

BibTeX

@misc{reference.wolfram_2026_splitby, author="Wolfram Research", title="{SplitBy}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/SplitBy.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_splitby, organization={Wolfram Research}, title={SplitBy}, year={2026}, url={https://reference.wolfram.com/language/ref/SplitBy.html}, note=[Accessed: 12-June-2026]}