WOLFRAM

Wolfram Language & System Documentation Center

TextContents[text]

gives a dataset of information about entities, dates, quantities and other content-related elements found in text.

TextContents[text,form]

searches for cases of the type form.

TextContents[text,{form1,form2,…}]

searches for cases of types form1, form2, …

TextContents[text,forms,props]

includes the property props for each object in the dataset produced.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Options  
AcceptanceThreshold  
VerifyInterpretation  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

TextContents   

Listing of Text Content Types »

TextContents[text]

gives a dataset of information about entities, dates, quantities and other content-related elements found in text.

TextContents[text,form]

searches for cases of the type form.

TextContents[text,{form1,form2,…}]

searches for cases of types form1, form2, …

TextContents[text,forms,props]

includes the property props for each object in the dataset produced.

Details and Options

  • In TextContents[text,…], text can be a string, a file with plain text represented by File[…], a ContentObject expression or a list of these text objects.
  • TextContents[{text1,text2,…},…] gives cases for each texti.
  • Identification type form can be:
  • "type"any text content type (e.g. "Noun", "City")
    Entity[…,…]a specific entity of a text content type
    form1|form2|…form matching any of the formi
    Containing[outer,inner]forms of type outer containing type inner
    Verbatim["string"]a specific string to be matched exactly
    patterna string pattern to be matched
    Automaticentities, dates, quantities and other content-related elements
  • Possible choices for the property prop include:
  • "String"string of the identified text (default)
    "Position"start and end position of the string in text
    "Probability"estimated probability that the identification is correct
    "Type"type of content (entity type, …)
    "Interpretation"standard interpretation of the identified string
    "Snippet"a snippet around the identified string
    "HighlightedSnippet"a snippet with the identified string highlighted
    Allall the preceding properties
    {prop1,prop2,…}a list of property specifications
  • The following options can be given:
  • AcceptanceThreshold Automaticminimum probability to accept identification
    TargetDevice"CPU"whether CPU or GPU computation should be used for entity detection
    VerifyInterpretation Falsewhether interpretability should be verified

Examples

open all close all

Basic Examples  (1)

Find entities in a text:

Wolfram Language code: TextContents["The flag of Italy is green, white and red. Since 1861, the capital is Rome, which also serves as the capital of the Lazio region. With 2,872,800 residents in 1,285 km2 (496.1 sq mi)"]

Only get the results for locations:

Wolfram Language code: TextContents["The flag of Italy is green, white and red. Since 1861, the capital is Rome, which also serves as the capital of the Lazio region. With 2,872,800 residents in 1,285 km2 (496.1 sq mi)", "Location"]

Only get the results for locations and quantities:

Wolfram Language code: TextContents["The flag of Italy is green, white and red. Since 1861, the capital is Rome, which also serves as the capital of the Lazio region. With 2,872,800 residents in 1,285 km2 (496.1 sq mi)", {"Location", "Quantity"}]

Get interpretations for all cases:

Wolfram Language code: TextContents["The flag of Italy is green, white and red. Since 1861, the capital is Rome, which also serves as the capital of the Lazio region. With 2,872,800 residents in 1,285 km2 (496.1 sq mi)", {"Location", "Quantity"}, All]

Get a specified set of properties for entities:

Wolfram Language code: TextContents["The flag of Italy is green, white and red. Since 1861, the capital is Rome, which also serves as the capital of the Lazio region. With 2,872,800 residents in 1,285 km2 (496.1 sq mi)", Automatic, {"HighlightedSnippet", "Interpretation"}]

Options  (2)

AcceptanceThreshold  (1)

By default, all the detected entities have an estimated probability higher than 0.5:

Wolfram Language code: TextContents[ExampleData[{"Text", "JFKInaugural"}]]

Get only the entities that are highly probable to be correct by setting a high AcceptanceThreshold:

Wolfram Language code: TextContents[ExampleData[{"Text", "JFKInaugural"}], AcceptanceThreshold -> 0.9]

VerifyInterpretation  (1)

By default, some entities cannot be interpreted, either because they are not correct or because they are not yet in the knowledgebase:

Wolfram Language code: TextContents["We visited Toulouse and Auterive in Midi-Pyrénées in France.", Automatic, {"String", "Interpretation"}]

Use VerifyInterpretation to filter out the entities that cannot be interpreted:

Wolfram Language code: TextContents["We visited Toulouse and Auterive in Midi-Pyrénées in France.", Automatic, {"String", "Interpretation"}, VerifyInterpretation -> True]

Properties & Relations  (1)

TextContents handles the same types as TextPosition and TextCases and always identifies the same substrings as these functions for a given type:

Wolfram Language code: TextContents["Boston, Worcester, and Springfield are the largest cities in Massachusetts.", "City"]
Wolfram Language code: TextCases["Boston, Worcester, and Springfield are the largest cities in Massachusetts.", "City"]
Wolfram Language code: TextPosition["Boston, Worcester, and Springfield are the largest cities in Massachusetts.", "City"]

A dataset that is similar to the output of TextContents can be obtained using TextCases:

Wolfram Language code: Dataset@TextCases["Boston, Worcester, and Springfield are the largest cities in Massachusetts.", "City" -> Identity]
Wolfram Language code: Dataset@TextCases["Boston, Worcester, and Springfield are the largest cities in Massachusetts.", "City" -> Function[<|"City" -> Last[#Interpretation][[1]], "State" -> Last[#Interpretation][[2]], "Country" -> Last[#Interpretation][[3]], "Position" -> #Position, "HighlightedSnippet" -> #HighlightedSnippet|>]]

Neat Examples  (1)

Load the text of a Wikipedia page about the Moon:

Wolfram Language code: moon = WikipediaData["Moon"];
Wolfram Language code: Snippet[moon, 5]

Extract notable text contents from the page:

Wolfram Language code: contents = TextContents[moon, VerifyInterpretation -> True]

Visualize the frequency of content types found on the page:

Wolfram Language code: counts = ReverseSort@CountsBy[contents, #Type&]
Wolfram Language code: WordCloud[counts]

Find potential notable persons identified on the page:

Wolfram Language code: Normal[Select[contents, #Type === "Person"&][[All, "String"]]]

Interpret these persons as entities:

Wolfram Language code: persons = Normal[Select[contents, #Type === "Person"&][[All, "Interpretation"]]]

Visualize occupations of these persons:

Wolfram Language code: WordCloud[Counts[Flatten@EntityValue[persons, EntityProperty["Person", "Occupation"]]]]
Wolfram Research (2019), TextContents, Wolfram Language function, https://reference.wolfram.com/language/ref/TextContents.html.

Text

Wolfram Research (2019), TextContents, Wolfram Language function, https://reference.wolfram.com/language/ref/TextContents.html.

CMS

Wolfram Language. 2019. "TextContents." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/TextContents.html.

APA

Wolfram Language. (2019). TextContents. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TextContents.html

BibTeX

@misc{reference.wolfram_2026_textcontents, author="Wolfram Research", title="{TextContents}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/TextContents.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_textcontents, organization={Wolfram Research}, title={TextContents}, year={2019}, url={https://reference.wolfram.com/language/ref/TextContents.html}, note=[Accessed: 13-June-2026]}