WOLFRAM

Wolfram Language & System Documentation Center

StationaryDistribution[proc]

represents the stationary distribution of the process proc, when it exists.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

StationaryDistribution

StationaryDistribution[proc]

represents the stationary distribution of the process proc, when it exists.

Details

  • Stationary distribution is also known as limiting distribution, steady-state distribution, and invariant distribution.
  • The stationary distribution, if it exists, is a slice distribution that is independent of the time and characterizes the limiting behavior of the process proc after all possible transients have vanished.
  • StationaryDistribution[proc] is equivalent to SliceDistribution[proc,∞].

Examples

open all close all

Basic Examples  (1)

Stationary distribution for an M/M/1 queue:

Wolfram Language code: 𝒟 = StationaryDistribution[QueueingProcess[λ, μ]];

Probability density function:

Wolfram Language code: PDF[𝒟, x]
Wolfram Language code: DiscretePlot[PDF[𝒟 /. {λ -> 5, μ -> 6}, x], {x, 0, 10}]

Mean and variance:

Wolfram Language code: {Mean[𝒟], Variance[𝒟]}

Compute the probability of an event:

Wolfram Language code: Probability[x ^ 2 + E ^ x < 5, x𝒟]
Wolfram Language code: % /. {λ -> 5., μ -> 6}
Wolfram Language code: NProbability[x ^ 2 + E ^ x < 5, x𝒟 /. {λ -> 5, μ -> 6}]

Scope  (3)

Stationary distribution may autoevaluate to known distribution:

Wolfram Language code: StationaryDistribution[OrnsteinUhlenbeckProcess[μ, σ, θ]]
Wolfram Language code: StationaryDistribution[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]]]
Wolfram Language code: StationaryDistribution[BernoulliProcess[p]]
Wolfram Language code: StationaryDistribution[DiscreteMarkovProcess[1, RotateRight /@ IdentityMatrix[3]]]

Stationary distribution may autoevaluate to a derived distribution:

Wolfram Language code: StationaryDistribution[DiscreteMarkovProcess[1, With[{n = 10}, Table[Which[j == i - 1, i / n, j == i + 1, 1 - i / n, True, 0], {i, 0, n}, {j, 0, n}]]]]

Compute the stationary distribution for a discrete Markov process:

Wolfram Language code: proc = DiscreteMarkovProcess[{1 / 3, 0, 2 / 3, 0, 0}, {{(1/2), (1/2), 0, 0, 0}, {(1/3), (2/3), 0, 0, 0}, {0, (1/3), (2/3), 0, 0}, {0, 0, 0, 0, 1}, {0, 0, 0, 1, 0}}];

Some slice distributions:

Wolfram Language code: Table[N@PDF[proc[n], x], {n, {0, 3, 7, 12, 17}}]//Column

Stationary distribution:

Wolfram Language code: StationaryDistribution[proc]

Visualize the convergence to the stationary distribution using the PDF:

Wolfram Language code: DiscretePlot[PDF[proc[n], Range[5]], {n, 0, 20}, ExtentSize -> 1 / 3, ColorFunction -> Function[{x, y}, ColorData["Rainbow"][x]], AxesLabel -> {n, None}]

Properties & Relations  (3)

Stationary distribution is the SliceDistribution at infinity:

Wolfram Language code: StationaryDistribution[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]]]
Wolfram Language code: SliceDistribution[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]], ∞]

The stationary distribution may depend on the initial state:

Wolfram Language code: m = {{1 / 2, 1 / 2, 0, 0, 0}, {1 / 3, 2 / 3, 0, 0, 0}, {0, 1 / 3, 2 / 3, 0, 0}, {0, 0, 0, 0, 1}, {0, 0, 0, 1, 0}};
Wolfram Language code: StationaryDistribution[DiscreteMarkovProcess[1, m]]
Wolfram Language code: StationaryDistribution[DiscreteMarkovProcess[4, m]]

Mean system size is the mean of the stationary distribution for a queue:

Wolfram Language code: 𝒬 = QueueingProcess[λ, μ];
Wolfram Language code: QueueProperties[𝒬, "MeanSystemSize"]//Together
Wolfram Language code: Mean[StationaryDistribution[𝒬]]

Possible Issues  (1)

The stationary distribution may exist only for a certain range of process parameters:

Wolfram Language code: QueueProperties[QueueingProcess[λ, μ], "StationarySystem"]
Wolfram Research (2012), StationaryDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/StationaryDistribution.html.

Text

Wolfram Research (2012), StationaryDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/StationaryDistribution.html.

CMS

Wolfram Language. 2012. "StationaryDistribution." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/StationaryDistribution.html.

APA

Wolfram Language. (2012). StationaryDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/StationaryDistribution.html

BibTeX

@misc{reference.wolfram_2026_stationarydistribution, author="Wolfram Research", title="{StationaryDistribution}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/StationaryDistribution.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_stationarydistribution, organization={Wolfram Research}, title={StationaryDistribution}, year={2012}, url={https://reference.wolfram.com/language/ref/StationaryDistribution.html}, note=[Accessed: 13-June-2026]}